I_MAINTORDEROPERCOMP

@AbapCatalog.sqlViewName: 'IMTORDOPRCOMP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order Operation Component'
@VDM.viewType: #COMPOSITE

@ObjectModel.representativeKey: 'MaintOrderComponentInternalID'
@ObjectModel.semanticKey:  [ 'MaintenanceOrder', 'MaintenanceOrderOperation', 'MaintOrderComponentInternalID' ]

//@ObjectModel: {

//    createEnabled: true,

//    updateEnabled: true,

//    deleteEnabled: true

//}


@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

define view I_MaintOrderOperComp
  as select from I_MaintenanceOrderComponent_2 
  /* BOPF associations: */
  association [1..1] to I_MaintOrderOperTechObj    as _MaintenanceOrderOperation on  $projection.MaintenanceOrder          = _MaintenanceOrderOperation.MaintenanceOrder
                                                                                 and $projection.MaintenanceOrderOperation = _MaintenanceOrderOperation.MaintenanceOrderOperation
  association [1..1] to I_MaintOrderTechObj        as _MaintenanceOrder          on  $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder
  association [0..*] to I_StatusObjectActiveStatus as _StatusObjectActiveStatus  on  $projection.MaintOrderComponentInternalID = _StatusObjectActiveStatus.StatusObject
{
      @ObjectModel.foreignKey.association: '_MaintenanceOrder'
  key MaintenanceOrder,
      @ObjectModel.foreignKey.association: '_MaintenanceOrderOperation'
  key MaintenanceOrderOperation,
  key MaintenanceOrderSubOperation, 
  key MaintOrderComponentInternalID,
      MaintenanceOrderComponent,
      Reservation,
      ReservationItem,
      ReservationType,
      Material,
      MaterialGroup,
      ComponentDescription,
      RequirementQuantityInBaseUnit,
      BaseUnit,
      MaintOrderCompDebitCreditCode,
      Plant,
      StorageLocation,
      MaintOrderRoutingNumber,
      MaintOrderOperationCounter,
      MaintComponentItemCategory as ItemCategory,
      PurchaseRequisition,
      PurchaseRequisitionItem,
      PurReqnOrResvnGeneration,
      MaterialCompIsProcuredDirectly,
      Supplier,

      cast( case when IsDeleted = '' then IsDeleted
           else coalesce( _StatusObjectActiveStatus[ 1: StatusCode = 'I0013' ].StatusIsActive, '' ) end as xloek ) as IsDeleted,
      QuantityWithdrawnInBaseUnit,
      PerformancePeriodStartDate,
      PerformancePeriodStartTime,
      PerformancePeriodEndDate,
      PerformancePeriodEndTime,
      LeanServiceDuration,
      LeanServiceDurationUnit,
      @Semantics.currencyCode: true
      MaintOrdOpComponentCurrency,
      DistributionFunction,
      SrvcSchedgIsAlignedWthOpWrkCtr,
      @Semantics.amount.currencyCode: 'MaintOrdOpComponentCurrency'
      OverallLimitAmount,
      @Semantics.amount.currencyCode: 'MaintOrdOpComponentCurrency'
      ExpectedOverallLimitAmount,
      RqmtDateIsEnteredManually,
      cast(
        case
            when RqmtDateIsEnteredManually = 'X' then 'M'
            when DistributionFunction = 'S10' then ''
            when DistributionFunction = 'S50' then 'X'
        end as cc4_delvry_date_adj preserving type )                                                                 as MaintOrdCompDeliveryDateAdjmt,
      FldLogsDelivIsHeldOnShore,
      FldLogsSupplyProcess,

      /* Associations */
      _Supplier,
      _Material,
      _MaterialText,
      _MaterialGroup,
      _StatusObject,
      _Plant,
      _ItemCategoryText,
      _StorageLocation,
      _SafetyRelevance,
      _UnitOfMeasure,
      _PurReqnOrResvnGeneration,
      //@ObjectModel.association.type: [#TO_COMPOSITION_ROOT]

      _MaintenanceOrder,
      _StatusObjectActiveStatus,
      //@ObjectModel.association.type: [#TO_COMPOSITION_PARENT]

      _MaintenanceOrderOperation
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEORDERCOMPONENT_2",
"I_STATUSOBJECTACTIVESTATUS"
],
"ASSOCIATED":
[
"I_MAINTCOMPITEMCATEGORYTXT",
"I_MAINTORDEROPERTECHOBJ",
"I_MAINTORDERTECHOBJ",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_MATERIALTEXT",
"I_PLANT",
"I_PMUNITOFMEASUREVH",
"I_PURREQNORRESVNGENERATION",
"I_SAFETYRELEVANCE",
"I_STATUSOBJECT",
"I_STATUSOBJECTACTIVESTATUS",
"I_STORAGELOCATION",
"I_SUPPLIER"
],
"BASE":
[
"I_MAINTENANCEORDERCOMPONENT_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/