I_MRPPLANTCONTROLPARAMETER

CDS View

MRP Plant Control Parameters

I_MRPPLANTCONTROLPARAMETER is a CDS View in S/4HANA. MRP Plant Control Parameters. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_DDHistlBufStkTimeSeries view_entity inner COMPOSITE Stock for Product
P_LastFallBackLeadTime view left_outer CONSUMPTION
P_ProductIndivLeadTime view left_outer COMPOSITE 
@AbapCatalog.entityBuffer.definitionAllowed: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #FACT
@Analytics.technicalName: 'IMRPPLNTCTRLPAR'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_FACT
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'MRP Plant Control Parameters'
// CDS view entity for the plant-based MRP control parameters

// For MRP-group-based control parameters (T438M) refer to I_MRPGroupControlParameter


define view entity I_MRPPlantControlParameter
  as select from t399d

  association [1..1] to I_Plant                as _MRPPlant            on  $projection.MRPPlant = _MRPPlant.Plant
  association [0..1] to I_Plant                as _ReferencePlant      on  $projection.ReferencePlant = _ReferencePlant.Plant  
  association [0..1] to I_MRPController        as _MRPController       on  $projection.MRPPlant      = _MRPController.Plant
                                                                       and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_MRPPlanningPeriod    as _MRPPlanningCalendar on  $projection.MRPPlant            = _MRPPlanningCalendar.MRPPlant
                                                                       and $projection.MRPPlanningCalendar = _MRPPlanningCalendar.MRPPlanningCalendar  
  association [0..1] to I_OrderType            as _OrderType           on  $projection.OrderType = _OrderType.OrderType
  association [0..1] to I_OrderType            as _ProcessOrderType    on  $projection.ProcessOrderType = _ProcessOrderType.OrderType
{
      // Key

      @ObjectModel.foreignKey.association: '_MRPPlant'
  key werks                                    as MRPPlant,

      // Control parameter

      @ObjectModel.foreignKey.association: '_MRPPlanningCalendar'      
      mrrpp                                    as MRPPlanningCalendar,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MRPControllerVH', element: 'MRPController' } } ]
      cast(fedis as pph_dispo preserving type) as MRPController,
      cslid                                    as BOMPrioritizedVersion,
      @ObjectModel.foreignKey.association: '_ReferencePlant'
      refwk                                    as ReferencePlant,
      @ObjectModel.foreignKey.association: '_OrderType'
      auart                                    as OrderType,
      @ObjectModel.foreignKey.association: '_ProcessOrderType'      
      auar2                                    as ProcessOrderType,
      cast(umthz as vdm_umthz preserving type) as ReschedulingHorizonInWorkdays,
      cast(plahz as vdm_plahz preserving type) as PlanningHorizonInWorkdays,
      lifkz                                    as ScheduleLinesCreationCode,
      cast(prreg as bmg_prreg preserving type) as ATPCheckingRule,
      kzumb                                    as StkInTransfIsAvailForPlng,
      vertr                                    as StartDateInThePastIsAllowed,
      anzls                                    as PlannedMaterialListIsCreated,
      dbepl                                    as MRPIsActiveForMRPAreasAtPlant,
      xfan1                                    as BlockedStockIsIncludedInMRP,
      cast(nfvbc as vdm_nfvbc preserving type) as RestrictedBatchStockIsIncluded,
      cast(bztek as vdm_bztek preserving type) as PurchasingProcessingDuration,
      
      // Associations

      _MRPPlant,
      _ReferencePlant,
      _MRPController,
      _MRPPlanningCalendar,
      _OrderType,
      _ProcessOrderType
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T399D"
],
"ASSOCIATED":
[
"I_MRPCONTROLLER",
"I_MRPPLANNINGPERIOD",
"I_ORDERTYPE",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More