I_LOGLPRODUCTASSGMTDCTODC

CDS View

Logistical Product DC DC Assignment

I_LOGLPRODUCTASSGMTDCTODC is a CDS View in S/4HANA. Logistical Product DC DC Assignment. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_LoglProductAssgmtDCToDC view from CONSUMPTION Logistical Product DC DC Assignment
P_AssgblReceivingDCFromDC view left_outer CONSUMPTION 
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #M
}
@AbapCatalog: {
  sqlViewName: 'ILOGLPRODASSDCDC',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@EndUserText.label: 'Logistical Product DC DC Assignment'

@VDM:
  {
    viewType: #COMPOSITE
  }

@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_LoglProductAssgmtDCToDC
  as select from I_MPPurchasingSourceItem as SourceList
    join         I_Supplier                                 on SourceList.Supplier = I_Supplier.Supplier
    join         I_Plant                  as SupplyingPlant on  I_Supplier.Supplier          = SupplyingPlant.PlantSupplier
                                                            and SupplyingPlant.PlantCategory = 'B' -- Distribution Center
    join         I_Plant                  as ReceivingPlant on  SourceList.Plant             = ReceivingPlant.Plant
                                                            and ReceivingPlant.PlantCategory = 'B' -- Distribution Center

  /* Compositional associations    */


  association [0..1] to I_Plant                   as _ReceivingDistributionCenter on $projection.ReceivingDistributionCenter = _ReceivingDistributionCenter.Plant
  association [0..1] to I_Plant                   as _SupplyingDistributionCenter on $projection.SupplyingDistributionCenter = _SupplyingDistributionCenter.Plant
  association [1..1] to I_ActiveLogisticalProduct as _ActiveLogisticalProduct     on $projection.Material = _ActiveLogisticalProduct.Product
{
  key SourceList.Material,

      @ObjectModel.foreignKey.association: '_ReceivingDistributionCenter'
  key cast(SourceList.Plant as receivingdistributioncenter preserving type)     as ReceivingDistributionCenter,

  key SourceList.SourceListRecord,


      case I_Supplier.IsBusinessPurposeCompleted
        when 'X' then '*****'
        else SourceList.Supplier
      end                                                                       as Supplier,

      @ObjectModel.foreignKey.association: '_SupplyingDistributionCenter'
      cast(SupplyingPlant.Plant as supplyingdistributioncenter preserving type) as SupplyingDistributionCenter,

      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      SourceList.PurchasingOrganization,

      cast(SourceList.ValidityStartDate as validitystartdate preserving type) as ValidityStartDate,

      cast(SourceList.ValidityEndDate as validityenddate preserving type)     as ValidityEndDate,


      SourceList.LastChangeDateTime,

      /*  Exposed associations  */
      _ReceivingDistributionCenter,
      _SupplyingDistributionCenter,
      _PurchasingOrganization,
      _ActiveLogisticalProduct
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MPPURCHASINGSOURCEITEM",
"I_PLANT",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_ACTIVELOGISTICALPRODUCT",
"I_PLANT",
"I_PURCHASINGORGANIZATION"
],
"BASE":
[
"I_MPPURCHASINGSOURCEITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More