I_LOCATION

CDS View

Location

I_LOCATION is a CDS View in S/4HANA. Location. It contains 6 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 6 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
C_PMAssetLocationVH view from CONSUMPTION Asset Location Value Help
C_PPM_ProjectElementLocationVH view from CONSUMPTION Value Help for Location
I_InternalOrderLocationVH view_entity from COMPOSITE Location
I_WorkCenterLocation view from BASIC Work Center Location
P_FixedAssetOvwLocationVH view from BASIC

Fields (6)

KeyField CDS FieldsUsed in Views
KEY Location Location,WorkCenterLocation 2
KEY Plant Plant,WorkCenterPlant 2
_Address _Address 1
_Plant _Plant 1
AddressID AddressID 2
LocationName LocationName,WorkCenterLocationName 2 
@AbapCatalog.sqlViewName: 'IPPLOCATION'
@AbapCatalog.buffering: {status: #ACTIVE, type: #FULL, numberOfKeyFields: 000}
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.privilegedAssociations: ['_Address', '_Address_2']
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY, #EXTRACTION_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
@ObjectModel.representativeKey: 'Location'
@ObjectModel.semanticKey: ['Location', 'Plant']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Location'

define view I_Location as select from t499s as loc
  association [1..1] to I_Plant     as _Plant     on  $projection.Plant     = _Plant.Plant
  association [0..1] to I_Address   as _Address   on  $projection.AddressID = _Address.AddressID
  association [0..1] to I_Address_2 as _Address_2 on  $projection.AddressID = _Address_2.AddressID
                                                  and _Address_2.AddressPersonID           = ''
                                                  and _Address_2.AddressRepresentationCode = ''
{
      @ObjectModel.text.element: ['LocationName']
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key loc.stand   as Location,
      @ObjectModel.foreignKey.association: '_Plant'
  key loc.werks   as Plant,
      @ObjectModel.foreignKey.association: '_Address'
      loc.addrnum as AddressID,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(loc.ktext as locationname preserving type) as LocationName,

      // Associations

      _Plant,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_Address_2'
      _Address,
      _Address_2
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T499S"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_ADDRESS_2",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More