I_LOCAGGREGATIONROOT

CDS View

Location Aggregation Root

I_LOCAGGREGATIONROOT is a CDS View in S/4HANA. Location Aggregation Root. It contains 8 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 8 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_EHSLocationAggregationDEX view_entity from CONSUMPTION Location Aggregation Data Extraction
I_EHSAmountsForActivity view inner COMPOSITE Amounts for Activity
I_EHSDataSet view union COMPOSITE Data Sets
I_EnvrmtAmountsForActivity view inner COMPOSITE Amounts for Activities

Fields (8)

KeyField CDS FieldsUsed in Views
KEY LocAggregationUUID EHSClassifiedDataUUID,EHSComplianceScenActivityUUID 2
_EHSDataPeriod _EHSDataPeriod 1
_EHSLocation _EHSLocation 1
DataUsagePeriodicity DataUsagePeriodicity 1
EHSLocationUUID EHSLocationUUID 3
LocAggregationID EHSComplianceScenActivityID 1
LocAggregationName EHSClassifiedDataName,EHSComplianceScenActivityName 2
LocAggregationTitle EHSClassifiedDataTitle,EHSComplianceScenActivityTitle 2 
@AbapCatalog.sqlViewName: 'IADEFROOT'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@VDM.viewType: #BASIC
@EndUserText.label: 'Location Aggregation Root'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view I_LocAggregationRoot
  as select from ehenvd_adef_root

  association [0..1] to I_UnitOfMeasure       as _UnitText    on $projection.UnitOfMeasure = _UnitText.UnitOfMeasure
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [1..1] to I_EHSLocationRevision as _EHSLocation on $projection.EHSLocationUUID     = _EHSLocation.EHSLocationUUID
                                                              and(
                                                                _EHSLocation.RevisionStartDate   <= $session.system_date
                                                                and _EHSLocation.RevisionEndDate >= $session.system_date
                                                              )
  association [0..1] to I_EHSDataPeriod as _EHSDataPeriod     on $projection.DataUsagePeriodicity = _EHSDataPeriod.EHSDataPeriod
{
  key db_key                                                              as  LocAggregationUUID,

      cast( datetime_cr as ehfnd_datetime_cr preserving type )            as  CreationDateTime,
      user_id_cr                                                          as  CreatedByUser,

      cast( datetime_ch as ehfnd_datetime_ch preserving type )            as  LastChangeDateTime,
      user_id_ch                                                          as  LastChangedByUser,

      id                                                                  as  LocAggregationID,
      
      migration_src                                                       as  LocAggregationMigrationSource,
      
      name                                                                as  LocAggregationName,
      cast ( usage_period as ehenv_adef_usage_period_nc preserving type ) as  DataUsagePeriodicity,

      @ObjectModel.foreignKey.association: '_EHSLocation'
      cast( loc_root_key_ref as ehfnd_location_uuid_ref preserving type ) as  EHSLocationUUID,
      _EHSLocation,

      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_UnitText'
      cast( unit as ehfnd_unit_code_nce preserving type )                 as  UnitOfMeasure,
      _UnitText,

      subject_type_code                                                   as  EHSSubjectType,
      subject_root_key_ref                                                as  EHSSubjectUUID,

      title                                                               as  LocAggregationTitle,
      
      cast(  aggr_cla_root_key_ref as /bobf/conf_key )                    as EHSDataClassifierUUID,
      
      _EHSDataPeriod
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHENVD_ADEF_ROOT"
],
"ASSOCIATED":
[
"I_EHSDATAPERIOD",
"I_EHSLOCATIONREVISION",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More