I_LOGLPRODUCTASSGMTDCTOSTORE

CDS View

Logistical Product DC Store Assignment

I_LOGLPRODUCTASSGMTDCTOSTORE is a CDS View in S/4HANA. Logistical Product DC Store Assignment. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_LoglProductAssgmtDCToStore view from CONSUMPTION Logistical Product DC Store Assignment
P_AssgblStoreForProcmtProdExt view left_outer CONSUMPTION
P_AssgblStoreForProcmtProdInt view left_outer CONSUMPTION 
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #S
}
@AbapCatalog: {
  sqlViewName: 'ILOGLPRODASSDCST',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@EndUserText.label: 'Logistical Product DC Store Assignment'

@VDM:
  {
    viewType: #COMPOSITE
  }

@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_LoglProductAssgmtDCToStore
  as select from I_MPPurchasingSourceItem as SourceList
    join         I_Supplier                         on SourceList.Supplier = I_Supplier.Supplier
    join         I_Plant                            on  I_Supplier.Supplier   = I_Plant.PlantSupplier
                                                    and I_Plant.PlantCategory = 'B' -- Distribution Center
    join         I_Plant                  as Plant2 on  SourceList.Plant     = Plant2.Plant
                                                    and Plant2.PlantCategory = 'A' -- Store
                                                    
left outer join P_StoreGrpFromClfnStore( P_SAPClient : $session.client)        as _AssgdStoreGroup           on Plant2.Plant = _AssgdStoreGroup.Store       

  association [0..1] to I_Plant                   as _Store                   on $projection.Store = _Store.Plant
  association [0..1] to I_Plant                   as _DistributionCenter      on $projection.DistributionCenter = _DistributionCenter.Plant
  association [1..1] to I_ActiveLogisticalProduct as _ActiveLogisticalProduct on $projection.Material = _ActiveLogisticalProduct.Product
{
  key SourceList.Material,

      @ObjectModel.foreignKey.association: '_Store'
  key cast(SourceList.Plant as store)                                         as Store,

  key SourceList.SourceListRecord,


      case I_Supplier.IsBusinessPurposeCompleted
        when 'X' then '*****'
        else SourceList.Supplier
      end                                                                     as Supplier,

      @ObjectModel.foreignKey.association: '_DistributionCenter'
      cast(I_Plant.Plant as distributioncenter)                               as DistributionCenter,

      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      SourceList.PurchasingOrganization,

      cast(SourceList.ValidityStartDate as validitystartdate preserving type) as ValidityStartDate,

      cast(SourceList.ValidityEndDate as validityenddate preserving type)     as ValidityEndDate,

      SourceList.LastChangeDateTime,
      
      _AssgdStoreGroup.StoreGroupInternalID as StoreGroupInternalID,

      /*  Exposed associations  */
      _Store,
      _DistributionCenter,
      _PurchasingOrganization,
      _ActiveLogisticalProduct
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MPPURCHASINGSOURCEITEM",
"I_PLANT",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_ACTIVELOGISTICALPRODUCT",
"I_PLANT",
"I_PURCHASINGORGANIZATION"
],
"BASE":
[
"I_MPPURCHASINGSOURCEITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More