I_JOURNALENTRYITEMONETIMEDATA
One-Time Data for Journal Entry Item
I_JOURNALENTRYITEMONETIMEDATA is a CDS View in S/4HANA. One-Time Data for Journal Entry Item. It contains 13 fields. 12 CDS views read from this table.
CDS Views using this table (12)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_StRpDocLineItemWthRefDoc | view | left_outer | CONSUMPTION | Tax Items with Reference Accounting Documents |
| I_RO_SAFTOneTimeCustomer | view | from | COMPOSITE | RO SAFT One Time Customer |
| I_RO_SAFTOneTimeSupplier | view | from | COMPOSITE | RO SAFT One Time Supplier |
| I_RO_SAFTOneTmeCustVATRegn | view | from | COMPOSITE | RO SAFT One Time Customer |
| I_RO_SAFTOneTmeSuplrVATRegn | view | from | COMPOSITE | RO SAFT One Time Supplier |
| I_SAFTAcctgOneTimeCustomer | view | inner | COMPOSITE | SAF-T Accounting OneTimeCustomers |
| I_SAFTGeneralLedgerOneTimeBP | view | inner | COMPOSITE | SAFT GLedger One Time Business Partner |
| I_SAFTGenLedgerOneTimeCustomer | view | inner | COMPOSITE | SAF-T Gen Ledger One Time Customer |
| I_SAFTGenLedgerOneTimeSupplier | view | inner | COMPOSITE | SAF-T Gen Ledger OneTimeSupplier |
| P_LU_SAFTJournalItemBP | view | inner | COMPOSITE | |
| P_RO_SAFTBSECTaxID | view | from | COMPOSITE | BSEC TaxID |
| P_StRpBillgDocSuplrInvcItem | view | left_outer | COMPOSITE |
Fields (13)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | AccountingDocument | AccountingDocument | 5 |
| KEY | AccountingDocumentItem | AccountingDocumentItem | 5 |
| KEY | CompanyCode | CompanyCode | 5 |
| KEY | FiscalYear | FiscalYear | 5 |
| AddressID | AddressID | 4 | |
| BusinessPartnerName1 | BusinessPartnerName1 | 4 | |
| CityName | CityName | 8 | |
| Country | Country | 8 | |
| POBox | POBox | 3 | |
| POBoxPostalCode | POBoxPostalCode | 3 | |
| PostalCode | PostalCode | 8 | |
| Region | Region | 8 | |
| StreetAddressName | StreetName | 4 |
@EndUserText: { label: 'One-Time Data for Journal Entry Item' }
@VDM: { viewType: #BASIC }
@Search: { searchable: false }
@AccessControl: { authorizationCheck: #PRIVILEGED_ONLY,
privilegedAssociations: ['_Address'],
personalData.blocking: #REQUIRED}
@ObjectModel: {
usageType.serviceQuality: #A,
usageType.sizeCategory: #M,
usageType.dataClass: #TRANSACTIONAL,
representativeKey: 'AccountingDocumentItem',
modelingPattern: #ANALYTICAL_DIMENSION,
supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE , #CDS_MODELING_ASSOCIATION_TARGET , #SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION ]
}
@Analytics: { internalName: #LOCAL,
technicalName: 'IJEONETIMEDATA' }
@Metadata: { ignorePropagatedAnnotations: true,
allowExtensions: true }
define view entity I_JournalEntryItemOneTimeData
as select from bsec
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_JournalEntry as _AccountingDocument on $projection.CompanyCode = _AccountingDocument.CompanyCode
and $projection.AccountingDocument = _AccountingDocument.AccountingDocument
and $projection.FiscalYear = _AccountingDocument.FiscalYear
association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear on $projection.FiscalYear = _FiscalYear.FiscalYear
and $projection.CompanyCode = _FiscalYear.CompanyCode
association [0..1] to I_Address as _Address on $projection.AddressID = _Address.AddressID
association [0..1] to I_Iban as _IBAN on $projection.BankCountry = _IBAN.BankCountry
and $projection.BankNumber = _IBAN.Bank
and $projection.BankAccount = _IBAN.BankAccount
and $projection.BankControlKey = _IBAN.BankControlKey
association [0..1] to I_Bank_2 as _Bank on $projection.BankCountry = _Bank.BankCountry
and $projection.BankNumber = _Bank.BankInternalID
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key bsec.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_AccountingDocument'
key bsec.belnr as AccountingDocument,
@ObjectModel.foreignKey.association: '_FiscalYear'
key cast( bsec.gjahr as fis_gjahr_no_conv preserving type ) as FiscalYear,
key bsec.buzei as AccountingDocumentItem,
cast(bsec.name1 as ad_name1) as BusinessPartnerName1,
cast(bsec.name2 as ad_name2) as BusinessPartnerName2,
cast(bsec.name3 as ad_name3) as BusinessPartnerName3,
cast(bsec.name4 as ad_name4) as BusinessPartnerName4,
bsec.land1 as Country,
cast(bsec.ort01 as ad_city1) as CityName,
bsec.pfach as POBox,
bsec.pstl2 as POBoxPostalCode,
bsec.pstlz as PostalCode,
bsec.stkzu as IsVATLiable,
bsec.regio as Region,
bsec.stcd1 as TaxID1,
bsec.stcd2 as TaxID2,
bsec.stcd3 as TaxID3,
bsec.stcd4 as TaxID4,
bsec.stcd5 as TaxID5,
bsec.stras as StreetAddressName,
bsec.fityp as ResponsibleType,
bsec.stcdt as TaxNumberType,
bsec.j_1kftbus as BusinessType,
bsec.j_1kftind as IndustryType,
bsec.anred as OneTimeAccountBPSalutationText,
bsec.adrnr as AddressID,
bsec.intad as AccountingClerkInternetAddress,
bsec.bankn as BankAccount,
bsec.bankl as BankNumber,
bsec.banks as BankCountry,
bsec.pskto as PostOfficeBankAccount,
bsec.payment_system as PaymentSystem,
bsec.alias_type as AliasType,
bsec.bank_alias as BPBankAccountAliasName,
@Semantics.booleanIndicator: true
cast(bsec.stkzn as bu_natural_person) as IsNaturalPerson,
bsec.xcpdk as IsOneTimeAccount,
bkont as BankControlKey,
glo_re1_ot as OneTimeAcctCntrySpecificRef1,
_CompanyCode,
_AccountingDocument,
_FiscalYear,
_Address,
_IBAN,
_Bank
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BSEC"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_BANK_2",
"I_COMPANYCODE",
"I_FISCALYEARFORCOMPANYCODE",
"I_IBAN",
"I_JOURNALENTRY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/