I_JOINTVENTUREMASTERFLD

@AbapCatalog.sqlViewName: 'IJVMSTFLD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel:{
   representativeKey: 'JointVenture',
   usageType: {
       serviceQuality: #A,
       sizeCategory: #M,
       dataClass: #MASTER
   }          }
@EndUserText.label: 'Joint Venture Master Data Fields'
@Metadata.ignorePropagatedAnnotations:true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@Analytics: {
    dataCategory: #DIMENSION
}
@Metadata.allowExtensions: true
@Analytics.internalName:#LOCAL
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE
define view I_JointVentureMasterFld
  as select from t8jv
  association [0..1] to I_CompanyCode      as _CompanyCode      on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_JointVentureDesc as _JointVentureDesc on  $projection.CompanyCode  = _JointVentureDesc.CompanyCode
                                                                and $projection.JointVenture = _JointVentureDesc.JointVenture
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key bukrs                                            as CompanyCode,
      @ObjectModel.text.association: '_JointVentureDesc'
  key cast(vname as jv_name_cds preserving type )      as JointVenture,
      payterms                                         as JointVenturePaymentTerms,
      bmethod                                          as JointVentureBillingMethod, 
      vtype                                            as JointVentureType,
      operator                                         as JointVentureOperator,
      taxcode                                          as JointVentureTaxCode,
      vclass                                           as JVAVentureClass,
      itd                                              as JntVntrInceptionToDateData,
      cruser                                           as JointVentureCreatedByUser,
      cast( crtime as jv_crtime_cds )                  as JntVntrTimeCreated,
      crdate                                           as JntVntrDateCreated,
      chuser                                           as JointVentureLastChangedByUser,

      cast( case when chtime is null or chtime = ' ' then '000000' else chtime
              end as jv_chtime_cds )                   as JntVntrTimeLastChanged,

      cast( case when chdate is null or chdate = ' ' then '00000000' else chdate
              end as jv_chdate_cds )                   as JntVntrDateLastChanged,

      bformat                                          as JntVntrBillgFormat,
      joa                                              as JntOpgAgrmt,
      vactive                                          as JntVntrBillgCutbackIsBlk,
      txjcd                                            as JntVntrTaxJurisdiction,
      outpayterm                                       as JntVntrOutPaymentTerms,
      outtaxcode                                       as JntVntrOutTaxCode,
      txjcd2                                           as JntVntrOutTaxJurisdiction,
      nbformat                                         as JntVntrNonBillgFormat,
      bfreq                                            as JntVntrBillgFrqcy,
      ovrdf                                            as JntVntrDrillingPayRate,
      ovrnd                                            as JntVntrNonDrillingPayRate,
      pcocostc                                         as JntVntrParentCoOvhdExpnCostCtr,
      cast ( pcoprojk as ps_s4_pspnr preserving type ) as JntVntrParentCoOvhdProject,
      pcoordnr                                         as JntVntrParentCoOvhdExpnOrder,
      kostl                                            as JntVntrSubstituteCostCtr,
      fundgroup                                        as JntVntrFundingGroup,
      checkfc                                          as JntVntrCrcyIsFundingCrcy,
      property                                         as JntVntrProperty,

      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_Currency'
      _CompanyCode.Currency,

      @Semantics: { amount : { currencyCode: 'Currency'} }
      billthres                                        as JntVntrBillgThldDebit,
      @Semantics: { amount : { currencyCode: 'Currency'} }
      billthresc                                       as JntVntrBillgThldCredit,
      billthresa                                       as JntVntrBillgThldIsActive,
      pschem                                           as JntVntrPaymentTermSchema,
      ic_group                                         as JVAVentureIntrstCalcGrpID,   

      _CompanyCode,
      _CompanyCode._Currency,
      _JointVentureDesc
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"T8JV"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_JOINTVENTUREDESC"
],
"BASE":
[
"I_COMPANYCODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/