I_JITOUTBCALLCOMPGRP

@EndUserText.label: 'JIT Call Component Group Outbound'
@Metadata.allowExtensions:true
@Analytics.internalName:#LOCAL
@ObjectModel.representativeKey: 'CompGrpNumber'
@ClientHandling: {
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}

@AbapCatalog: {
  sqlViewName: 'IJITCALLCGRPOUTB',
  compiler.compareFilter: true,
  preserveKey:true
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@ObjectModel: {
  usageType.dataClass: #TRANSACTIONAL,
  usageType.serviceQuality: #B,
  usageType.sizeCategory: #XL
}
@Analytics.dataCategory: #DIMENSION

define view I_JITOutbCallCompGrp
  as select from njit_call_d_cgrp
  association [1..1] to I_Product              as _ProductCompGrp       on  $projection.CompGrpMatl = _ProductCompGrp.Product

  association [0..1] to I_JITInternalStatus    as _JITInternalStatus    on  $projection.JITIntProcessingStatus = _JITInternalStatus.JITIntProcessingStatus

  association [0..1] to I_Plant                as _Plant                on  $projection.Plant = _Plant.Plant

  association [0..1] to I_ProductionSupplyArea as _ProductionSupplyArea on  $projection.ProductionSupplyArea = _ProductionSupplyArea.ProductionSupplyArea
                                                                        and $projection.Plant                = _ProductionSupplyArea.Plant


  association [0..1] to I_StorageLocation      as _StorageLocation      on  $projection.Plant           = _StorageLocation.Plant
                                                                        and $projection.StorageLocation = _StorageLocation.StorageLocation

  association [0..1] to I_JITStockTransferSts  as _JITStockTransferSts  on  $projection.JITOutbStockTransferSts = _JITStockTransferSts.JITOutbStockTransferSts
  association [1..1] to I_JITOutbCallHeader    as _JITOutbCallHeader    on  $projection.ParentDraftKey = _JITOutbCallHeader.JITHeaderUUID
                                                                        and $projection.InternalJITCallNumber = _JITOutbCallHeader.InternalJITCallNumber
{

  key db_key                     as JITCallCompGrpUUID,
  key int_call_num               as InternalJITCallNumber,
  key comp_grp_num               as CompGrpNumber,
  key parent_key                 as ParentDraftKey,
      ext_comp_grp_num           as ExtCompGrpNumber,
      @ObjectModel.foreignKey.association: '_ProductCompGrp'
      comp_grp_mat               as CompGrpMatl,
      cust_comp_grp_mat          as CustCompGrpMatl,
      ext_sequence_num           as JITExtSequenceNumber,
      ext_stat_trans             as TransmittedExtStatusByMfr,
      ext_stat                   as JITExtStatusAtSupplier,
      ext_stat_updated_on        as JITExtStatusUpdtdOn,
      int_stat                   as JITIntProcessingStatus,
      int_stat_updated_on        as JITIntStatusUpdtdOn,
      requirement_dt             as RequirementDateTime,
      supply_date_time           as JITSupplyDateTime,
      @ObjectModel.foreignKey.association: '_Plant'
      werks                      as Plant,
      cust_sup_area              as CustSupplyArea,
      ablad                      as UnloadingPointName,
      njit_call_d_cgrp.supply_cntrl               as SupplyControlID,
      njit_call_d_cgrp.supplycontroluuid          as SupplyControlUUID,
      action_cntrl               as JITActionCtrl,
      fldpo                      as CustAssemblyLoc,
      vstel                      as ShippingPoint,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      lgort                      as StorageLocation,
      planned_shipping_dt        as PlannedShippingDateTime,
      actual_shipping_dt         as ActualShippingDateTime,
      material_availability_date as MaterialAvailabilityDate,
      wldat                      as RequestedDeliveryDate,
      wluhr                      as RequestedDeliveryTime,
      ewm_lgnum                  as WarehouseNumber,
      src_lgnum                  as JITSourceWarehouseNumber,
      ledat                      as DeliveryCreationDate,
      prodn_start_date           as ProductionStartDate,
      /* Document Status Indicator */
      deli_crea_stat             as DeliveryStatus,
      pick_stat                  as PickingStatus,
      goods_mvmt_stat            as GoodsMovementStatus,
      @ObjectModel.foreignKey.association: '_JITStockTransferSts'
      stk_trnsfr_stat            as JITOutbStockTransferSts,
      control_cycle              as JITControlCycle,
      @ObjectModel.foreignKey.association: '_ProductionSupplyArea'
      prod_sup_area              as ProductionSupplyArea,
      dest_storage_loc           as JITOutbDestinationStorLoc,
      _ProductCompGrp._Text[1:Language = $session.system_language].ProductName ,
      //Associations

      _ProductCompGrp,
      _JITInternalStatus,
      _Plant,
      _ProductionSupplyArea,
      _StorageLocation,
      _JITStockTransferSts,
      _JITOutbCallHeader

}
where control_cycle is not initial
  and _JITOutbCallHeader.JITScenario = '2'
  and _JITOutbCallHeader.JITCallIsForwarded = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JITOUTBCALLHEADER",
"I_PRODUCT",
"I_PRODUCTTEXT",
"NJIT_CALL_D_CGRP"
],
"ASSOCIATED":
[
"I_JITINTERNALSTATUS",
"I_JITOUTBCALLHEADER",
"I_JITSTOCKTRANSFERSTS",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTIONSUPPLYAREA",
"I_STORAGELOCATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/