I_JITCONTROLCYCLE
Basic View for JIT Control Cycles
I_JITCONTROLCYCLE is a CDS View in S/4HANA. Basic View for JIT Control Cycles. It contains 15 fields. 13 CDS views read from this table.
CDS Views using this table (13)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_JITControlCycleVH | view | from | CONSUMPTION | Value help for Control Cycles |
| C_JITOutbControlCycleOvw | view | from | CONSUMPTION | Consumption view for control cycle overview |
| C_JITOutbSqncControlCycleVH | view_entity | from | CONSUMPTION | Control Cycle |
| I_JITCallsForCommGroupBasic | view | from | COMPOSITE | Control cycles and JIT calls for Communication groups |
| I_JITOutbCallCompGrpData | view | inner | COMPOSITE | Composite View-JIT Call CompGrp Outbound |
| I_JITOutbCallsBOMTP | view | inner | TRANSACTIONAL | Transactional View for BOM Explosion |
| I_JITOutbControlCyclePrimary | view | from | COMPOSITE | Primary Control Cycle |
| I_JITOutbControlCycleSecondary | view | from | COMPOSITE | Secondary Control Cycle |
| I_JITOutbCtrlCycBOMSchedgAgrmt | view | inner | COMPOSITE | Control Cycle BOM Scheduling agreement |
| I_JITOutbSqncCalls | view | inner | COMPOSITE | Monitor JIS calls |
| I_JITReldControlCycleVH | view | from | BASIC | Value help for Control Cycles |
| P_JITControlCycle | view | from | COMPOSITE | |
| P_JITOutBOMData | view | inner | TRANSACTIONAL | Bill of material data |
Fields (15)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | JITControlCycle | JITControlCycle | 4 |
| IssuingOrReceivingStorageLoc | IssuingOrReceivingStorageLoc | 1 | |
| JITControlCycleCategory | JITControlCycleCategory | 3 | |
| JITCtrlCycLifeCycSts | JITCtrlCycLifeCycSts | 3 | |
| JITReqQtyLowerToleranceLvl | JITReqQtyLowerToleranceLvl | 1 | |
| JITReqQtyUpperToleranceLvl | JITReqQtyUpperToleranceLvl | 1 | |
| ProductionSupplyArea | ProductionSupplyArea | 1 | |
| QuantityUnit | QuantityUnit | 1 | |
| ReplenishmentStrategy | ReplenishmentStrategy | 1 | |
| ReplnmtPlanningProcedure | ReplnmtPlanningProcedure | 1 | |
| SourceStorageBin | SourceStorageBin | 1 | |
| StorageBin | StorageBin | 1 | |
| StorageType | StorageType | 1 | |
| Supplier | Supplier | 1 | |
| SupplierName | SupplierName | 1 |
@AbapCatalog.sqlViewName: 'IJITCTRLCYC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Basic View for JIT Control Cycles'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'JITControlCycle'
@AccessControl.privilegedAssociations: ['_ProductionSupplyArea']
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_JITControlCycle
as select from pkhd
association [1..1] to I_ProductionSupplyArea as _ProductionSupplyArea on $projection.Plant = _ProductionSupplyArea.Plant
and $projection.ProductionSupplyArea = _ProductionSupplyArea.ProductionSupplyArea
// Association to fetch source supply area name
association [1..1] to I_ProductionSupplyArea as _SourceSupplyArea on $projection.Plant = _SourceSupplyArea.Plant
and $projection.SourceProductionSupplyArea = _SourceSupplyArea.ProductionSupplyArea
association [1..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [1..1] to I_Product as _Product on $projection.Material = _Product.Product
association [0..1] to I_JITCtrlCycleLifeCycleStatus as _JITCtrlCycleLifeCycleStatus on $projection.JITCtrlCycLifeCycSts = _JITCtrlCycleLifeCycleStatus.JITCtrlCycLifeCycSts
association [0..1] to I_JITCtrlCycleCategory as _JITCtrlCycleCategory on $projection.JITControlCycleCategory = _JITCtrlCycleCategory.JITControlCycleCategory
association [1..1] to I_JITOutbReplnmtStrgy as _JITOutbReplenish on $projection.Plant = _JITOutbReplenish.Plant
and $projection.ReplenishmentStrategy = _JITOutbReplenish.ReplenishmentStrategy
association [0..*] to I_MRPController as _ResponsiblePerson on $projection.Plant = _ResponsiblePerson.Plant
association [1..1] to I_Product as _JITContainer on $projection.JITContainer = _JITContainer.Product
association [0..1] to I_StorageLocation as _StorageLocation on $projection.IssuingOrReceivingStorageLoc = _StorageLocation.StorageLocation
and $projection.Plant = _StorageLocation.Plant
association [0..1] to I_JITOutbCallProfile as _JITOutbCallProfile on $projection.JITCallProfile = _JITOutbCallProfile.JITCallProfile
association [0..1] to I_JITActionCtrl as _JITActionCtrl on $projection.JITActionCtrl = _JITActionCtrl.JITActionCtrl
association [0..1] to I_UserContactCard as _LastChangedByUser on $projection.LastChangedByUserName = _LastChangedByUser.ContactCardID
association [0..1] to I_JITOutbPlngProcedure as _JITPlngProcedure on $projection.ReplnmtPlanningProcedure = _JITPlngProcedure.JITPlanningProcedure
association [0..1] to I_JITOutbCommunicationGroup as _JITCommunicationGroup on $projection.JITOutbCommunicationGroup = _JITCommunicationGroup.JITOutbCommunicationGroup
association [0..1] to I_JITSupplyControlHeader as _JITSupplyControlHeader on $projection.SupplyControlID = _JITSupplyControlHeader.SupplyControlID
{
//PKHD
key pknum as JITControlCycle,
lcm_status as JITCtrlCycLifeCycSts,
werks as Plant,
matnr as Material,
behmg as JITContainerQuantityInBsUnt,
meins as QuantityUnit,
prvbe as ProductionSupplyArea,
jit_stck_transfer_repl_strat as ReplenishmentStrategy,
ablad as StoringPositionName,
lgnum as WarehouseNumber, //ERP Wno.
nlpla as StorageBin, //EWM storage bin
cast('' as abap.char(5)) as StorageType,
cast('' as abap.char(40)) as StorageTypeName,
vlpla as SourceStorageBin,
qupvb as SourceProductionSupplyArea,
jit_ext_proc_repl_strat as ExtProcurementReplnmtStrgy,
@Semantics.systemDate.createdAt: true
cre_date as JITCtrlCycleCreationDate,
@Semantics.businessDate.at: true
rls_date as JITCtrlCycleReleaseDate,
obs_date as LockDate,
release_time as JITCtrlCycleReleaseTime,
lock_time as JITCtrlCycleLockTime,
@Semantics.user.lastChangedBy: true
lastchange_user as LastChangedByUserName,
anzlt as NumberOfLoadCarriers,
pkbht as JITContainer,
@Semantics.systemDateTime.lastChangedAt: true
lastchange_datetime as LastChangeDateTime,
umlgo as IssuingOrReceivingStorageLoc,
pkste as InHouseProductionReplnmtStrgy,
pabprf as JITCallProfile,
jit_action_control as JITActionCtrl,
repl_qty_lower_tolerance_lvl as Threshold,
supl_qty_upper_tolerance_lvl as JITReqQtyUpperToleranceLvl,
supl_qty_lower_tolerance_lvl as JITReqQtyLowerToleranceLvl,
@Semantics.unitOfMeasure: true
cast(' % ' as abap.unit(3)) as HundredInPercent,
// (cast ( repl_qty_lower_tolerance_lvl * behmg as abap.fltp(16)) / 100.00 ) as MinimumQuantityVolume,
(cast ( division(repl_qty_lower_tolerance_lvl * behmg,100,3) as abap.dec(13,3))) as MinimumQuantityVolume,
partial_gr_allowed_ind as IsPartiallyDelivered,
max_number_open_calls as MaxNumberOfOpenJITCalls,
kwbzd as ReplnmtLeadTimeInWorkdays,
cast(kwbzm as abap.dec(11)) as ReplnmtLeadTimeInHoursAndMins,
rksta as JITControlCycleCategory,
cast( '0' as int4 ) as NumberOfActiveJITCalls,
// RequestedDeliveryDateTime denotes the Demand Date and Time
// The below fields are to store the oData response
cast(0000 as abap.dec(15,0)) as RequestedDeliveryDateTime,
cast(0000 as njit_supply_date_time ) as JITSupplyDateTime,
cast('' as njit_immediate_req) as JITCallImmediateRequest,
cast('' as njit_priority_type) as JITCallPriorityType,
cast('' as lprio) as JITCallPriorityID,
//Planning parameters
plng_procedure as ReplnmtPlanningProcedure,
cast(plng_horizon as abap.dec(11)) as PlanningHorizonTime,
min_stock as MinimumStockQuantity,
safety_time_in_days as ReplnmtSafetyTimeInDays,
cast(safety_time_in_minutes as abap.dec(11)) as ReplnmtSafetyTimeInMins,
communication_group as JITOutbCommunicationGroup,
_JITCommunicationGroup.JITOutbCommunicationGroupDesc as JITOutbCommunicationGroupDesc,
_JITCommunicationGroup.Supplier as Supplier,
_JITCommunicationGroup._Supplier.SupplierName as SupplierName,
// @DefaultAggregation: #NONE // non-summable format
cast(offset_from_start_of_prodn as abap.dec(11)) as JITProdnOffstInHoursAndMins,
cast(cast(div(mod(ceil(div(kwbzm,100)),100)+60*ceil(div(kwbzm,10000)),60) as kwbz_min) as abap.char(30)) as ReplnmtLeadTimeInHours,
cast(cast(mod(mod(ceil(div(kwbzm,100)),100)+60*ceil(div(kwbzm,10000)),60) as kwbz_min) as abap.char(30)) as ReplnmtLeadTimeInMinutes,
_ProductionSupplyArea.StorageLocation as StorageLocation,
_ProductionSupplyArea.UnloadingPointName as UnloadingPointName,
jit_fwdng_rlvnce as JITIsForwardingRelevant,
jit_supplycontrolid as SupplyControlID,
//kitzd as TransferTimeInDays,
cast(kitzm as abap.dec(11)) as TransferTimeDuration,
jit_receiving_point as GoodsReceivingPoint,
//Associations
_ProductionSupplyArea,
_Plant,
_Product,
_JITCtrlCycleLifeCycleStatus,
_ResponsiblePerson,
_JITContainer,
_StorageLocation,
_JITOutbReplenish,
_JITOutbCallProfile,
_JITCtrlCycleCategory,
_JITActionCtrl,
_JITPlngProcedure,
_SourceSupplyArea,
_JITCommunicationGroup,
// _JITOutbStorageBin,
_LastChangedByUser,
_JITSupplyControlHeader
}
where
rksta = 'J'
or rksta = 'Q'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JITOUTBCOMMUNICATIONGROUP",
"I_PRODUCTIONSUPPLYAREA",
"I_SUPPLIER",
"PKHD"
],
"ASSOCIATED":
[
"I_JITACTIONCTRL",
"I_JITCTRLCYCLECATEGORY",
"I_JITCTRLCYCLELIFECYCLESTATUS",
"I_JITOUTBCALLPROFILE",
"I_JITOUTBCOMMUNICATIONGROUP",
"I_JITOUTBPLNGPROCEDURE",
"I_JITOUTBREPLNMTSTRGY",
"I_JITSUPPLYCONTROLHEADER",
"I_MRPCONTROLLER",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTIONSUPPLYAREA",
"I_STORAGELOCATION",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/