I_INVOICELISTITEM

CDS View

Invoice List Item

I_INVOICELISTITEM is a CDS View in S/4HANA. Invoice List Item. It contains 12 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 12 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_InvoiceListItemObjPg view from CONSUMPTION
I_InvoiceListRemuneration view from BASIC Invoice List Remuneration
P_SAFT_BillDocOnInvoiceList view from COMPOSITE

Fields (12)

KeyField CDS FieldsUsed in Views
KEY BillingDocument BillingDocument 2
KEY InvoiceList InvoiceList 3
KEY InvoiceListItem InvoiceListItem 2
_BillingDocument _BillingDocument 1
_SoldToParty _SoldToParty 1
GrossAmount GrossAmount 1
NetAmount NetAmount 2
RemunerationNetAmount RemunerationNetAmount 2
RemunerationTaxAmount RemunerationTaxAmount 1
SoldToParty SoldToParty 1
TaxAmount TaxAmount 1
TransactionCurrency TransactionCurrency 2 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'InvoiceListItem'
@Analytics.dataCategory: #DIMENSION
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AbapCatalog: {
  sqlViewName: 'ISDINVOICELISTIT',
  preserveKey: true 
}
@EndUserText.label: 'Invoice List Item'
@Metadata.allowExtensions: true

define view I_InvoiceListItem
  as select from vbrl
  //Association


  association [1..1] to I_InvoiceList     as _InvoiceList         on $projection.InvoiceList = _InvoiceList.InvoiceList
  association [0..1] to I_BillingDocument as _BillingDocument     on $projection.BillingDocument = _BillingDocument.BillingDocument
  association [0..1] to I_Currency        as _TransactionCurrency on $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_Customer        as _SoldToParty         on $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_LogicalSystem   as _LogicalSystem       on $projection.LogicalSystem = _LogicalSystem.LogicalSystem
{
      //Key

      @Consumption.valueHelpDefinition: [ 
      { entity:  { name:    'I_InvoiceListStdVH',
                   element: 'InvoiceList' }
      }]    
      @ObjectModel.foreignKey.association: '_InvoiceList'
  key vbeln                                                   as InvoiceList,
  key posnr                                                   as InvoiceListItem,

      //Billing

      //--[ GENERATED:012:GlBfhyJl7kY4v5RWfCiSf0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BillingDocumentStdVH',
                     element: 'BillingDocument' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_BillingDocument'
      vbeln_vf                                                as BillingDocument,

      //Pricing

      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      netwr                                                   as NetAmount,
      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      mwsbp                                                   as TaxAmount,
      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(netwr + mwsbp + kwert_rl + mwsbp_rl as brtwert_rl) as GrossAmount,

      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      kwert_rl                                                as RemunerationNetAmount,
      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      mwsbp_rl                                                as RemunerationTaxAmount,

      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      _BillingDocument.TransactionCurrency                    as TransactionCurrency,
      uvprs                                                   as PricingIsIncomplete,

      //Sales

      //--[ GENERATED:012:GlBfhyJl7kY4v5RWfCiSf0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Customer_VH',
                     element: 'Customer' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_SoldToParty'
      kunag                                                   as SoldToParty,

      //Admin

      @ObjectModel.foreignKey.association: '_LogicalSystem'
      logsys                                                  as LogicalSystem,

      //Association

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _InvoiceList,
      _BillingDocument,
      _TransactionCurrency,
      _SoldToParty,
      _LogicalSystem

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENT",
"VBRL"
],
"ASSOCIATED":
[
"I_BILLINGDOCUMENT",
"I_CURRENCY",
"I_CUSTOMER",
"I_INVOICELIST",
"I_LOGICALSYSTEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More