I_INSURANCEPOLICYPREMPAYER

CDS View

Premium Payer in Insurance Policy

I_INSURANCEPOLICYPREMPAYER is a CDS View in S/4HANA. Premium Payer in Insurance Policy. It contains 19 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 19 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_InsurCust360PremPyr view from COMPOSITE Grundsicht zum Abrufen Details des FS-PM-Prämienzahlers
R_InsurancePolicyPremPayerTP view_entity from TRANSACTIONAL Premium Payer in Insurance Policy - TP

Fields (19)

KeyField CDS FieldsUsed in Views
KEY InsurPlcyContrPremPayerID InsurPlcyContrPremPayerID 1
KEY InsurPlcyInsurContr InsurPlcyInsurContr 1
KEY InsurPlcyUUID InsurPlcyUUID 1
AddressID AddressID 1
BankIdentification BankIdentification 1
CAPaymentMethod CAPaymentMethod 1
InsurPlcyCollectionType InsurPlcyCollectionType 1
InsurPlcyJrnlEndNmbr InsurPlcyJrnlEndNmbr 1
InsurPlcyJrnlNmbr InsurPlcyJrnlNmbr 1
InsurPlcyPremiumCurrency InsurPlcyPremiumCurrency 1
InsurPlcyPremiumPayerID InsurPlcyPremiumPayerID 1
InsurPlcyPremiumPayerTemplate InsurPolicyPremiumPayerControl 1
InsurPlcyPremPayerShareAmount InsurPlcyPremPayerShareAmount 1
InsurPlcyPremPayerSharePercent InsurPlcyPremPayerSharePercent 1
InsurPlcyPremPyrRmngAmtIsAssgd InsurPlcyPremPyrRmngAmtIsAssgd 1
InsurPlcyProductPackageID InsurPolicyContractPackageID 1
LastChangeDateTime LastChangeDateTime 1
PaymentCardID PaymentCardID 1
SEPAMandate SEPAMandate 1 
@EndUserText.label: 'Premium Payer in Insurance Policy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_BusinessPartner',
                              '_Address']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyContrPremPayerID',
   semanticKey: [ 'InsurPlcyPremiumPayerID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcyPremPyr'
}

define view entity I_InsurancePolicyPremPayer
  as select from I_InsurPlcyPremPayerBasic as PremPayer

  association        to parent I_InsuranceContract as _InsuranceContract       on  $projection.InsurPlcyUUID       = _InsuranceContract.InsurPlcyUUID
                                                                               and $projection.InsurPlcyInsurContr = _InsuranceContract.InsurPlcyInsurContr

  association [1..1] to I_Currency                 as _Currency                on  $projection.InsurPlcyPremiumCurrency = _Currency.Currency
  association [1..1] to I_InsurancePolicy          as _InsurancePolicy         on  $projection.InsurPlcyUUID = _InsurancePolicy.InsurPlcyUUID

  association [1..*] to I_InsurPlcyTemplateT       as _InsurPlcyTemplateT      on  $projection.InsurPlcyPremiumPayerTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [0..1] to I_Address                  as _Address                 on  $projection.AddressID = _Address.AddressID
  association [0..1] to I_BusinessPartner          as _BusinessPartner         on  $projection.InsurPlcyPremiumPayerID = _BusinessPartner.BusinessPartner

  association [0..*] to I_CAPaymentMethodText      as _CAPaymentMethodText     on  $projection.CAPaymentMethod  = _CAPaymentMethodText.CAPaymentMethod
                                                                               and $projection.InsurPlcyCountry = _CAPaymentMethodText.Country
  association [1..1] to I_InsurPlcyCollectionType  as _InsurPlcyCollectionType on  $projection.InsurPlcyCollectionType = _InsurPlcyCollectionType.InsurPlcyCollectionType

{

  key PremPayer.InsurPlcyUUID,
  key PremPayer.InsurPlcyInsurContr,
  key PremPayer.InsurPlcyContrPremPayerID,
      PremPayer.InsurPlcyJrnlNmbr,
      PremPayer.InsurPlcyJrnlEndNmbr,
      PremPayer.InsurPlcyProductPackageID,
      @ObjectModel.foreignKey.association: '_Address'
      PremPayer.AddressID,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      @ObjectModel.sapObjectNodeTypeReference: 'BusinessPartner'
      PremPayer.InsurPlcyPremiumPayerID,
      PremPayer.BankIdentification,
      PremPayer.PaymentCardID,
      @ObjectModel.text.association: '_CAPaymentMethodText'
      @ObjectModel.sapObjectNodeTypeReference: 'ContrAcctgPaymentMethod'
      PremPayer.CAPaymentMethod,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      // @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'

      PremPayer.InsurPlcyPremiumPayerTemplate,
      PremPayer.SEPAMandate,
      @Semantics.systemDateTime.lastChangedAt: true
      PremPayer.LastChangeDateTime,
      _InsuranceContract.InsurPlcyCountry as InsurPlcyCountry,
      @ObjectModel.text.association: '_InsurPlcyCollectionType'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyCollectionType'
      PremPayer.InsurPlcyCollectionType,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      PremPayer.InsurPlcyPremPayerShareAmount,
      PremPayer.InsurPlcyPremPayerSharePercent,
      PremPayer.InsurPlcyPremPyrRmngAmtIsAssgd,
      @ObjectModel.foreignKey.association: '_Currency'
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      PremPayer.InsurPlcyPremiumCurrency,

      /* Associations */
      _InsurancePolicy,
      _InsuranceContract,
      _BusinessPartner,
      _Address,
      _Currency,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _CAPaymentMethodText,
      @Consumption.hidden: true
      _InsurPlcyCollectionType

}
where
      PremPayer.InsurPlcyJrnlEndNmbr    = 2147483647
  and PremPayer.InsurPlcyBusinessObject = 'P'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURANCECONTRACT",
"I_INSURPLCYPREMPAYERBASIC"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_BUSINESSPARTNER",
"I_CAPAYMENTMETHODTEXT",
"I_CURRENCY",
"I_INSURANCECONTRACT",
"I_INSURANCEPOLICY",
"I_INSURPLCYCOLLECTIONTYPE",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More