I_INSURPLCYSURCHARGEDISCBASIC

@EndUserText.label: 'Surcharge Discount in Insurance Policy'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcySurchargeDiscID',
   semanticKey: [ 'InsurPlcySurchargeDiscID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
}
@Metadata.allowExtensions: true
@Analytics: {
  technicalName: 'IPSurchrgDiscBsc'
}

define view entity I_InsurPlcySurchargeDiscBasic
  as select from /pm0/abdasupdc as SurchargeDiscount

  association [1..1] to I_Currency as _Currency on $projection.InsurPlcySurchrgDiscCurrency = _Currency.Currency

{

  key cast( SurchargeDiscount.policy_id as /pm0/vdm_policy_uuid preserving type )           as InsurPlcyUUID,
  key SurchargeDiscount.policyproduct_id                                                    as InsurPlcyInsurContr,
  key SurchargeDiscount.covpac_id                                                           as InsurPlcyCoveragePackageID,
  key SurchargeDiscount.coverage_id                                                         as InsurPlcyCoverageID,
  key SurchargeDiscount.subject_id                                                          as InsurPlcyInsuredObjectID,
  key SurchargeDiscount.supdc_id                                                            as InsurPlcySurchargeDiscID,
  key cast( SurchargeDiscount.journalno_id as /pm0/vdm_journal_number_id preserving type )  as InsurPlcyJrnlNmbr,
  key SurchargeDiscount.journalendno_id                                                     as InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      SurchargeDiscount.ppdpac_id                                                           as InsurPlcyProductPackageID,
      cast( SurchargeDiscount.pm_id as /pm0/vdm_surchrg_template_code preserving type )     as InsurPlcySurchrgDiscTemplate,
      @Semantics.businessDate.from: true
      cast( SurchargeDiscount.premfactbeg_dt as /pm0/vdm_supdc_start_date preserving type ) as InsurPlcySurchargeDiscStrtDate,
      @Semantics.businessDate.to: true
      cast( SurchargeDiscount.premfactend_dt as /pm0/vdm_supdc_end_date preserving type )   as InsurPlcySurchargeDiscEndDate,
      SurchargeDiscount.premfactor_vl                                                       as InsurPlcySurchrgDiscBaseAmtPct,
      @Semantics.amount.currencyCode: 'InsurPlcySurchrgDiscCurrency'
      SurchargeDiscount.amount_am                                                           as InsurPlcySurchargeDiscAmount,
      SurchargeDiscount.premfactcalc_cd                                                     as InsurPlcySurchrgDiscAmtType,
      SurchargeDiscount.premfactunit_cd                                                     as InsurPlcySurchrgDiscAmtUnit,
      SurchargeDiscount.premfact_cd                                                         as InsurPlcySurchargeDiscTypeID,
      @ObjectModel.foreignKey.association: '_Currency'
      SurchargeDiscount.currency_id                                                         as InsurPlcySurchrgDiscCurrency,
      @Consumption.hidden: true
      SurchargeDiscount.bo_cd                                                               as InsurPlcyBusinessObject,
      @Semantics.systemDateTime.lastChangedAt: true
      SurchargeDiscount.change_ts                                                           as LastChangeDateTime,

      _Currency

}
where
      covcp_id = 0
  and uwdcn_id = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/PM0/ABDASUPDC"
],
"ASSOCIATED":
[
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/