I_INSURPLCYDCBLAMOUNTUNIT

CDS View

Deductible Amount Unit in Insur Policy

I_INSURPLCYDCBLAMOUNTUNIT is a CDS View in S/4HANA. Deductible Amount Unit in Insur Policy. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_InsurPlcyDcblAmountUnitLink view_entity from BASIC Link to Dcbl Amt Unit in Insur Plcy 
@EndUserText.label: 'Deductible Amount Unit in Insur Policy'
@ObjectModel:{
    representativeKey: 'InsurPlcyDeductibleAmountUnit',
    sapObjectNodeType.name: 'InsurPlcyDeductibleAmountUnit',
    usageType: {
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #CUSTOMIZING
    },
    modelingPattern: #ANALYTICAL_DIMENSION,
    resultSet.sizeCategory: #XS,
    supportedCapabilities: [#ANALYTICAL_DIMENSION,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #EXTRACTION_DATA_SOURCE,
                            #SEARCHABLE_ENTITY,
                            #SQL_DATA_SOURCE]
}
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck:#NOT_REQUIRED
@Analytics: {
  technicalName: 'IPDcblAmtUnit',
  dataCategory: #DIMENSION,
  dataExtraction.enabled: true,
  internalName: #LOCAL
}
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true

define root view entity I_InsurPlcyDcblAmountUnit
  as select from /pm0/abucibctcha as Characteristics
    inner join   /pm0/abupdedct on  /pm0/abupdedct.list_id         = Characteristics.list_id
                                and Characteristics.application_id = 'POLICY'
                                and Characteristics.state_cd       = '3' // Released

                                and Characteristics.markname       = 'DEDUCTIBLETYP_CD'

  composition [0..*] of I_InsurPlcyDcblAmountUnitT   as _Text

  association [0..1] to I_InsurPolicyProductTemplate as _InsurPlcyTemplate        on $projection.InsurPlcyDeductibleTemplate = _InsurPlcyTemplate.InsurPlcyTemplate
  association [0..1] to I_InsurPlcyDcblAmtUnitList   as _InsurPlcyDcblAmtUnitList on $projection.InsurPlcyTemplateCharcsList = _InsurPlcyDcblAmtUnitList.InsurPlcyTemplateCharcsList

{

      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @ObjectModel.text.association: '_Text'
  key /pm0/abupdedct.deductibletyp_cd as InsurPlcyDeductibleAmountUnit,
      @ObjectModel.foreignKey.association: '_InsurPlcyDcblAmtUnitList'
  key /pm0/abupdedct.list_id          as InsurPlcyTemplateCharcsList,
      @ObjectModel.foreignKey.association: '_InsurPlcyTemplate'
  key Characteristics.template_id     as InsurPlcyDeductibleTemplate,

      _Text,
      _InsurPlcyTemplate,
      _InsurPlcyDcblAmtUnitList

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/PM0/ABUCIBCTCHA",
"/PM0/ABUPDEDCT"
],
"ASSOCIATED":
[
"I_INSURPLCYDCBLAMOUNTUNITT",
"I_INSURPLCYDCBLAMTUNITLIST",
"I_INSURPOLICYPRODUCTTEMPLATE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More