I_INSPECTIONRESULT
Summarized Insp Result for an Insp Charc
I_INSPECTIONRESULT is a CDS View in S/4HANA. Summarized Insp Result for an Insp Charc. It contains 66 fields. 16 CDS views read from this table.
CDS Views using this table (16)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_InspCharcMltplRsltRec | view | left_outer | CONSUMPTION | Insp Charac for Mltpl Rslt Recording |
| C_InspResultMltplRsltRec | view | left_outer | CONSUMPTION | Recorded Results for Mltpl Rslt Rec |
| C_Qm_Charsresults | view | left_outer | CONSUMPTION | Characteristic list of record results |
| C_QM_InspCharInfo | view | left_outer | CONSUMPTION | Characteristic details- More information |
| I_InspCharacteristicAggregate | view | left_outer | COMPOSITE | Aggregation on inspection characteristic level |
| I_InspCharQuantitativeCube | view | from | COMPOSITE | Chracteristics Analytics - Quantitative Analysis |
| I_InspectionCharacteristicFact | view | left_outer | COMPOSITE | Inspection Characteristic Fact |
| I_InspectionResultHistory | view | from | COMPOSITE | Inspection Result History |
| I_InspectionResultTP | view | from | TRANSACTIONAL | Summarized Insp Result for an Insp Charc |
| I_MfgInspCharcHistory | view | inner | COMPOSITE | Inspection Characteristic History |
| I_MfgOrdPlanInspCharInfo | view | left_outer | COMPOSITE | Order PIC Info |
| P_Inspcharresultdet_Wo_Smpl | view | left_outer | COMPOSITE | |
| P_MfgInspCharcResultAll | view_entity | inner | COMPOSITE | Insp Charcs Recording Results |
| P_MPEOrdILOperOpenCharcCount | view_entity | left_outer | CONSUMPTION | Number of Open Characteristics in Inspection Lot Operation |
| P_MPEOrdInspLotOpenCharcCount | view_entity | left_outer | CONSUMPTION | Number of Open Characteristics in Inspection Lot |
| R_InspectionResultTP | view_entity | from | TRANSACTIONAL | Inspection Result TP |
Fields (66)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | InspectionCharacteristic | InspectionCharacteristic | 5 |
| KEY | InspectionLot | InspectionLot | 3 |
| KEY | InspPlanOperationInternalID | InspPlanOperationInternalID | 5 |
| _CharcAttributeCode | _CharcAttributeCode | 1 | |
| _CharcAttributeCodeGrp | _CharcAttributeCodeGrp | 1 | |
| _InspectionResultAttribute | _InspectionResultAttribute | 1 | |
| _InspectionValuationResult | _InspectionValuationResult | 1 | |
| ChangedDateTime | ChangedDateTime | 2 | |
| ChangedTime | ChangedTime | 2 | |
| CharacteristicAttributeCatalog | CharacteristicAttributeCatalog | 2 | |
| CharacteristicAttributeCode | CharacteristicAttributeCode | 5 | |
| CharacteristicAttributeCodeGrp | CharacteristicAttributeCodeGrp | 5 | |
| CharcAttributeCodeVers | CharcAttributeCodeVers | 1 | |
| CreatedByUser | CreatedByUser | 5 | |
| CreationDate | CreationDate | 5 | |
| CreationTime | CreationTime | 4 | |
| DefectClass | DefectClass | 1 | |
| InspectionEndDate | InspectionEndDate | 2 | |
| InspectionEndTime | InspectionEndTime | 2 | |
| InspectionNumberOfDefects | InspectionNumberOfDefects | 1 | |
| InspectionPartialSampleSize | InspectionPartialSampleSize | 2 | |
| InspectionResultAttribute | InspectionResultAttribute | 3 | |
| InspectionResultCatalog2 | InspectionResultCatalog2 | 2 | |
| InspectionResultCatalog3 | InspectionResultCatalog3 | 2 | |
| InspectionResultCatalog4 | InspectionResultCatalog4 | 2 | |
| InspectionResultCatalog5 | InspectionResultCatalog5 | 2 | |
| InspectionResultCode2 | InspectionResultCode2 | 2 | |
| InspectionResultCode2Vers | InspectionResultCode2Vers | 1 | |
| InspectionResultCode3 | InspectionResultCode3 | 2 | |
| InspectionResultCode3Vers | InspectionResultCode3Vers | 1 | |
| InspectionResultCode4 | InspectionResultCode4 | 2 | |
| InspectionResultCode4Vers | InspectionResultCode4Vers | 1 | |
| InspectionResultCode5 | InspectionResultCode5 | 2 | |
| InspectionResultCode5Vers | InspectionResultCode5Vers | 1 | |
| InspectionResultCodeGroup2 | InspectionResultCodeGroup2 | 2 | |
| InspectionResultCodeGroup3 | InspectionResultCodeGroup3 | 2 | |
| InspectionResultCodeGroup4 | InspectionResultCodeGroup4 | 2 | |
| InspectionResultCodeGroup5 | InspectionResultCodeGroup5 | 2 | |
| InspectionResultHasLongText | InspectionResultHasLongText | 2 | |
| InspectionResultHasMeanValue | InspectionResultHasMeanValue | 3 | |
| InspectionResultMaximumValue | InspectionResultMaximumValue | 3 | |
| InspectionResultMeanValue | InspectionResultMeanValue | 5 | |
| InspectionResultMinimumValue | InspectionResultMinimumValue | 3 | |
| InspectionResultOrigin | InspectionResultOrigin | 2 | |
| InspectionResultOriginalValue | InspectionResultOriginalValue | 3 | |
| InspectionResultStatus | InspectionResultStatus | 2 | |
| InspectionResultText | InspectionResultText | 3 | |
| InspectionStartDate | InspectionStartDate | 2 | |
| InspectionStartTime | InspectionStartTime | 2 | |
| InspectionValuationResult | InspectionValuationResult | 5 | |
| Inspector | Inspector | 4 | |
| InspResultDynModifValuation | InspResultDynModifValuation | 1 | |
| InspResultHasMaximumValue | InspResultHasMaximumValue | 2 | |
| InspResultHasMinimumValue | InspResultHasMinimumValue | 2 | |
| InspResultNmbrOfRecordedRslts | InspResultNmbrOfRecordedRslts | 1 | |
| InspResultNrOfAddlDcmlsPlaces | InspResultNrOfAddlDcmlsPlaces | 1 | |
| InspResultValidValuesNumber | InspResultValidValuesNumber | 5 | |
| InspResultVariance | InspResultVariance | 3 | |
| InspRsltAboveToleranceFraction | InspRsltAboveToleranceFraction | 3 | |
| InspRsltAboveToleranceValsNmbr | InspRsltAboveToleranceValsNmbr | 3 | |
| InspRsltBelowToleranceFraction | InspRsltBelowToleranceFraction | 3 | |
| InspRsltBelowToleranceValsNmbr | InspRsltBelowToleranceValsNmbr | 3 | |
| InspRsltFreeDefinedTestEquip | InspRsltFreeDefinedTestEquip | 2 | |
| InspRsltNonconformingValsNmbr | InspRsltNonconformingValsNmbr | 3 | |
| LastChangeDate | LastChangeDate | 2 | |
| LastChangedByUser | LastChangedByUser | 3 |
@AbapCatalog.sqlViewName: 'IINSPRESULT'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Summarized Insp Result for an Insp Charc'
@VDM: {
viewType: #BASIC,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
[ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.usageType: {
dataClass: #TRANSACTIONAL,
sizeCategory: #L,
serviceQuality: #B
}
@ObjectModel.representativeKey: 'InspectionCharacteristic'
@Metadata.ignorePropagatedAnnotations: true
define view I_InspectionResult
as select from qamr
association [1..1] to I_InspectionLot as _InspectionLot on $projection.InspectionLot = _InspectionLot.InspectionLot
association [1..1] to I_InspectionOperation as _InspectionOperation on $projection.InspectionLot = _InspectionOperation.InspectionLot
and $projection.InspPlanOperationInternalID = _InspectionOperation.InspPlanOperationInternalID
association [1..1] to I_InspectionCharacteristic as _InspectionCharacteristic on $projection.InspectionLot = _InspectionCharacteristic.InspectionLot
and $projection.InspPlanOperationInternalID = _InspectionCharacteristic.InspPlanOperationInternalID
and $projection.InspectionCharacteristic = _InspectionCharacteristic.InspectionCharacteristic
association [0..1] to I_CharcAttributeCodeGrp as _CharcAttributeCodeGrp on $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCodeGrp.CharacteristicAttributeCodeGrp
association [0..1] to I_CharcAttributeCode as _CharcAttributeCode on $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCode.CharacteristicAttributeCodeGrp
and $projection.CharacteristicAttributeCode = _CharcAttributeCode.CharacteristicAttributeCode
association [0..1] to I_InspectionResultStatus as _InspectionResultStatus on $projection.InspectionResultStatus = _InspectionResultStatus.InspectionResultStatus
association [0..1] to I_InspectionResultAttribute as _InspectionResultAttribute on $projection.InspectionResultAttribute = _InspectionResultAttribute.InspectionResultAttribute
association [0..1] to I_InspectionResultOrigin as _InspectionResultOrigin on $projection.InspectionResultOrigin = _InspectionResultOrigin.InspectionResultOrigin
association [0..1] to I_InspectionValuationResult as _InspectionValuationResult on $projection.InspectionValuationResult = _InspectionValuationResult.InspectionValuationResult
association [0..1] to I_InspectionValuationResult as _InspResultDynModifValuation on $projection.InspResultDynModifValuation = _InspResultDynModifValuation.InspectionValuationResult
association [0..*] to I_InspResultLongText as _InspResultLongText on $projection.InspectionLot = _InspResultLongText.InspectionLot
and $projection.InspPlanOperationInternalID = _InspResultLongText.InspPlanOperationInternalID
and $projection.InspectionCharacteristic = _InspResultLongText.InspectionCharacteristic
//Extension
association [1..1] to E_InspectionResult as _Extension //Ignore "_Extension is not used because of Guideline !
on $projection.InspectionLot = _Extension.InspectionLot
and $projection.InspPlanOperationInternalID = _Extension.InspPlanOperationInternalID
and $projection.InspectionCharacteristic = _Extension.InspectionCharacteristic
{
//--[ GENERATED:012:GlBfhyFV7jY4iHvp9{5ddW
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_InspectionLotStdVH',
element: 'InspectionLot' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_InspectionLot'
key qamr.prueflos as InspectionLot,
//--[ GENERATED:012:GlBfhyFV7jY4iHvp9{5ddW
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_InspectionOperationStdVH',
element: 'InspPlanOperationInternalID' },
additionalBinding: [{ localElement: 'InspectionLot',
element: 'InspectionLot' }]
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_InspectionOperation'
key qamr.vorglfnr as InspPlanOperationInternalID,
@ObjectModel.foreignKey.association: '_InspectionCharacteristic'
key qamr.merknr as InspectionCharacteristic,
qamr.pruefer as Inspector,
@ObjectModel.foreignKey.association: '_InspectionResultStatus'
qamr.satzstatus as InspectionResultStatus,
case qamr.kzbewertg when '+' then cast('X' as vdm_inspres_completion_forced preserving type )
when '.' then cast('X' as vdm_inspres_completion_forced preserving type )
when '/' then cast('X' as vdm_inspres_completion_forced preserving type )
else cast('' as vdm_inspres_completion_forced preserving type )
end as InspResultIsCompletionForced,
@ObjectModel.foreignKey.association: '_InspectionResultAttribute'
qamr.attribut as InspectionResultAttribute, // Attribute at header leve - Single/Summary
@ObjectModel.foreignKey.association: '_InspectionResultOrigin'
qamr.qergdath as InspectionResultOrigin,
@ObjectModel.foreignKey.association: '_InspectionValuationResult'
qamr.mbewertg as InspectionValuationResult, //Valuation displayed at char header level
@ObjectModel.foreignKey.association: '_InspResultDynModifValuation'
qamr.dbewertg as InspResultDynModifValuation,
qamr.mittelwert as InspectionResultMeanValue, //Mean value, single/Summary at header level
cast(case qamr.mittelwni when '*' then 'X' else qamr.mittelwni end as qninitial preserving type ) as InspectionResultHasMeanValue,
qamr.maxwert as InspectionResultMaximumValue, //Maximum value, single/Summary at header level
cast(case qamr.maxwertni when '*' then 'X' else qamr.maxwertni end as qninitial preserving type ) as InspResultHasMaximumValue,
qamr.minwert as InspectionResultMinimumValue, //Minimum value, single/Summary at header level
cast(case qamr.minwertni when '*' then 'X' else qamr.minwertni end as qninitial preserving type ) as InspResultHasMinimumValue,
qamr.original_input as InspectionResultOriginalValue, //Original value for result record type summary
qamr.anzwertg as InspResultValidValuesNumber,
qamr.iststpumf as InspResultNmbrOfRecordedRslts,
cast( qamr.pruefbemkt as vdm_qinspectionresultdesc preserving type ) as InspectionResultText,
qamr.prltextkz as InspectionResultHasLongText,
qamr.ltextspr as Language,
//--[ GENERATED:012:GlBfhyFV7jY4iHvp9{5ddW
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CharcAttributeCodeGrpStdVH',
element: 'CharacteristicAttributeCodeGrp' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_CharcAttributeCodeGrp'
qamr.gruppe1 as CharacteristicAttributeCodeGrp,
//--[ GENERATED:012:GlBfhyFV7jY4iHvp9{5ddW
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CharcAttributeCodeStdVH',
element: 'CharacteristicAttributeCode' },
additionalBinding: [{ localElement: 'CharacteristicAttributeCodeGrp',
element: 'CharacteristicAttributeCodeGrp' }]
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_CharcAttributeCode'
qamr.code1 as CharacteristicAttributeCode,
qamr.version1 as CharcAttributeCodeVers,
qamr.maschine as InspRsltFreeDefinedTestEquip,
qamr.anzwertu as InspRsltBelowToleranceValsNmbr,
qamr.anzwerto as InspRsltAboveToleranceValsNmbr,
qamr.anzfehleh as InspRsltNonconformingValsNmbr,
qamr.anzfehler as InspectionNumberOfDefects,
qamr.anteilo as InspRsltAboveToleranceFraction,
qamr.anteilu as InspRsltBelowToleranceFraction,
qamr.varianz as InspResultVariance,
cast(case qamr.varianzni when '*' then 'X' else qamr.varianzni end as vdm_varianzni preserving type) as InspResultHasVariance,
qamr.katalgart1 as CharacteristicAttributeCatalog,
qamr.katalgart2 as InspectionResultCatalog2,
qamr.katalgart3 as InspectionResultCatalog3,
qamr.katalgart4 as InspectionResultCatalog4,
qamr.katalgart5 as InspectionResultCatalog5,
qamr.code2 as InspectionResultCode2,
qamr.code3 as InspectionResultCode3,
qamr.code4 as InspectionResultCode4,
qamr.code5 as InspectionResultCode5,
qamr.version2 as InspectionResultCode2Vers,
qamr.version3 as InspectionResultCode3Vers,
qamr.version4 as InspectionResultCode4Vers,
qamr.version5 as InspectionResultCode5Vers,
qamr.gruppe2 as InspectionResultCodeGroup2,
qamr.gruppe3 as InspectionResultCodeGroup3,
qamr.gruppe4 as InspectionResultCodeGroup4,
qamr.gruppe5 as InspectionResultCodeGroup5,
qamr.fehlklas as DefectClass,
qamr.iststpanz as InspectionPartialSampleSize,
qamr.pruefdatuv as InspectionStartDate,
qamr.pruefzeitv as InspectionStartTime,
cast( qamr.pruefdatub as vdm_qpruefdatb preserving type ) as InspectionEndDate,
qamr.pruefzeitb as InspectionEndTime,
@Semantics.user.createdBy: true
qamr.ersteller as CreatedByUser,
@Semantics.systemDate.createdAt: true
qamr.erstelldat as CreationDate,
@Semantics.user.lastChangedBy: true
qamr.aenderer as LastChangedByUser,
@Semantics.systemDate.lastChangedAt: true
qamr.aenderdat as LastChangeDate,
case qamr.changeddatetime
when 0 then cast( '19000101010101' as tzntstmps )
else qamr.changeddatetime end as ChangedDateTime,
qamr.zeitaend as ChangedTime,
qamr.zeiterstl as CreationTime,
qamr.diff_dec_places as InspResultNrOfAddlDcmlsPlaces,
// Associations
_InspectionLot,
_InspectionOperation,
_InspectionCharacteristic,
_CharcAttributeCodeGrp,
_CharcAttributeCode,
_InspectionResultStatus,
_InspectionResultAttribute,
_InspectionResultOrigin,
_InspectionValuationResult,
_InspResultDynModifValuation,
_InspResultLongText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QAMR"
],
"ASSOCIATED":
[
"E_INSPECTIONRESULT",
"I_CHARCATTRIBUTECODE",
"I_CHARCATTRIBUTECODEGRP",
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULTATTRIBUTE",
"I_INSPECTIONRESULTORIGIN",
"I_INSPECTIONRESULTSTATUS",
"I_INSPECTIONVALUATIONRESULT",
"I_INSPRESULTLONGTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/