I_INSPECTIONCODETEXT

CDS View

Inspection Code - Text

I_INSPECTIONCODETEXT is a CDS View in S/4HANA. Inspection Code - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_WrntyDefectCodeText view from COMPOSITE Defect code for warranty - Text 
@AbapCatalog.sqlViewName: 'IINSPCODETEXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Code - Text'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'InspectionCode'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities: 
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT ]
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #CUSTOMIZING }
@Metadata.ignorePropagatedAnnotations: true
define view I_InspectionCodeText
  as select from qpct
  association [1..1] to I_Inspectioncatalog   as _InspectionCatalog   on  $projection.InspectionCatalog = _InspectionCatalog.InspectionCatalog
  association [1..1] to I_InspectionCodeGroup as _InspectionCodeGroup on  $projection.InspectionCatalog   = _InspectionCodeGroup.InspectionCatalog
                                                                      and $projection.InspectionCodeGroup = _InspectionCodeGroup.InspectionCodeGroup
  association [1..1] to I_InspectionCode      as _InspectionCode      on  $projection.InspectionCatalog   = _InspectionCode.InspectionCatalog
                                                                      and $projection.InspectionCodeGroup = _InspectionCode.InspectionCodeGroup
                                                                      and $projection.InspectionCode      = _InspectionCode.InspectionCode
{
      @ObjectModel.foreignKey.association: '_InspectionCatalog'
  key katalogart as InspectionCatalog,
      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionCodeGroupStdVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'InspectionCatalog',
                                element: 'InspectionCatalog' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_InspectionCodeGroup'
  key codegruppe as InspectionCodeGroup,
      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionCodeStdVH',
                     element: 'InspectionCode' },
          additionalBinding: [{ localElement: 'InspectionCatalog',
                                element: 'InspectionCatalog' },
                              { localElement: 'InspectionCodeGroup',
                                element: 'InspectionCodeGroup' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_InspectionCode'
  key code       as InspectionCode,
      @Semantics.language: true
  key sprache    as Language,
      @Semantics.text: true
      cast( kurztext as vdm_qtxt_code preserving type )  as InspectionCodeText,

      // Associations

      _InspectionCatalog,
      _InspectionCodeGroup,
      _InspectionCode
}                
 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QPCT"
],
"ASSOCIATED":
[
"I_INSPECTIONCATALOG",
"I_INSPECTIONCODE",
"I_INSPECTIONCODEGROUP"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More