I_INSPMETHINSPSPEC

CDS View

Master Charcs. of Inspection Method

I_INSPMETHINSPSPEC is a CDS View in S/4HANA. Master Charcs. of Inspection Method. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_InspMethInspSpecTP view from TRANSACTIONAL Master Charcs. of Inspection Method 
@AbapCatalog.sqlViewName: 'IIMETHDISPEC'
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Master Charcs. of Inspection Method'
@VDM.viewType: #COMPOSITE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
}
@Metadata.ignorePropagatedAnnotations: true

define view I_InspMethInspSpec as select from I_InspSpecificationVersion 
  inner join I_AssgmtInspMethInspSpec 
        on    I_InspSpecificationVersion.InspectionSpecification = I_AssgmtInspMethInspSpec.InspectionSpecification
          and I_InspSpecificationVersion.InspectionSpecificationPlant = I_AssgmtInspMethInspSpec.InspectionSpecificationPlant
          and I_InspSpecificationVersion.InspectionSpecificationVersion = I_AssgmtInspMethInspSpec.InspectionSpecificationVersion
          and I_AssgmtInspMethInspSpec.InspectionMethodPlant    <> ' '
          and I_AssgmtInspMethInspSpec.InspectionMethod         <> ' '
          and I_AssgmtInspMethInspSpec.InspectionMethodVersion  <> ' '

{
   key I_AssgmtInspMethInspSpec.InspectionMethod,
   key I_AssgmtInspMethInspSpec.InspectionMethodPlant,
   key I_AssgmtInspMethInspSpec.InspectionMethodVersion,
   key I_InspSpecificationVersion.InspectionSpecification,
   @ObjectModel.foreignKey.association: '_InspSpecificationPlant'
   key I_InspSpecificationVersion.InspectionSpecificationPlant,
   key I_InspSpecificationVersion.InspectionSpecificationVersion,
   
   @ObjectModel.foreignKey.association: '_InspSpecCharcType'
   I_InspSpecificationVersion.InspSpecCharacteristicType,
   @ObjectModel.foreignKey.association: '_InspSpecStatus'
   I_InspSpecificationVersion.InspectionSpecificationStatus,
   case I_InspSpecificationVersion.InspectionSpecificationStatus
    /* 'Neutral' is reflected by 0, 'Negative' is reflected by 1, the value 'Critical' by 2, and the value 'Positive' by 3.*/
     when '2' then 3 // 2=Released --> 3=Positive

     when '1' then 2 // 1=Being Created --> 2=Critical

     when '3' then 1 // 3=Can no longer be used --> 1=Negative                                                                                                      

     else 0 
   end as InspSpecStatusCriticality,
   
   /* Associations */
   I_InspSpecificationVersion._Text                      as _InspSpecVersionText,
   I_InspSpecificationVersion._InspSpecificationPlant    as _InspSpecificationPlant,
   I_InspSpecificationVersion._InspSpecCharcType         as _InspSpecCharcType,
   I_InspSpecificationVersion._InspSpecStatus            as _InspSpecStatus,
   I_AssgmtInspMethInspSpec._InspectionMethodVersion     as _InspectionMethodVersion
   
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSGMTINSPMETHINSPSPEC",
"I_INSPSPECIFICATIONVERSION"
],
"ASSOCIATED":
[
"I_INSPECTIONMETHODVERSION",
"I_INSPECTIONMSTRDATASTATUS",
"I_INSPSPECCHARCTYPE",
"I_INSPSPECIFICATIONVERSIONTEXT",
"I_PLANT"
],
"BASE":
[
"I_ASSGMTINSPMETHINSPSPEC",
"I_INSPSPECIFICATIONVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More