I_GLACCOUNTTEXT

CDS View

General Ledger Account - Text

I_GLACCOUNTTEXT is a CDS View in S/4HANA. General Ledger Account - Text. It contains 5 fields. 10 CDS views read from this table.

Used by 10 CDS view(s) 5 fields

CDS Views using this table (10)

ViewTypeJoinVDMDescription
A_GLAccountText view from BASIC API General Ledger Account Text
C_BalanceAuditTrailAccount view inner CONSUMPTION
C_InventoryGLAcctBalCube view left_outer CONSUMPTION Turkey Inventory CDS cube view
C_PE_GLAcctHierarchyInCoCode view left_outer CONSUMPTION Acc. Ctrl. for Jrnl Entry Item Cube View
C_ReconAccountTextVHTemp view from CONSUMPTION
I_GlAccountTextInCompanycode view from BASIC G/L Account in Company Code - Text
I_PH_CASCashItemCube view left_outer COMPOSITE CAS Cash Item Cube
I_PRAGLAccountText view from BASIC PRA General Ledger Account - Text
P_CN_AlternativeGLAccountText view from COMPOSITE
P_CnsldtnGLAccountT view from COMPOSITE

Fields (5)

KeyField CDS FieldsUsed in Views
KEY GLAccount GLAccount 2
KEY Language Language 4
ChartOfAccounts ChartOfAccounts 2
GLAccountLongName GLAccountLongName 2
GLAccountName GLAccountName 3 
@EndUserText.label: 'General Ledger Account - Text'
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFIGLACCOUNTT'
@ObjectModel.entityChangeStateId: 'LastChangeDateTime'
@ObjectModel.representativeKey: 'GLAccount'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
//@AbapCatalog.buffering.status: #ACTIVE

//@AbapCatalog.buffering.type: #FULL

//@AbapCatalog.buffering.numberOfKeyFields: 1

//@AccessControl.authorizationCheck: #NOT_REQUIRED

@AccessControl.authorizationCheck: #CHECK
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
//--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

@AccessControl.privilegedAssociations: ['_ChartOfAccountsText']
// ]--GENERATED

@AbapCatalog.preserveKey:true
@Search.searchable: true
@ObjectModel.supportedCapabilities:[#CDS_MODELING_DATA_SOURCE,#LANGUAGE_DEPENDENT_TEXT]
define view I_GLAccountText
  as select from skat //P_GLAcctInDefaultLanguageText


  //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

  association [0..*] to I_ChartOfAccountsText as _ChartOfAccountsText on $projection.ChartOfAccounts = _ChartOfAccountsText.ChartOfAccounts
  // ]--GENERATED

  association [0..1] to I_Language            as _Language            on $projection.Language = _Language.Language

  association [0..1] to I_ChartOfAccounts     as _ChartOfAccounts     on $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts

{
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ChartOfAccountsStdVH',
                     element: 'ChartOfAccounts' }
        }]
      @ObjectModel.text.association: '_ChartOfAccountsText'
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ChartOfAccounts' //Inserted by VDM CDS Suite Plugin

  key ktopl           as ChartOfAccounts,
      @ObjectModel.text.element: 'GLAccountLongName'
  key saknr           as GLAccount,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language' //Inserted by VDM CDS Suite Plugin

  key spras           as Language, //as Language

      @Semantics.text: true
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
      cast( txt20 as fis_txt20_skat_20 preserving type ) as GLAccountName,
      @Semantics.text: true
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
      cast( txt50 as fis_txt50_skat preserving type ) as GLAccountLongName,

      last_changed_ts as LastChangeDateTime,

      _Language,
      _ChartOfAccounts,
      
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.hidden: true
      _ChartOfAccountsText
      // ]--GENERATED


}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SKAT"
],
"ASSOCIATED":
[
"I_CHARTOFACCOUNTS",
"I_CHARTOFACCOUNTSTEXT",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More