I_FUNDEDPROGRAMHIERARCHYTEXT

CDS View

Funded Program Hierarch - Text

I_FUNDEDPROGRAMHIERARCHYTEXT is a CDS View in S/4HANA. Funded Program Hierarch - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_FundedProgramHierarchyText view from CONSUMPTION Funded Program Hierarchy Text 
@EndUserText.label: 'Funded Program Hierarch - Text'
@ObjectModel.representativeKey: 'FundedProgramHierarchy'
//@Analytics: { dataExtraction.enabled: true }

@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFUNDEDPHT'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL
}

define view I_FundedProgramHierarchyText
  as select from hrrp_directoryt
    inner join   hrrp_node on  hrrp_directoryt.hryid    = hrrp_node.hryid
                           and hrrp_directoryt.hryver   = hrrp_node.hryver
                           and hrrp_directoryt.hryvalto = hrrp_node.hryvalto
                           and hrrp_node.nodetype       = 'R'

  association [1..*] to I_FinancialManagementAreaText as _FinancialManagementAreaText on $projection.FinancialManagementArea = _FinancialManagementAreaText.FinancialManagementArea

  association [1..1] to I_FinancialManagementArea     as _FinMgmtArea                 on $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea

  association [0..1] to I_Language                    as _Language                    on $projection.Language = _Language.Language

{
        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_FinMgmtAreaStdVH',
                       element: 'FinancialManagementArea' }
          }]
        @ObjectModel.foreignKey.association: '_FinMgmtArea'
  key   cast(hrrp_node.nodecls as fikrs )                        as FinancialManagementArea,
  key   cast(hrrp_directoryt.hryid as fmis_hryid_fundedprogram ) as FundedProgramHierarchy,

        @Semantics.businessDate.to: true
  key   hrrp_directoryt.hryvalto                                 as ValidityEndDate,
        @Semantics.language
  key   spras                                                    as Language,
        @Semantics.businessDate.from: true
        hrrp_directoryt.hryvalfrom                               as ValidityStartDate,
        @Semantics.text
        hrytxt                                                   as FundedProgramHierarchyName,
        _FinancialManagementAreaText,
        _Language,
        _FinMgmtArea


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIRECTORYT",
"HRRP_NODE"
],
"ASSOCIATED":
[
"I_FINANCIALMANAGEMENTAREA",
"I_FINANCIALMANAGEMENTAREATEXT",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More