I_FIXEDASSETDEPRAREA

CDS View

Fixed Asset Depreciation

I_FIXEDASSETDEPRAREA is a CDS View in S/4HANA. Fixed Asset Depreciation. It contains 31 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 31 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_FixedAssetDeprAreaTP view from COMPOSITE Transactional View Fixed Asset Depreciation Areas
P_AssetValuationForLedger view from COMPOSITE
P_RS_TaxDeprFixedAssetFields view inner COMPOSITE

Fields (31)

KeyField CDS FieldsUsed in Views
KEY AssetRealDepreciationArea AssetDepreciationArea,AssetRealDepreciationArea 2
KEY CompanyCode CompanyCode 2
KEY FixedAsset FixedAsset 2
KEY MasterFixedAsset MasterFixedAsset 2
KEY ValidityEndDate ValidityEndDate 2
AcqnProdnCostScrapPercent AcqnProdnCostScrapPercent 2
AssetOpgReadinessDate AssetOpgReadinessDate 1
AssetRevaluation AssetRevaluation 1
DepreciationAreaCurrency DepreciationAreaCurrency 1
DepreciationAreaIsDactvtd DepreciationAreaIsDactvtd 1
DepreciationKey DepreciationKey 2
DepreciationStartDate DepreciationStartDate 2
DeprKeyChangeoverPeriod DeprKeyChangeoverPeriod 2
DeprKeyChangeoverYear DeprKeyChangeoverYear 2
GroupFixedAsset GroupFixedAsset 1
GroupMasterFixedAsset GroupMasterFixedAsset 1
InterestCalcStartDate InterestCalcStartDate 1
InvestmentSupportMeasure InvestmentSupportMeasure 2
NegativeAmountIsAllowed NegativeAmountIsAllowed 1
OriglAstUsefulLifeInPerds OriglAstUsefulLifeInPerds 2
OriglAstUsefulLifeInYears OriglAstUsefulLifeInYears 2
PlannedUsefulLifeInPeriods PlannedUsefulLifeInPeriods 2
PlannedUsefulLifeInYears PlannedUsefulLifeInYears 2
ReplacementValueIndexSers ReplacementValueIndexSers 2
RplcmtValueAgingIndexSers RplcmtValueAgingIndexSers 2
ScrapAmountInCoCodeCrcy ScrapAmountInCoCodeCrcy 1
SpecialDeprStartDate SpecialDeprStartDate 2
ValidityStartDate ValidityStartDate 2
VariableDeprPercent VariableDeprPercent 2
VintageMonth VintageMonth 2
VintageYear VintageYear 2 
@AbapCatalog: {sqlViewName: 'IFASSETDEPR', preserveKey: true}
@Analytics: { dataCategory: #DIMENSION }
@EndUserText.label: 'Fixed Asset Depreciation'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'AssetRealDepreciationArea',
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MASTER }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions: true}

/*************************************************/
/*!!! Do not use any longer !!!                  */
/* Deprecated with CE1911.                       */
/* Substitute view is: I_AssetValuationForLedger */
/*************************************************/
define view I_FixedAssetDeprArea
  as select from P_FixedAssetDeprArea

  association [0..1] to I_CompanyCode                  as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_MasterFixedAsset             as _MasterFixedAsset          on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                     and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
  association [1..1] to I_FixedAsset                   as _FixedAsset                on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                                     and $projection.FixedAsset       = _FixedAsset.FixedAsset
                                                                                     and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
  association [0..1] to I_RealDepreciationAreaByCoCode as _RealDepreciationArea      on  $projection.CompanyCode               = _RealDepreciationArea.CompanyCode
                                                                                     and $projection.AssetRealDepreciationArea = _RealDepreciationArea.AssetRealDepreciationArea
  association [0..1] to I_Currency                     as _Currency                  on  $projection.DepreciationAreaCurrency = _Currency.Currency
  association [0..1] to I_ReplacementValueIndexSers    as _ReplacementValueIndexSers on  $projection.ReplacementValueIndexSers = _ReplacementValueIndexSers.ReplacementValueIndexSers

{
            @ObjectModel.foreignKey.association: '_CompanyCode'
            @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
  key       CompanyCode,
            @ObjectModel.foreignKey.association: '_MasterFixedAsset'
            @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MasterFixedAssetStdVH', element: 'MasterFixedAsset' },
                                                  additionalBinding:  [ { localElement: 'CompanyCode', element: 'CompanyCode' } ]
                                              } ]
  key       MasterFixedAsset,
            @ObjectModel.foreignKey.association: '_FixedAsset'
            @Consumption.valueHelpDefinition: [ { entity: { name: 'I_FixedAssetStdVH', element: 'FixedAsset' },
                                                  additionalBinding:  [ { localElement: 'CompanyCode', element: 'CompanyCode' },
                                                                        { localElement: 'MasterFixedAsset', element: 'MasterFixedAsset' } ]
                                              } ]
  key       FixedAsset,
  key       AssetRealDepreciationArea,
            @Semantics.businessDate.to: true
  key       ValidityEndDate_anlb           as ValidityEndDate,

            @Semantics.businessDate.from: true
            cast('19000101' as adatu)      as ValidityStartDate,

            DepreciationStartDate,
            SpecialDeprStartDate,
            InterestCalcStartDate,
            @ObjectModel.foreignKey.association: '_ReplacementValueIndexSers'
            ReplacementValueIndexSers,
            RplcmtValueAgingIndexSers,
            @Semantics.currencyCode: true
            @ObjectModel: { foreignKey.association: '_Currency'}
            _RealDepreciationArea.Currency as DepreciationAreaCurrency,
            OriglAstUsefulLifeInYears,
            GroupMasterFixedAsset,
            @Semantics.businessDate.at: true
            AssetOpgReadinessDate,
            NegativeAmountIsAllowed,
            DepreciationAreaIsDactvtd,
            AssetRevaluation,
            InvestmentSupportMeasure,
            DeprKeyChangeoverYear,
            DeprKeyChangeoverPeriod,
            VintageMonth,
            @Semantics.calendar.year: true
            VintageYear,
            OriglAstUsefulLifeInPerds,
            GroupFixedAsset,

            DepreciationKey_anlb           as DepreciationKey,
            PlannedUsefulLifeInYears_anlb  as PlannedUsefulLifeInYears,
            PlndUsefulLifeInPeriods_anlb   as PlannedUsefulLifeInPeriods,
            VariableDeprPercent_anlb       as VariableDeprPercent,
            @DefaultAggregation: #NONE
            @Semantics.amount.currencyCode: 'DepreciationAreaCurrency'
            ScrapAmountInCoCodeCrcy_anlb   as ScrapAmountInCoCodeCrcy,
            AcqnProdnCostScrapPercent_anlb as AcqnProdnCostScrapPercent,

            @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
            _FixedAsset,

            _CompanyCode,
            _MasterFixedAsset,
            _RealDepreciationArea,
            _Currency,
            _ReplacementValueIndexSers
}
where
  ValidityEndDate_anlbza is null

union all select from P_FixedAssetDeprArea

association [0..1] to I_CompanyCode                  as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_MasterFixedAsset             as _MasterFixedAsset          on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                   and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
association [1..1] to I_FixedAsset                   as _FixedAsset                on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                                   and $projection.FixedAsset       = _FixedAsset.FixedAsset
                                                                                   and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
association [0..1] to I_RealDepreciationAreaByCoCode as _RealDepreciationArea      on  $projection.CompanyCode               = _RealDepreciationArea.CompanyCode
                                                                                   and $projection.AssetRealDepreciationArea = _RealDepreciationArea.AssetRealDepreciationArea
association [0..1] to I_Currency                     as _Currency                  on  $projection.DepreciationAreaCurrency = _Currency.Currency
association [0..1] to I_ReplacementValueIndexSers    as _ReplacementValueIndexSers on  $projection.ReplacementValueIndexSers = _ReplacementValueIndexSers.ReplacementValueIndexSers
{
            @ObjectModel.foreignKey.association: '_CompanyCode'
            @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
  key       CompanyCode,
            @ObjectModel.foreignKey.association: '_MasterFixedAsset'
            @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MasterFixedAssetStdVH', element: 'MasterFixedAsset' },
                                                  additionalBinding:  [ { localElement: 'CompanyCode', element: 'CompanyCode' } ]
                                              } ]
  key       MasterFixedAsset,
            @ObjectModel.foreignKey.association: '_FixedAsset'
            @Consumption.valueHelpDefinition: [ { entity: { name: 'I_FixedAssetStdVH', element: 'FixedAsset' },
                                                  additionalBinding:  [ { localElement: 'CompanyCode', element: 'CompanyCode' },
                                                                        { localElement: 'MasterFixedAsset', element: 'MasterFixedAsset' } ]
                                              } ]
  key       FixedAsset,
  key       AssetRealDepreciationArea,
            @Semantics.businessDate.to: true
  key       ValidityEndDate_anlbza         as ValidityEndDate,

            @Semantics.businessDate.from: true
            ValidityStartDate_anlbza       as ValidityStartDate,

            DepreciationStartDate,
            SpecialDeprStartDate,
            InterestCalcStartDate,
            @ObjectModel.foreignKey.association: '_ReplacementValueIndexSers'
            ReplacementValueIndexSers,
            RplcmtValueAgingIndexSers,
            @Semantics.currencyCode: true
            @ObjectModel: { foreignKey.association: '_Currency'}
            _RealDepreciationArea.Currency as DepreciationAreaCurrency,
            OriglAstUsefulLifeInYears,
            GroupMasterFixedAsset,
            @Semantics.businessDate.at: true
            AssetOpgReadinessDate,
            NegativeAmountIsAllowed,
            DepreciationAreaIsDactvtd,
            AssetRevaluation,
            InvestmentSupportMeasure,
            DeprKeyChangeoverYear,
            DeprKeyChangeoverPeriod,
            VintageMonth,
            @Semantics.calendar.year: true
            VintageYear,
            OriglAstUsefulLifeInPerds,
            GroupFixedAsset,

            DepreciationKey_anlbza         as DepreciationKey,
            PlndUsefulLifeInYears_anlbza   as PlannedUsefulLifeInYears,
            PlndUsefulLifeInPeriods_anlbza as PlannedUsefulLifeInPeriods,
            VariableDeprPercent_anlbza     as VariableDeprPercent,
            @DefaultAggregation: #NONE
            @Semantics.amount.currencyCode: 'DepreciationAreaCurrency'
            ScrapAmountInCoCodeCrcy_anlbza as ScrapAmountInCoCodeCrcy,
            AcqnProdnCostScrapPrcnt_anlbza as AcqnProdnCostScrapPercent,

            @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
            _FixedAsset,

            _CompanyCode,
            _MasterFixedAsset,
            _RealDepreciationArea,
            _Currency,
            _ReplacementValueIndexSers
}
where
  ValidityEndDate_anlbza is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REALDEPRECIATIONAREABYCOCODE",
"P_FIXEDASSETDEPRAREA"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_FIXEDASSET",
"I_MASTERFIXEDASSET",
"I_REALDEPRECIATIONAREABYCOCODE",
"I_REPLACEMENTVALUEINDEXSERS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More