I_FISCALCALYEARPERIODFORCOCODE

CDS View

Fiscal Year Period for Company Code

I_FISCALCALYEARPERIODFORCOCODE is a CDS View in S/4HANA. Fiscal Year Period for Company Code. It contains 6 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 6 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
fmlv_ckmlcr_compat view inner Compatibility View for CKMLCR
I_AccrSubobjItmWthPerdcAmounts view from COMPOSITE Accrual Subobject Item with Periodic Amounts
P_FiscalPeriodDateForPlant view inner COMPOSITE
P_PROJCOTMERNGEWTHSPCLPERD view from COMPOSITE

Fields (6)

KeyField CDS FieldsUsed in Views
KEY CompanyCode CompanyCode 2
KEY FiscalPeriod poper 1
KEY FiscalYear bdatj 1
KEY FiscalYearPeriod FiscalYearPeriod 1
FiscalPeriodEndDate FiscalPeriodEndDate 1
FiscalPeriodStartDate FiscalPeriodStartDate 2 
@AbapCatalog.sqlViewName: 'IFIFCFYPERDCC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC

@ObjectModel: { usageType.serviceQuality: #A,
                usageType.sizeCategory: #L,
                usageType.dataClass: #CUSTOMIZING,
                representativeKey: 'FiscalYearPeriod',
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE],
                modelingPattern: #ANALYTICAL_DIMENSION }   
@AccessControl.authorizationCheck: #NOT_REQUIRED

//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics: { dataCategory: #DIMENSION }

@EndUserText.label: 'Fiscal Year Period for Company Code'

define view I_FiscalCalYearPeriodForCoCode as select from P_FiscalYearPeriod inner join  I_CompanyCode 
                                                       on P_FiscalYearPeriod.fiscal_year_variant = I_CompanyCode.FiscalYearVariant

association [0..1] to I_CompanyCode               as _CompanyCode on  $projection.CompanyCode       = _CompanyCode.CompanyCode
association [0..1] to I_FiscalYearVariant         as _FiscalYearVariant on  $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_FiscalYearForCompanyCode  as _FiscalYear  on  $projection.FiscalYear        = _FiscalYear.FiscalYear
                                                                 and $projection.CompanyCode        = _FiscalYear.CompanyCode  
association [0..*] to I_FiscalPeriodForCoCodeText as _Text        on  $projection.CompanyCode       = _Text.CompanyCode
                                                                 and $projection.FiscalYear         = _Text.FiscalYear
                                                                 and $projection.FiscalPeriod       = _Text.FiscalPeriod

{

      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_CompanyCode'      
key cast( I_CompanyCode.CompanyCode as fis_bukrs preserving type ) as CompanyCode,
key P_FiscalYearPeriod.fiscal_year_period as FiscalYearPeriod,
@ObjectModel.foreignKey.association: '_FiscalYear'      
    P_FiscalYearPeriod.fiscal_year as FiscalYear,
@ObjectModel.text.association: '_Text'
    P_FiscalYearPeriod.fiscal_period as FiscalPeriod,

@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
    P_FiscalYearPeriod.fiscal_year_variant as FiscalYearVariant,


//@ObjectModel.foreignKey.association: '_FiscalPeriodStartDate'      

    P_FiscalYearPeriod.fiscal_period_start_date       as FiscalPeriodStartDate,
    P_FiscalYearPeriod.fiscal_period_end_date         as FiscalPeriodEndDate,
    
    P_FiscalYearPeriod.is_special_period              as IsSpecialPeriod,
    
    P_FiscalYearPeriod.fiscal_year_start_date         as FiscalYearStartDate,
    P_FiscalYearPeriod.fiscal_year_end_date           as FiscalYearEndDate,
       
   
    _CompanyCode,
    _FiscalYearVariant,
    
    _FiscalYear,
    _Text 
           
}

                   
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"P_FISCALYEARPERIOD"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_FISCALPERIODFORCOCODETEXT",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARVARIANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More