I_FISCCALENDARDATEFORCOMPCODE

CDS View

Fiscal Calendar Date For Company Code

I_FISCCALENDARDATEFORCOMPCODE is a CDS View in S/4HANA. Fiscal Calendar Date For Company Code. It contains 2 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 2 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
P_FiscalPeriodStart view from COMPOSITE
P_PeriodTypeByFiscalYearPeriod view left_outer COMPOSITE
P_RblsItmForKeyDteRepPeriod view from COMPOSITE

Fields (2)

KeyField CDS FieldsUsed in Views
KEY CalendarDate CalendarDate 1
KEY CompanyCode CompanyCode 1 
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IFIFCCLNDARDTCC'
@AbapCatalog.compiler.compareFilter: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Fiscal Calendar Date For Company Code'
@VDM.viewType: #BASIC

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'CalendarDate'
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics: { dataCategory: #DIMENSION }

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
define view I_FiscCalendarDateForCompCode as select from I_FiscalCalendarDate inner join  I_CompanyCode 
                                                    on   I_FiscalCalendarDate.FiscalYearVariant = I_CompanyCode.FiscalYearVariant

association [0..1] to I_CompanyCode          as _CompanyCode  on  $projection.CompanyCode       = _CompanyCode.CompanyCode
association [0..*] to I_FiscalYearPeriodText as _Text         on  $projection.FiscalYearVariant = _Text.FiscalYearVariant
                                                              and $projection.FiscalYear        = _Text.FiscalYear
                                                              and $projection.FiscalPeriod      = _Text.FiscalPeriod

{
 
//@ObjectModel.foreignKey.association: '_CalendarDate'      

key I_FiscalCalendarDate.CalendarDate,
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_CompanyCode'      
key cast( I_CompanyCode.CompanyCode as fis_bukrs preserving type ) as CompanyCode,

@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
    I_FiscalCalendarDate.FiscalYearVariant,    
    
    FiscalYear,
    FiscalYearStartDate,
    FiscalYearEndDate,

@ObjectModel.text.association: '_Text'
    FiscalPeriod,
    FiscalPeriodStartDate,
    FiscalPeriodEndDate,
    
    FiscalQuarter,
    FiscalQuarterStartDate,
    FiscalQuarterEndDate,
    
    FiscalWeek,
    FiscalWeekStartDate,
    FiscalWeekEndDate,
     
    FiscalYearPeriod,
    FiscalYearQuarter,  
    FiscalYearWeek,

    FiscalYearConsecutiveNumber,
    FiscalPeriodConsecutiveNumber,
    FiscalQuarterConsecutiveNumber,
    FiscalWeekConsecutiveNumber,
    
    I_FiscalCalendarDate._FiscalYearVariant,
    _CompanyCode,
    _CalendarDate,
    _Text
    
}            

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_FISCALCALENDARDATE"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_COMPANYCODE",
"I_FISCALYEARPERIODTEXT",
"I_FISCALYEARVARIANT"
],
"BASE":
[
"I_FISCALCALENDARDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More