I_FINANCIALSTATEMENTHIERT

CDS View

Financial Statement Hierarchy - Text

I_FINANCIALSTATEMENTHIERT is a CDS View in S/4HANA. Financial Statement Hierarchy - Text. It contains 1 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 1 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_EntProjControllingAreaVH view left_outer CONSUMPTION Controlling Area Value Help

Fields (1)

KeyField CDS FieldsUsed in Views
FinancialStmntHierarchyName FinancialStmntHierarchyName 1 
@AbapCatalog.sqlViewName: 'IFISTMTHERT'
@AbapCatalog.buffering.status: #NOT_ALLOWED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Financial Statement Hierarchy - Text'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'FinancialStatementHierarchy'
@ObjectModel.dataCategory: #TEXT
@Consumption.filter.businessDate.at: true
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE ]
@Analytics.dataExtraction.enabled: true
define view I_FinancialStatementHierT
  as select from hrrp_dirt_n
  association [0..1] to I_Language               as _Language  on  $projection.Language = _Language.Language
  association [0..1] to I_FinancialStatementHier as _Hierarchy on  $projection.FinancialStatementHierarchy = _Hierarchy.FinancialStatementHierarchy
                                                               and $projection.ValidityEndDate             = _Hierarchy.ValidityEndDate // Hierarchy directory and hierarchy nodes have the same time slice


{
  key  hrrp_dirt_n.hryid_42 as FinancialStatementHierarchy,
       @Semantics.businessDate.to: true
  key  hryvalto             as ValidityEndDate,
       @ObjectModel.foreignKey.association: '_Language'
       @Semantics.language: true
  key  spras                as Language,
       @Semantics.businessDate.from: true
       hryvalfrom           as ValidityStartDate,
       @Semantics.text: true
       @EndUserText.label: 'Financial Statement Description'
       hrytxt               as FinancialStmntHierarchyName,
       _Language,
       _Hierarchy
}
where
      hrrp_dirt_n.hrytyp =    'FSVN'
  and not hryid          like '0109/%'
  and not hryid          like '0102/%'
  and not hryid          like 'H109/%'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIRT_N"
],
"ASSOCIATED":
[
"I_FINANCIALSTATEMENTHIER",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More