I_FINTRANSCURRENTACTIVITY

CDS View

Financial Transaction Current Activity

I_FINTRANSCURRENTACTIVITY is a CDS View in S/4HANA. Financial Transaction Current Activity. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_FinTransNominal view inner COMPOSITE Fin Trans Nominal Amount 
@AbapCatalog.sqlViewName: 'IFTRCURRENTACT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Financial Transaction Current Activity'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@Metadata.allowExtensions:false
@Metadata.ignorePropagatedAnnotations: true // For C1-Release

@VDM.viewType: #COMPOSITE
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
define view I_FinTransCurrentActivity 
// restrict selection from I_FinTransActivity to last active activity

  as select from I_FinTransActivity as Activity
  inner join I_FinancialTransaction as Transaction on  Activity.CompanyCode                 = Transaction.CompanyCode
                                                   and Activity.FinancialTransaction        = Transaction.FinancialTransaction
                                                   and Activity.FinancialInstrumentActivity = Transaction.FinInstrLastActiveActivity

{
// exposed fields (same as with I_FinTransActivity)

  @ObjectModel.foreignKey.association: '_CompanyCode'
  key Activity.CompanyCode,
  @ObjectModel.foreignKey.association: '_FinTrans'
  key Activity.FinancialTransaction,
  key Activity.FinancialInstrumentActivity,
  @ObjectModel.foreignKey.association: '_ActivityCategory'
  Activity.FinancialInstrActivityCategory,
  Activity.TermEndDate,
  Activity.TermEndDateIsInclusive,
  Activity.FinTransNoticeDate,
  Activity.FinTransActyConclusionDate,
  Activity.FinTransActyConclusionTime,
  @ObjectModel.foreignKey.association: '_TimeZone'
  Activity.FinTransActyConclusionTimeZone,
  Activity.FinTransRolloverDate,
  @EndUserText.label: 'Exercise Date'
  @EndUserText.quickInfo: 'Exercise Date'
  Activity.FinTransExerciseDate,
  Activity.FinTransOrderValidityEndDate,
  Activity.FinTransFixingDate,
  @ObjectModel.foreignKey.association: '_FixRef'
  Activity.ForeignExchangeFixingReference,
  Activity.Trader,
  Activity.FinancialInstrContactPerson,
  Activity.FinInstrExternalReference,
  @ObjectModel.foreignKey.association: '_RevReason'
  Activity.TreasuryReversalReason,
  @ObjectModel.foreignKey.association: '_ConfStatus'
  Activity.FinTransConfirmationStatus,
  Activity.FinTransConfirmationDate,
  @EndUserText.label: 'Confirmed By User'
  Activity.FinTransConfirmedByUser,
  @ObjectModel.foreignKey.association: '_CntrconfStatus'
  Activity.FinTransCntrconfStatus,
  Activity.FinTransCntrconfDate,
  @EndUserText.label: 'Conterconfirmed By User'
  Activity.FinTransCntrconfCreatedByUser,
  @ObjectModel.foreignKey.association: '_LeadingCurrency'
  @Semantics.currencyCode: true
  Activity.LeadingCurrency,
  @ObjectModel.foreignKey.association: '_FollowingCurrency'
  @Semantics.currencyCode: true
  Activity.FollowingCurrency,
  Activity.ExchangeRate,
  Activity.SpotExchangeRate,
  Activity.SwapExchangeRate,
  Activity.EffectiveInterestRate,
  Activity.EffectiveInterestMethod,
  Activity.LetterOfCredit,
  @ObjectModel.foreignKey.association: '_ApplicantBP'
  Activity.TreasuryApplicant,
  @ObjectModel.foreignKey.association: '_BeneficiaryBP'
  Activity.TreasuryBeneficiary,
  @ObjectModel.foreignKey.association: '_AdvisingBankBP'
  Activity.TreasuryAdvisingBank,
  @ObjectModel.foreignKey.association: '_IssuingBankBP'
  Activity.TreasuryIssuingBank,
// exposed dimensions (same as within I_FinTransActivity)

  Activity._CompanyCode,
  Activity._FinTrans,
  Activity._ActivityCategory,
  Activity._TimeZone,
  Activity._FixRef,
  Activity._RevReason,
  Activity._ConfStatus,
  Activity._CntrconfStatus,
  Activity._LeadingCurrency,
  Activity._FollowingCurrency,
  Activity._ApplicantBP,
  Activity._BeneficiaryBP,
  Activity._AdvisingBankBP,
  Activity._IssuingBankBP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALTRANSACTION",
"I_FINTRANSACTIVITY"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_CURRENCY",
"I_FINANCIALTRANSACTION",
"I_FINTRANSACTIVITYCATEGORY",
"I_FINTRANSCNTRCONFSTATUS",
"I_FINTRANSCONFSTATUS",
"I_FXFIXINGREFERENCE",
"I_TIMEZONE",
"I_TREASURYREVERSALREASON"
],
"BASE":
[
"I_FINTRANSACTIVITY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More