I_FINTRANSCNDNFMLAVARBL

CDS View

Fin Trans Condition Formula Variable

I_FINTRANSCNDNFMLAVARBL is a CDS View in S/4HANA. Fin Trans Condition Formula Variable. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_IntrstRateInstrFmlaVarbl view_entity from CONSUMPTION Formula Variable
I_FinTransCondition view left_outer COMPOSITE Financial Transaction Condition 
@AbapCatalog.sqlViewName: 'IFINTRANSCNDNVAR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Fin Trans Condition Formula Variable'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@Metadata.allowExtensions:false
@Metadata.ignorePropagatedAnnotations: true // For C1-Release

@VDM.viewType: #COMPOSITE
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
define view I_FinTransCndnFmlaVarbl 
  //all activities containing conditions

  as select from R_FinTransCashFlowActivity as Activity
  //all conditions of these activities (within where-condition they can be restricted)

  inner join R_FinTransCndnFmlaVarbl as FormulaVariable on Activity.CompanyCode                 = FormulaVariable.CompanyCode
                                                       and Activity.FinancialTransaction        = FormulaVariable.FinancialTransaction
                                                       and Activity.FinancialInstrumentActivity = FormulaVariable.FinancialInstrumentActivity
// dimensions, containing for example text fields

  association [0..1] to I_CompanyCode              as _CompanyCode           on  $projection.CompanyCode                   = _CompanyCode.CompanyCode
  association [0..1] to I_FinancialTransaction     as _FinTrans              on  $projection.CompanyCode                   = _FinTrans.CompanyCode
                                                                             and $projection.FinancialTransaction          = _FinTrans.FinancialTransaction
  association [0..1] to I_FinTransActivity         as _Activity              on  $projection.CompanyCode                   = _Activity.CompanyCode
                                                                             and $projection.FinancialTransaction          = _Activity.FinancialTransaction
                                                                             and $projection.FinancialInstrumentActivity   = _Activity.FinancialInstrumentActivity
  association [0..1] to I_FinTransactionDirection  as _Direction             on  $projection.FinancialTransactionDirection = _Direction.FinancialTransactionDirection
  association [0..1] to I_ReferenceInterestRate    as _ReferenceInterestRate on  $projection.InterestReference             = _ReferenceInterestRate.ReferenceInterestRate

{
  //exposed fields

  @ObjectModel.foreignKey.association: '_CompanyCode'
  key FormulaVariable.CompanyCode                    as CompanyCode,
  @ObjectModel.foreignKey.association: '_FinTrans'
  key FormulaVariable.FinancialTransaction           as FinancialTransaction,
  @ObjectModel.foreignKey.association: '_Activity'
  key FormulaVariable.FinancialInstrumentActivity    as FinancialInstrumentActivity,
  @ObjectModel.foreignKey.association: '_Direction'
  key FormulaVariable.FinancialTransactionDirection  as FinancialTransactionDirection,
  key FormulaVariable.FinConditionItem               as FinConditionItem,
  key FormulaVariable.ConditionItemValidityStartDate as ConditionItemValidityStartDate,
  key FormulaVariable.FinConditionFormulaReference   as FinConditionFormulaReference,
  key FormulaVariable.FinCndnFormulaVariable         as FinCndnFormulaVariable,
  _FinTrans.FinancialInstrProductCategory            as FinancialInstrProductCategory,
  FormulaVariable.ConditionPercentageRate            as ConditionPercentageRate,
  @ObjectModel.foreignKey.association: '_ReferenceInterestRate'
  FormulaVariable.InterestReference                  as InterestReference,
  
  //exposed dimensions, containing for example text fields

  _CompanyCode,
  _FinTrans,
  _Activity,
  _Direction,
  _ReferenceInterestRate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALTRANSACTION",
"R_FINTRANSCASHFLOWACTIVITY",
"R_FINTRANSCNDNFMLAVARBL"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_FINANCIALTRANSACTION",
"I_FINTRANSACTIONDIRECTION",
"I_FINTRANSACTIVITY",
"I_REFERENCEINTERESTRATE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More