I_FUNDHIERARCHYNODE

CDS View

Fund Hierarchy Node

I_FUNDHIERARCHYNODE is a CDS View in S/4HANA. Fund Hierarchy Node. It contains 12 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 12 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_FundCoreHierNode view from COMPOSITE Fund Hierarchy Node
A_FundHierNode view from COMPOSITE Fund Hierarchy Node

Fields (12)

KeyField CDS FieldsUsed in Views
KEY FinancialManagementArea FinancialManagementArea 2
KEY FundHierarchy FundHierarchy 2
KEY HierarchyNode HierarchyNode 2
KEY ValidityEndDate ValidityEndDate 2
Fund Fund 2
HierarchyNodeLevel HierarchyNodeLevel 2
HierarchyNodeSequence HierarchyNodeSequence 2
HierarchyNodeVal HierarchyNodeVal 1
HierarchyVersion HierarchyVersion 2
NodeType NodeType 2
ParentNode ParentNode 2
ValidityStartDate ValidityStartDate 2 
@AbapCatalog.sqlViewName: 'IFUNDHN'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Fund Hierarchy Node'

@VDM.viewType: #BASIC
@Hierarchy.parentChild:[
{ recurse:          {   parent: 'ParentNode',   child:  'HierarchyNode'   },
  siblingsOrder:    {   by: 'HierarchyNodeSequence',    direction: 'ASC'   },
  directory:        '_Hierarchy'
  }]
@Analytics: { dataExtraction: {enabled:true} }
@ObjectModel: {
     representativeKey: 'HierarchyNode',
     dataCategory: #HIERARCHY,
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #A,
         sizeCategory: #XL
     }
}

@AccessControl.privilegedAssociations: ['_FinMgmtArea']

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION,  #EXTRACTION_DATA_SOURCE ]

define view I_FundHierarchyNode
  as select from hrrp_node_n

  association [0..*] to I_FundHierarchyNodeText   as _Text        on  $projection.FundHierarchy = _Text.FundHierarchy
                                                                  and $projection.HierarchyNode = _Text.HierarchyNode
                                                                  and $projection.Fund          = '' // just to show that this association is only to be followed if funds is blank


  association [0..1] to I_Fund                    as _Fund        on  $projection.Fund                    = _Fund.Fund
                                                                  and $projection.FinancialManagementArea = _Fund.FinancialManagementArea

  association [1..1] to I_FundHierarchy           as _Hierarchy   on  $projection.FundHierarchy   = _Hierarchy.FundHierarchy
                                                                  and $projection.ValidityEndDate = _Hierarchy.ValidityEndDate

  association [0..1] to I_FinancialManagementArea as _FinMgmtArea on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea

{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast(hrrp_node_n.hryid_42 as fmis_hryid_fund preserving type) as FundHierarchy,
      @ObjectModel.text.association: '_Text'
  key hrrp_node_n.hrynode                                        as HierarchyNode,
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @Semantics.businessDate.to: true
  key cast(hrrp_node_n.hryvalto as fis_datbi preserving type )   as ValidityEndDate,
      hrrp_node_n.parnode                                        as ParentNode,
      @VDM.lifecycle.status:    #DEPRECATED
      cast( '000000000000001' as hryversn )                      as HierarchyVersion,
      @Semantics.businessDate.from: true
      cast(hrrp_node_n.hryvalfrom as fis_datab preserving type)  as ValidityStartDate,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_FinMgmtAreaStdVH',
                     element: 'FinancialManagementArea' } }]
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_FinMgmtArea'
      cast( hrrp_node_n.fikrs as fikrs )                       as FinancialManagementArea,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_FundStdVH',
                     element: 'Fund' },
          additionalBinding: [{ localElement: 'FinancialManagementArea',
                                element: 'FinancialManagementArea' }]
        }]
      @ObjectModel.foreignKey.association: '_Fund'
      @Consumption.filter.businessDate.at:true
      hrrp_node_n.fincode                                      as Fund,
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'HierarchyNodeSequence'
      concat(hrrp_node_n.hryseqnbr, hrrp_node_n.hrynode)           as SequenceNumber, // do not use any longer, use HierarchyNodeSequence

      hrrp_node_n.hryseqnbr                                      as HierarchyNodeSequence,
      hrrp_node_n.hrylevel                                       as HierarchyNodeLevel,
      hrrp_node_n.nodetype                                       as NodeType,
      hrrp_node_n.nodevalue                                      as HierarchyNodeVal,

      _Text,
      _Fund,
      _FinMgmtArea,
      _Hierarchy

}
where
      hrrp_node_n.nodetype <> 'D'
  and hrrp_node_n.hrytyp  =  '0111';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE_N"
],
"ASSOCIATED":
[
"I_FINANCIALMANAGEMENTAREA",
"I_FUND",
"I_FUNDHIERARCHY",
"I_FUNDHIERARCHYNODETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More