I_FSITEMMAPPINGREVISION

CDS View

Financial Statement Item Mapping Revision

I_FSITEMMAPPINGREVISION is a CDS View in S/4HANA. Financial Statement Item Mapping Revision. 6 CDS views read from this table.

Used by 6 CDS view(s)

CDS Views using this table (6)

ViewTypeJoinVDMDescription
C_FSItemMappedHeader view from CONSUMPTION Financial Statement Item Mapped Header
C_FSItemMappingRevision view from CONSUMPTION Financial Statement Item Mapping Revision
P_FSItemMappingFSItemAll view from COMPOSITE
P_FSItemMappingGLAccountAll view from COMPOSITE
P_FSITEMMAPPINGHEADERALL view from COMPOSITE
P_FSITEMMAPPINGHEADERDEF view from COMPOSITE 
@EndUserText.label: 'Financial Statement Item Mapping Revision'
@AbapCatalog.sqlViewName: 'IFSITEMMAPREV'
@VDM.viewType: #BASIC

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'FSItemMappingRevision'

@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #B,
  sizeCategory: #M
}

define view I_FSItemMappingRevision
  as select from fincs_fsimaprv
  association [1..1] to I_CnsldtnChartOfAccounts as _ConsChartOfAccounts on  $projection.ConsolidationChartOfAccounts = _ConsChartOfAccounts.ConsolidationChartOfAccounts

  association [1..1] to I_ChartOfAccounts        as _GLChartOfAccounts   on  $projection.ChartOfAccounts = _GLChartOfAccounts.ChartOfAccounts

  association [1..1] to I_FSItemMapping          as _Mapping             on  $projection.FSItemMappingID = _Mapping.FSItemMappingID

  association [0..*] to I_FSItemMappingRevisionT as _Text                on  $projection.ConsolidationChartOfAccounts = _Text.ConsolidationChartOfAccounts
                                                                         and $projection.ChartOfAccounts              = _Text.ChartOfAccounts
                                                                         and $projection.FSItemMappingID              = _Text.FSItemMappingID
                                                                         and $projection.FSItemMappingRevision        = _Text.FSItemMappingRevision

{

      @ObjectModel.foreignKey.association: '_ConsChartOfAccounts'
  key ritclg                                                  as    ConsolidationChartOfAccounts,

      @EndUserText.label: 'G/L Chart of Accounts'
      @ObjectModel.foreignKey.association: '_GLChartOfAccounts'
  key ktopl                                                   as    ChartOfAccounts,

      @ObjectModel.foreignKey.association: '_Mapping'
  key mapping_id                                              as    FSItemMappingID,

      @ObjectModel.text.association: '_Text'
  key revision                                                as    FSItemMappingRevision,


      created_by                                              as    CreatedByUser,
      case when created_at = 0 then dats_tims_to_tstmp( cast('20180801' as abap.dats), 
                          cast('010000' as abap.tims), 
                          abap_system_timezone( $session.client,'NULL' ), 
                          $session.client, 
                         'NULL' ) else created_at end as    CreationDateTime,
      last_changed_by                                         as    LastChangeByUser,
      case when last_changed_at = 0 then dats_tims_to_tstmp( cast('20180801' as abap.dats), 
                          cast('010000' as abap.tims), 
                          abap_system_timezone( $session.client,'NULL' ), 
                          $session.client, 
                         'NULL' ) else last_changed_at end as    LastChangeDateTime,

      _ConsChartOfAccounts,

      _GLChartOfAccounts,

      _Mapping,

      _Text

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINCS_FSIMAPRV"
],
"ASSOCIATED":
[
"I_CHARTOFACCOUNTS",
"I_CNSLDTNCHARTOFACCOUNTS",
"I_FSITEMMAPPING",
"I_FSITEMMAPPINGREVISIONT"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More