I_FMEAOBJECTTP

CDS View

Transactional Processing for FMEA Object

I_FMEAOBJECTTP is a CDS View in S/4HANA. Transactional Processing for FMEA Object. It contains 2 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 2 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_FMEAMngObject view_entity projection CONSUMPTION FMEA Objects
I_FMEAObjectText view_entity from COMPOSITE FMEA Object Text

Fields (2)

KeyField CDS FieldsUsed in Views
KEY FMEAObjectUUID FMEAObjectUUID 1
FMEAObject FMEAObject 1 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Transactional Processing for FMEA Object'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #B
}
define view entity I_FMEAObjectTP
  as select from I_FMEAObject
  association        to parent I_FailureModeEffectAnalysisTP as _FailureModeEffectAnalysisTP on  $projection.FMEAHeaderUUID = _FailureModeEffectAnalysisTP.FMEAHeaderUUID
  association [0..1] to I_FMEAObjectText                     as _FMEAObjectText              on  $projection.FMEAObjectUUID = _FMEAObjectText.FMEAObjectUUID
  association [0..1] to I_Product                            as _Product                    on  $projection.Material = _Product.Product
  association [0..1] to I_MfgBOOOperationChangeState         as _BOOOperationChangeState     on  $projection.BillOfOperationsType        = _BOOOperationChangeState.BillOfOperationsType
                                                                                             and $projection.BillOfOperationsGroup       = _BOOOperationChangeState.BillOfOperationsGroup
                                                                                             and $projection.BillOfOperationsVariant     = _BOOOperationChangeState.BillOfOperationsVariant
                                                                                             and $projection.BillOfOperationsSequence    = _BOOOperationChangeState.BillOfOperationsSequence
                                                                                             and $projection.BOOOperationInternalID      = _BOOOperationChangeState.BOOOperationInternalID
                                                                                             and $projection.BOOOpInternalVersionCounter = _BOOOperationChangeState.BOOOpInternalVersionCounter
{
  key FMEAObjectUUID,
      FMEAHeaderUUID,
      FMEAType,
      FMEATypeObjectType,
      FMEAObject,
      _FMEATypeObjectType.BusinessObjectType,
      case when  _FMEATypeObjectType.BusinessObjectType = 'BUS1001006'
           then FMEAObject else '' end as Material,
      case when _FMEATypeObjectType.BusinessObjectType = 'BUS1012'
           then cast(substring(FMEAObject,1,1) as plnty preserving type )
           else ''  end                as BillOfOperationsType,
      case when _FMEATypeObjectType.BusinessObjectType = 'BUS1012'
           then cast(substring(FMEAObject,2,8) as plnnr preserving type )
       else ''  end                    as BillOfOperationsGroup,
      case when _FMEATypeObjectType.BusinessObjectType = 'BUS1012'
           then cast(substring(FMEAObject,10,8) as plnkn )
       else '00000000' end                     as BOOOperationInternalID,
      case when _FMEATypeObjectType.BusinessObjectType = 'BUS1012'
           then cast(substring(FMEAObject,18,8) as cim_count )
       else '00000000' end                     as BOOOpInternalVersionCounter,
      case when _FMEATypeObjectType.BusinessObjectType = 'BUS1012'
           then cast(substring(FMEAObject,26,2) as plnal preserving type )
       else '' end                     as BillOfOperationsVariant,
      case when _FMEATypeObjectType.BusinessObjectType = 'BUS1012'
           then cast(substring(FMEAObject,28,6) as plnfolge preserving type )
       else '' end                     as BillOfOperationsSequence,

      //Associations

      _FailureModeEffectAnalysisTP,
      _FailureModeEffectAnalysis,
      _FMEAType,
      _FMEATypeObjectType,
      _BOOOperationChangeState,
      _Product,
      _FMEAObjectText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FMEAOBJECT",
"I_FMEATYPEOBJECTTYPE"
],
"ASSOCIATED":
[
"I_FAILUREMODEEFFECTANALYSIS",
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEAOBJECTTEXT",
"I_FMEATYPE",
"I_FMEATYPEOBJECTTYPE",
"I_MFGBOOOPERATIONCHANGESTATE",
"I_PRODUCT"
],
"BASE":
[
"I_FMEAOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More