I_FISCALCALYEARPERIODFORLEDGER

CDS View

Fiscal Year Period for Ledger

I_FISCALCALYEARPERIODFORLEDGER is a CDS View in S/4HANA. Fiscal Year Period for Ledger. It contains 5 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 5 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
P_CN_GLAcctPerd view from CONSUMPTION Cartesian Product of G/L Account and Fiscal Period
P_FinStatisticalKeyFigureItem1 view inner COMPOSITE
P_GLAccountBalanceEnd_F0707A view_entity inner CONSUMPTION
P_GLAcctBalance01 view inner COMPOSITE
P_MaxFiscalPeriod view from COMPOSITE

Fields (5)

KeyField CDS FieldsUsed in Views
KEY CompanyCode CompanyCode 1
KEY FiscalPeriod FiscalPeriod 2
KEY FiscalYear FiscalYear 1
KEY Ledger Ledger 1
FiscalYearPeriod FiscalYearPeriod 1 
@AbapCatalog.sqlViewName: 'IFIFCFYPERD4L'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'FiscalYearPeriod'
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics: { dataCategory: #DIMENSION }
@EndUserText.label: 'Fiscal Year Period for Ledger'

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
define view I_FiscalCalYearPeriodForLedger as select from I_FiscalYearPeriod inner join finsc_ld_cmp 
                                                  on   I_FiscalYearPeriod.FiscalYearVariant = finsc_ld_cmp.periv

association [0..1] to I_CompanyCode              as _CompanyCode on  $projection.CompanyCode       = _CompanyCode.CompanyCode
association [0..1] to I_Ledger                   as _Ledger      on  $projection.Ledger            = _Ledger.Ledger
association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear  on  $projection.FiscalYear        = _FiscalYear.FiscalYear
                                                                 and $projection.CompanyCode       = _FiscalYear.CompanyCode  
association [0..*] to I_FiscalYearPeriodText     as _Text        on  $projection.FiscalYearVariant = _Text.FiscalYearVariant
                                                                 and $projection.FiscalYear        = _Text.FiscalYear
                                                                 and $projection.FiscalPeriod      = _Text.FiscalPeriod
association [0..1] to I_FiscalYear               as _FiscalYearForVariant  on  $projection.FiscalYearVariant = _FiscalYearForVariant.FiscalYearVariant
                                                                           and $projection.FiscalYear        = _FiscalYearForVariant.FiscalYear                                                                 

{

@ObjectModel.foreignKey.association: '_CompanyCode'      
key cast( bukrs as fis_bukrs preserving type ) as CompanyCode, 
@ObjectModel.foreignKey.association: '_Ledger'      
key cast( rldnr as fis_rldnr preserving type ) as Ledger,
key FiscalYearPeriod,

@ObjectModel.foreignKey.association: '_FiscalYearForVariant'      
    FiscalYear,
@ObjectModel.text.association: '_Text'
    FiscalPeriod,

@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
    I_FiscalYearPeriod.FiscalYearVariant,

@ObjectModel.foreignKey.association: '_FiscalPeriodStartDate'      
    FiscalPeriodStartDate,
    FiscalPeriodEndDate,
    
    IsSpecialPeriod,
    
    FiscalYearStartDate,
    FiscalYearEndDate,
    
    NextFiscalPeriod,
    NextFiscalPeriodFiscalYear,
     
    _CompanyCode,
    _Ledger,
    _FiscalYearVariant,
    _FiscalYearForVariant,
    _FiscalPeriodStartDate,
    _FiscalYear,
    _Text

}                
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FISCALYEARPERIOD",
"FINSC_LD_CMP"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_COMPANYCODE",
"I_FISCALYEAR",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARPERIODTEXT",
"I_FISCALYEARVARIANT",
"I_LEDGER"
],
"BASE":
[
"I_FISCALYEARPERIOD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More