I_ENGMNTPROJPLNDATAUNITVERS

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IEPRJPLNDATAUVER'
@EndUserText.label: 'Enagagement Project Plan Data Unit Version'
@VDM.viewType: #BASIC
@Analytics:{dataCategory:#FACT}
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view I_EngmntProjPlnDataUnitVers
  as select from I_EngmntProjPlanDataWithDraft as A

  association [0..1] to I_EngagementProject           as _EngagementProject           on  $projection.EngagementProject = _EngagementProject.EngagementProject

  association [0..1] to I_EngagementProjFinancialPlan as _EngagementProjFinancialPlan on  $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID

  association [1..1] to I_WorkPackage                 as _WorkPackage                 on  $projection.WorkPackage = _WorkPackage.WorkPackage

  association [0..1] to I_EngmtProjFinPlanVersion     as _EngmtProjFinPlanVersion     on  $projection.EngagementProjFinPlanUUID = _EngmtProjFinPlanVersion.EngagementProjFinPlanUUID
                                                                                      and $projection.EngmtProjFinPlanVersion   = _EngmtProjFinPlanVersion.EngmtProjFinPlanVersion


  association [0..1] to I_EngmntProjResourceType      as _EngmntProjResourceType      on  $projection.EngagementProjectResourceType = _EngmntProjResourceType.EngagementProjectResourceType

  association [0..*] to I_EngagementProjectResource   as _EngagementProjectResource   on  $projection.EngagementProjectResource = _EngagementProjectResource.EngagementProjectResource


  association [0..1] to I_WorkPackageWorkItem         as _WorkItem                    on  $projection.WorkItem    = _WorkItem.WorkItem
                                                                                      and $projection.WorkPackage = _WorkItem.WorkPackage

  association [0..1] to I_Currency                    as _Currency                    on  $projection.Currency = _Currency.Currency

  association [0..1] to I_UnitOfMeasure               as _UnitOfMeasure               on  $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_BillingControlCategory      as _BillingControlCategory      on  $projection.BillingControlCategory = _BillingControlCategory.BillingControlCategory

  association [0..*] to I_PersnWrkAgreementDet        as _PersonWorkAgreementDet      on  $projection.EmploymentInternalID = _PersonWorkAgreementDet.PersonWorkAgreement
  //                                                                                      and _Employment.StartDate            <= $projection.WorkPackageEndDate

  //                                                                                      and _Employment.EndDate              >= $projection.WorkPackageStartDate

  association [0..1] to I_Employment                  as _Employment                  on  $projection.EmploymentInternalID = _Employment.EmploymentInternalID
  association [0..1] to I_PersonWorkAgreement_1       as _PersonWorkAgreement_1       on  $projection.EmploymentInternalID = _PersonWorkAgreement_1.PersonWorkAgreement
  association [0..1] to I_EngagementProjectSrvcOrg    as _EngagementProjectServiceOrg on  $projection.EngagementProjectServiceOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg

  association [0..1] to I_PlanSkillTags               as _PlanSkillTags               on  $projection.ResourceDemandUUID = _PlanSkillTags.ResourceDemandUUID
{

  key A.PlanLineItemUUID,
  key A.EngagementProject,
  key A.WorkPackage,
  key A.EngagementProjFinPlanUUID,
  key A.WorkPackageUUID,
  key A.EngmtProjFinPlanVersion,

      @ObjectModel.foreignKey.association: '_EngmntProjResourceType'
  key A.EngagementProjectResourceType,

      @Semantics.fiscal.period: true
  key A.FiscalPeriod,

      @Semantics.fiscal.year: true
  key A.FiscalYear,

      @ObjectModel.foreignKey.association: '_EngagementProjectResource'
  key A.EngagementProjectResource,

      @ObjectModel.foreignKey.association: '_PersonWorkAgreementDet'
  key A.EmploymentInternalID,
  key A.EngmtProjEmployeeIsStaffed,
      @ObjectModel.foreignKey.association: '_WorkItem'
  key A.WorkItem,
  key A.ResourceDemandUUID,

      @ObjectModel.foreignKey: {
        association: '_BillingControlCategory'
      }
      A.BillingControlCategory,

      @ObjectModel.foreignKey.association:'_EngagementProjectServiceOrg'
      A.EngagementProjectServiceOrg,
      A.IsUnitBased,
      A.ParentUnitDemandUUID,

      @Semantics.currencyCode: true
      A.Currency,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      A.PlndCostAmt,

      @Semantics.unitOfMeasure: true
      A.UnitOfMeasure,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @DefaultAggregation: #SUM
      A.PlndEffortQty,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      A.PlndRevnAmt,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode:'Currency'
      A.ActualPlanDeviationCost,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @DefaultAggregation: #SUM
      A.ActualPlanDeviationEffort,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      A.ActualPlanDeviationRevenue,
      A.EngmntProjPlanLineType,
      A.ResourceDemand,
      A.ResourceSupply,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'SupplySource'
      A.SourceOfSupply,
      A.SupplySource,

      // Following attributes are exposed to use in DCL

      _EngagementProject.EngagementProjectType,
      _EngagementProject.EngagementProjectCategory,
      
      @Consumption.hidden: true
      _EngagementProject.ProjectProfileCode,
      
      @Consumption.hidden: true
      _EngagementProject.CompanyCode,
      
      @Consumption.hidden: true
      cast( _EngagementProject.CostCenter as fis_kostl) as CostCenter,
      
      @Consumption.hidden: true
      _EngagementProject.ProfitCenter,

      _EngagementProject,
      _EngagementProjFinancialPlan,
      _EngmtProjFinPlanVersion,
      _WorkPackage,
      _EngmntProjResourceType,
      _WorkItem,
      _EngagementProjectResource,
      _PersonWorkAgreementDet,
      _Currency,
      _EngagementProjectServiceOrg,
      _UnitOfMeasure,
      _PlanSkillTags,
      @VDM.lifecycle: {
        successor: '_PersonWorkAgreement_1',
        status: #DEPRECATED
      }
      _Employment,
      _PersonWorkAgreement_1,
      _BillingControlCategory


} where A.PlanLineItemIsTemporary <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGAGEMENTPROJECT",
"I_ENGMNTPROJPLANDATAWITHDRAFT"
],
"ASSOCIATED":
[
"I_BILLINGCONTROLCATEGORY",
"I_CURRENCY",
"I_EMPLOYMENT",
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJECTRESOURCE",
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_ENGMNTPROJRESOURCETYPE",
"I_ENGMTPROJFINPLANVERSION",
"I_PERSNWRKAGREEMENTDET",
"I_PERSONWORKAGREEMENT_1",
"I_PLANSKILLTAGS",
"I_UNITOFMEASURE",
"I_WORKPACKAGE",
"I_WORKPACKAGEWORKITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/