Which CDS Views use I_ENGMNTPROJPLANDATAWITHDRAFT?

I_ENGMNTPROJPLANDATAWITHDRAFT is used by 2 CDS view(s), including: I_EngmntProjPlnDataUnitVers, P_EngmntProjPlanDataWithDraft.

How many fields does I_ENGMNTPROJPLANDATAWITHDRAFT have?

I_ENGMNTPROJPLANDATAWITHDRAFT has 31 fields. Key fields: EmploymentInternalID, EngagementProject, EngagementProjectResource, EngagementProjectResourceType, EngagementProjFinPlanUUID, EngmtProjEmployeeIsStaffed, EngmtProjFinPlanVersion, FiscalPeriod, FiscalYear, PlanLineItemUUID, ResourceDemandUUID, WorkItem, WorkPackage, WorkPackageUUID.

I_ENGMNTPROJPLANDATAWITHDRAFT

CDS View

Engagement Project Plan Data with Draft

I_ENGMNTPROJPLANDATAWITHDRAFT is a CDS View in S/4HANA. Engagement Project Plan Data with Draft. It contains 31 fields. 2 CDS views read from this table.

CDS Views using this table (2)

View	Type	Join	VDM	Description
I_EngmntProjPlnDataUnitVers	view	from	BASIC	Enagagement Project Plan Data Unit Version
P_EngmntProjPlanDataWithDraft	view	inner	COMPOSITE

Fields (31)

Key	Field	CDS Fields	Used in Views
KEY	EmploymentInternalID	EmploymentInternalID	2
KEY	EngagementProject	EngagementProject	1
KEY	EngagementProjectResource	EngagementProjectResource	2
KEY	EngagementProjectResourceType	EngagementProjectResourceType	2
KEY	EngagementProjFinPlanUUID	EngagementProjFinPlanUUID	2
KEY	EngmtProjEmployeeIsStaffed	EngmtProjEmployeeIsStaffed	2
KEY	EngmtProjFinPlanVersion	EngmtProjFinPlanVersion	2
KEY	FiscalPeriod	FiscalPeriod	2
KEY	FiscalYear	FiscalYear	2
KEY	PlanLineItemUUID	PlanLineItemUUID	1
KEY	ResourceDemandUUID	ResourceDemandUUID	2
KEY	WorkItem	WorkItem	2
KEY	WorkPackage	WorkPackage	2
KEY	WorkPackageUUID	WorkPackageUUID	2
	ActualPlanDeviationCost	ActualPlanDeviationCost	1
	ActualPlanDeviationEffort	ActualPlanDeviationEffort	1
	ActualPlanDeviationRevenue	ActualPlanDeviationRevenue	1
	BillingControlCategory	BillingControlCategory	2
	Currency	Currency	2
	EngagementProjectServiceOrg	EngagementProjectServiceOrg	2
	EngmntProjPlanLineType	EngmntProjPlanLineType	2
	IsUnitBased	IsUnitBased	2
	ParentUnitDemandUUID	ParentUnitDemandUUID	1
	PlndCostAmt	PlndCostAmt	1
	PlndEffortQty	PlndEffortQty	1
	PlndRevnAmt	PlndRevnAmt	1
	ResourceDemand	ResourceDemand	2
	ResourceSupply	ResourceSupply	1
	SourceOfSupply	SourceOfSupply	1
	SupplySource	SupplySource	1
	UnitOfMeasure	UnitOfMeasure	2

@AbapCatalog.sqlViewName: 'IEPROJPLNWDFT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics:{dataCategory:#FACT}
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@EndUserText.label: 'Engagement Project Plan Data with Draft'
define view I_EngmntProjPlanDataWithDraft
  as select from /cpd/plandata as EngagementProjectPlanData


  association [0..1] to I_EngagementProject           as _EngagementProject           on  $projection.EngagementProject = _EngagementProject.EngagementProject

  association [0..1] to I_EngagementProjFinancialPlan as _EngagementProjFinancialPlan on  $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID

  association [1..1] to I_WorkPackage                 as _WorkPackage                 on  $projection.WorkPackage = _WorkPackage.WorkPackage

  association [0..1] to I_EngmtProjFinPlanVersion     as _EngmtProjFinPlanVersion     on  $projection.EngagementProjFinPlanUUID = _EngmtProjFinPlanVersion.EngagementProjFinPlanUUID
                                                                                      and $projection.EngmtProjFinPlanVersion   = _EngmtProjFinPlanVersion.EngmtProjFinPlanVersion


  association [0..1] to I_EngmntProjResourceType      as _EngmntProjResourceType      on  $projection.EngagementProjectResourceType = _EngmntProjResourceType.EngagementProjectResourceType

  association [0..*] to I_EngagementProjectResource   as _EngagementProjectResource   on  $projection.EngagementProjectResource = _EngagementProjectResource.EngagementProjectResource

  association [0..1] to I_WorkPackageWorkItem         as _WorkItem                    on  $projection.WorkItem    = _WorkItem.WorkItem
                                                                                      and $projection.WorkPackage = _WorkItem.WorkPackage

  association [0..1] to I_Currency                    as _Currency                    on  $projection.Currency = _Currency.Currency

  association [0..1] to I_UnitOfMeasure               as _UnitOfMeasure               on  $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_BillingControlCategory      as _BillingControlCategory      on  $projection.BillingControlCategory = _BillingControlCategory.BillingControlCategory

  association [0..*] to I_PersnWrkAgreementDet        as _PersonWorkAgreementDet      on  $projection.EmploymentInternalID = _PersonWorkAgreementDet.PersonWorkAgreement
  //                                                                                      and _Employment.StartDate            <= $projection.WorkPackageEndDate

  //                                                                                      and _Employment.EndDate              >= $projection.WorkPackageStartDate

  association [0..1] to I_PersonWorkAgreement_1       as _PersonWorkAgreement_1       on  $projection.EmploymentInternalID = _PersonWorkAgreement_1.PersonWorkAgreement
  association [0..1] to I_Employment                  as _Employment                  on  $projection.EmploymentInternalID = _Employment.EmploymentInternalID
  association [0..1] to I_EngagementProjectSrvcOrg    as _EngagementProjectServiceOrg on  $projection.EngagementProjectServiceOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg

  association [0..1] to I_PlanSkillTags               as _PlanSkillTags               on  $projection.ResourceDemandUUID = _PlanSkillTags.ResourceDemandUUID
{

  key EngagementProjectPlanData.plan_line_guid                                        as PlanLineItemUUID,

      cast(EngagementProjectPlanData.mp_id  as /cpd/eng_mp_id preserving type)        as EngagementProject,

      EngagementProjectPlanData.wp_id                                                 as WorkPackage,

      cast(EngagementProjectPlanData.fp_key  as /cpd/eng_pfp_db_key preserving type ) as EngagementProjFinPlanUUID,

      cast(EngagementProjectPlanData.wp_key as /cpd/wp_db_key preserving type )       as WorkPackageUUID,

      EngagementProjectPlanData.version                                               as EngmtProjFinPlanVersion,

      @ObjectModel.foreignKey.association: '_EngmntProjResourceType'
      EngagementProjectPlanData.res_type                                              as EngagementProjectResourceType,


      @Semantics.fiscal.period: true
      EngagementProjectPlanData.period                                                as FiscalPeriod,

      @Semantics.fiscal.year: true
      EngagementProjectPlanData.fc_year                                               as FiscalYear,

      @ObjectModel.foreignKey.association: '_EngagementProjectResource'
      EngagementProjectPlanData.resource_id                                           as EngagementProjectResource,

      @ObjectModel.foreignKey.association: '_PersonWorkAgreementDet'
      EngagementProjectPlanData.employee                                              as EmploymentInternalID,
      EngagementProjectPlanData.confirmed                                             as EngmtProjEmployeeIsStaffed,
      @ObjectModel.foreignKey.association: '_WorkItem'
      EngagementProjectPlanData.workitem_id                                           as WorkItem,

      EngagementProjectPlanData.demand_key                                            as ResourceDemandUUID,

      @ObjectModel.foreignKey: {
        association: '_BillingControlCategory'
      }
      EngagementProjectPlanData.billgctrlcat                                          as BillingControlCategory,

      @ObjectModel.foreignKey.association:'_EngagementProjectServiceOrg'
      EngagementProjectPlanData.delvry_serv_org                                       as EngagementProjectServiceOrg,

      @Semantics.currencyCode: true
      EngagementProjectPlanData.currency                                              as Currency,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.cost                                                  as PlndCostAmt,

      @Semantics.unitOfMeasure: true
      EngagementProjectPlanData.uom                                                   as UnitOfMeasure,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.effort                                                as PlndEffortQty,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.revenue                                               as PlndRevnAmt,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.cost_deviation                                        as ActualPlanDeviationCost,

      @Semantics.quantity.unitOfMeasure:'UnitOfMeasure'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.effort_deviation                                      as ActualPlanDeviationEffort,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.revenue_deviation                                     as ActualPlanDeviationRevenue,

      EngagementProjectPlanData.line_type                                             as EngmntProjPlanLineType,
      
      EngagementProjectPlanData.resource_demand_id                                    as ResourceDemand,
       
      EngagementProjectPlanData.resource_supply_id                                    as ResourceSupply,
 
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'SupplySource'      
      EngagementProjectPlanData.source_of_supply                                      as SourceOfSupply,
      EngagementProjectPlanData.source_of_supply                                      as SupplySource,

      //    EngagementProjectPlanData.is_draft                                                                                             as IsDraft,


      //    Identifies the Demand Row of the Unit Based Work Package

      EngagementProjectPlanData.is_unit_based                                         as IsUnitBased,

      EngagementProjectPlanData.is_draft                                              as PlanLineItemIsTemporary,
      @Semantics.dateTime:true
      @Semantics.systemDateTime.createdAt:true
      cast( EngagementProjectPlanData.created_on as /cpd/cpm_createdon)               as CreationDateTime,
      EngagementProjectPlanData.created_by                                            as CreatedByUser,

      EngagementProjectPlanData.parent_unit_demand_key                                as ParentUnitDemandUUID,

      _EngagementProject,
      _EngagementProjFinancialPlan,
      _EngmtProjFinPlanVersion,
      _WorkPackage,
      _EngmntProjResourceType,
      _WorkItem,
      _EngagementProjectResource,
      _PersonWorkAgreementDet,
      _Currency,
      _EngagementProjectServiceOrg,
      _UnitOfMeasure,
      _PlanSkillTags,
      @VDM.lifecycle: {
        successor: '_PersonWorkAgreement_1',
        status: #DEPRECATED
      }
      _Employment,
      _PersonWorkAgreement_1,
      _BillingControlCategory

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/CPD/PLANDATA"
],
"ASSOCIATED":
[
"I_BILLINGCONTROLCATEGORY",
"I_CURRENCY",
"I_EMPLOYMENT",
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJECTRESOURCE",
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_ENGMNTPROJRESOURCETYPE",
"I_ENGMTPROJFINPLANVERSION",
"I_PERSNWRKAGREEMENTDET",
"I_PERSONWORKAGREEMENT_1",
"I_PLANSKILLTAGS",
"I_UNITOFMEASURE",
"I_WORKPACKAGE",
"I_WORKPACKAGEWORKITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Depth:

I_ENGMNTPROJPLANDATAWITHDRAFT

CDS Views using this table (2)

Fields (31)

Learn More