I_EXPLCTASSMDLUSRPRODEXCLSNTP

CDS View

Product Exclusion from Assortment Module for Assortment User

I_EXPLCTASSMDLUSRPRODEXCLSNTP is a CDS View in S/4HANA. Product Exclusion from Assortment Module for Assortment User. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_AssortmentMdlUsrProdExclsn view_entity projection CONSUMPTION Product Exclusion from Assortment Module for Assortment User 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@EndUserText.label: 'Product Exclusion from Assortment Module for Assortment User'

@VDM: {
  viewType: #TRANSACTIONAL,

  lifecycle: {
    contract: {
      type: #SAP_INTERNAL_API
    }
  }
}
@ObjectModel: {
    usageType: {
        serviceQuality: #D,
        sizeCategory: #L,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'ListingCondition'
}
//This view is deprecated, use "I_AsstmtMdlUsrProdExclsnTP_2" instead

define root view entity I_ExplctAssMdlUsrProdExclsnTP
  as select from I_AsstmtMdlUserProductExclsn as Exclusions
    inner join   I_ExplicitAssortmentModule   as ExplicitModules on Exclusions.AssortmentModuleObjectUUID = ExplicitModules.AssortmentModuleUUID

  association [1..1] to I_ExplicitAssortmentModuleTP as _ExplicitAssortmentModule on  $projection.AssortmentModuleObjectUUID = _ExplicitAssortmentModule.AssortmentModuleUUID
  association [1..1] to I_Customer                   as _Customer                 on  $projection.AssortmentModuleUser = _Customer.Customer
  association [0..1] to I_ProdToExplicitAsstmtMdlTP  as _ModuleProduct            on  $projection.Product                    = _ModuleProduct.Product
                                                                                  and $projection.AssortmentModuleObjectUUID = _ModuleProduct.AssortmentModuleUUID
{
  key Exclusions.AssortmentModuleObjectUUID,
  key Exclusions.Product,
  key Exclusions.AssortmentModuleUser                                                as AssortmentModuleUser,
      Exclusions.LastChangeDate,
      Exclusions.LastChangeDateTime,
      /*For DCL*/
      Exclusions.SalesOrganization,
      Exclusions.DistributionChannel,
      case when coalesce( _ModuleProduct.Product, ' ' ) <> ' ' then 'X' else ' ' end as ProductIsAssignedToVersion,
      max(_ModuleProduct.ValidityEndDate) as ValidityEndDate,
      _ExplicitAssortmentModule,
      _Customer
}
group by Exclusions.AssortmentModuleObjectUUID, 
         Exclusions.Product,
         Exclusions.AssortmentModuleUser,
         Exclusions.LastChangeDate,
         Exclusions.LastChangeDateTime,
         Exclusions.SalesOrganization,
         Exclusions.DistributionChannel,
         _ModuleProduct.Product
         
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSTMTMDLUSERPRODUCTEXCLSN",
"I_EXPLICITASSORTMENTMODULE",
"I_PRODTOEXPLICITASSTMTMDLTP"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_EXPLICITASSORTMENTMODULETP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More