I_ELECTRONICDOCFILE

CDS View

eDocument File

I_ELECTRONICDOCFILE is a CDS View in S/4HANA. eDocument File. It contains 1 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 1 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_ElectronicDocFile view from COMPOSITE eDocument File
I_ElectronicDocAttachment view from COMPOSITE Electronic Document: Attachment

Fields (1)

KeyField CDS FieldsUsed in Views
KEY ElectronicDocUUID ElectronicDocUUID 1 
@AbapCatalog: {
  sqlViewName: 'IEDOFILE',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'eDocument File'

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #X,
  sizeCategory: #M
  }
define view I_ElectronicDocFile

  // Part 1: eDocument Files

  as select from I_ElectronicDoc         as Header
    inner join   I_ElectronicDocCommFile as File    on File.ElectronicDocUUID = Header.ElectronicDocUUID

  association [0..*] to I_CountryText                 as _CountryText                 on  $projection.ElectronicDocCountry = _CountryText.Country
  association [0..*] to I_ElectronicDocTypeText       as _ElectronicDocTypeText       on  $projection.ElectronicDocType = _ElectronicDocTypeText.ElectronicDocType
  association [0..*] to I_ElectronicDocSourceTypeText as _ElectronicDocSourceTypeText on  $projection.ElectronicDocSourceType = _ElectronicDocSourceTypeText.ElectronicDocSourceType
  association [0..*] to I_ElectronicDocProcStatusText as _ElectronicDocProcStatusText on  $projection.ElectronicDocProcessForStatus = _ElectronicDocProcStatusText.ElectronicDocProcess
                                                                                      and $projection.ElectronicDocProcessStatus = _ElectronicDocProcStatusText.ElectronicDocProcessStatus
  association [0..*] to I_ElectronicDocProcessText    as _ElectronicDocProcessText    on  $projection.ElectronicDocProcess = _ElectronicDocProcessText.ElectronicDocProcess
{
  key File.ElectronicDocFileUUID,
      ElectronicDocFileType,
      ElectronicDocFileName,
      ElectronicDocFileCreationTime,
      ElectronicDocFileCreationDate,
      ElectronicDocFileContent,

      Header.ElectronicDocUUID,
      Header.ElectronicDocCompanyCode,
      ElectronicDocCountry,
      ElectronicDocSourceType,
      ElectronicDocSourceKey,
      ElectronicDocType,
      ElectronicDocProcess,
      ElectronicDocProcessStatus,
      ElectronicDocLastChangeDate,
      ElectronicDocLastChangeTime,
      ElectronicDocCreationDate,
      ElectronicDocCreationTime,
      ElectronicDocProcessForStatus,

      //Associations

      _CountryText,
      _ElectronicDocTypeText,
      _ElectronicDocSourceTypeText,
      _ElectronicDocProcStatusText,
      _ElectronicDocProcessText
}


// Part 2: eDocument Source Files

union all select from I_ElectronicDoc           as Header
  inner join          I_ElectronicDocSourceFile as SourceFile on SourceFile.ElectronicDocFileUUID = Header.ElectronicDocSourceKey
                                                             and Header.ElectronicDocSourceType   = 'SRC_FILE'

association [0..*] to I_CountryText                 as _CountryText                 on  $projection.ElectronicDocCountry = _CountryText.Country
association [0..*] to I_ElectronicDocTypeText       as _ElectronicDocTypeText       on  $projection.ElectronicDocType = _ElectronicDocTypeText.ElectronicDocType
association [0..*] to I_ElectronicDocSourceTypeText as _ElectronicDocSourceTypeText on  $projection.ElectronicDocSourceType = _ElectronicDocSourceTypeText.ElectronicDocSourceType
association [0..*] to I_ElectronicDocProcStatusText as _ElectronicDocProcStatusText on  $projection.ElectronicDocProcessForStatus = _ElectronicDocProcStatusText.ElectronicDocProcess
                                                                                    and $projection.ElectronicDocProcessStatus = _ElectronicDocProcStatusText.ElectronicDocProcessStatus
association [0..*] to I_ElectronicDocProcessText    as _ElectronicDocProcessText    on  $projection.ElectronicDocProcess = _ElectronicDocProcessText.ElectronicDocProcess
{
  key SourceFile.ElectronicDocFileUUID,
      ElectronicDocFileType,
      ElectronicDocFileName,
      ElectronicDocFileCreationTime,
      ElectronicDocFileCreationDate,
      ElectronicDocFileContent,

      Header.ElectronicDocUUID,
      Header.ElectronicDocCompanyCode,
      ElectronicDocCountry,
      ElectronicDocSourceType,
      ElectronicDocSourceKey,
      ElectronicDocType,
      ElectronicDocProcess,
      ElectronicDocProcessStatus,
      ElectronicDocLastChangeDate,
      ElectronicDocLastChangeTime,
      ElectronicDocCreationDate,
      ElectronicDocCreationTime,
      ElectronicDocProcessForStatus,

      //Associations

      _CountryText,
      _ElectronicDocTypeText,
      _ElectronicDocSourceTypeText,
      _ElectronicDocProcStatusText,
      _ElectronicDocProcessText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ELECTRONICDOC",
"I_ELECTRONICDOCCOMMFILE",
"I_ELECTRONICDOCSOURCEFILE"
],
"ASSOCIATED":
[
"I_COUNTRYTEXT",
"I_ELECTRONICDOCPROCESSTEXT",
"I_ELECTRONICDOCPROCSTATUSTEXT",
"I_ELECTRONICDOCSOURCETYPETEXT",
"I_ELECTRONICDOCTYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More