I_EHSAMOUNTROOT

@AbapCatalog.sqlViewName: 'IEHSAMNROOT'
@EndUserText.label: 'EHS Amount Root'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
 

@AccessControl:
{
  authorizationCheck: #PRIVILEGED_ONLY,
  privilegedAssociations:  [ '_EHSAmountHistory', '_CreatedByUser' ],
  // blocking of personal data not required (user data can not be blocked and no BP info from user exposed)

  personalData.blocking: #NOT_REQUIRED
}


@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:{ dataClass: #TRANSACTIONAL,
                         serviceQuality: #C,
                         sizeCategory: #XL }
  
@ObjectModel:{modelCategory: #BUSINESS_OBJECT,
              transactionalProcessingEnabled: true,
              createEnabled: false,
              updateEnabled: true,
              deleteEnabled: false,
              writeActivePersistence: 'ehfndv_amns_root',
              representativeKey: 'EHSAmountUUID',
              compositionRoot: true,
              sapObjectNodeType.name: 'EHSDataAmount' }

@VDM: {
  lifecycle.contract.type:#SAP_INTERNAL_API,
  viewType: #BASIC
}

// protected by DCL0

define view I_EHSAmountRoot
  as select from    ehfndv_amns_root

    left outer to one join ehfndd_kv_temp on ehsamountuuid = hextobin(
      ehfndd_kv_temp.master_uuid
    )
  association [0..1] to I_User                as _CreatedByUser       on $projection.CreatedByUser = _CreatedByUser.UserID
  // association [0..1] to I_User                     as _LastChangedByUser     on  $projection.LastChangedByUser   = _LastChangedByUser.UserID

  association [0..*] to I_EHSAmountHistory    as _EHSAmountHistory    on $projection.EHSAmountUUID = _EHSAmountHistory.EHSAmountUUID
  association [0..*] to I_EHSAmountLimitFail  as _EHSAmountLimitFail  on $projection.EHSAmountUUID = _EHSAmountLimitFail.EHSAmountUUID
  association [1..1] to I_EHSAmountStatus     as _EHSAmountStatus     on $projection.EHSAmountStatus = _EHSAmountStatus.EHSAmountStatus
  association [0..1] to I_UnitOfMeasure       as _UnitText            on $projection.UnitOfMeasure = _UnitText.UnitOfMeasure
  association [0..1] to I_EHSAmountSourceType as _EHSAmountSourceType on $projection.EHSAmountSourceType = _EHSAmountSourceType.EHSAmountSourceType

    // Extension include

  association [1..1] to E_EHSDataAmount       as _Extension           on $projection.EHSAmountUUID = _Extension.EHSAmountUUID
{
 

  key ehsamountuuid                                                               as EHSAmountUUID,
      //admin fields

      @Semantics.systemDateTime.createdAt: true
      cast( creationdatetime as ehfnd_datetime_cr preserving type )               as CreationDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      cast( lastchangedatetime as ehfnd_datetime_ch preserving type )             as LastChangeDateTime,
      @Semantics.user.createdBy: true
      createdbyuser                                                               as CreatedByUser,
      // association

      _CreatedByUser,

      @Semantics.user.lastChangedBy: true
      lastchangedbyuser                                                           as LastChangedByUser,

      //funcional

      ehsamountsourceuuid                                                         as EHSAmountSourceUUID,
      @ObjectModel.foreignKey.association: '_EHSAmountSourceType'
      ehsamountsourcetype                                                         as EHSAmountSourceType,
      _EHSAmountSourceType,

      ehssubjecttype                                                              as EHSSubjectType,
      ehssubjectuuid                                                              as EHSSubjectUUID,
      ehsamountprocessuuid                                                        as EHSAmountProcessUUID,

      ehsamountutcdatetime                                                        as EHSAmountUTCDateTime,

      ehsamountvalue                                                              as EHSAmountValue,

      value                                                                       as EHSAmountValueAsText,

      @Semantics.unitOfMeasure
      unitofmeasure                                                               as UnitOfMeasure,
      _UnitText._Text[1: Language =  $session.system_language ].UnitOfMeasureName as UnitOfMeasureName,
      cast(unitofmeasuredimension as dimid preserving type )                      as UnitOfMeasureDimension,

      ehsamountcategory                                                           as EHSAmountCategory,
      ehsamountsubjcomponenttype                                                  as EHSAmountSubjComponentType,
      ehsamountsubjcomponentuuid                                                  as EHSAmountSubjComponentUUID,
      ehsamountismissing                                                          as EHSAmountIsMissing,
      ehsamountisfaulty                                                           as EHSAmountIsFaulty,
      ehsamountisnotavailable                                                     as EHSAmountIsNotAvailable,
      ehsamountisreplaced                                                         as EHSAmountIsReplaced,
      ehsamountdeviationid                                                        as EHSAmountDeviationID,
      ehsamounthaswarning                                                         as EHSAmountHasWarning,
      ehsamountispreliminary                                                      as EHSAmountIsPreliminary,

      @ObjectModel.foreignKey.association: '_EHSAmountStatus'
      cast( ehsamountstatus as ehfnd_amns_status_code_nc preserving type )        as EHSAmountStatus,
      ehsamountstatus                                                             as EHSAmountStatusName,


      ehsamountexternalsource                                                     as EHSAmountExternalSource,

      ehsamtoutofprecisenessoptr                                                  as EHSAmtOutOfPrecisenessOptr,

      note                                                                        as Note,
      
      ehsamountmigrationsource                                                    as EHSAmountMigrationSource,
      
      ehsdataamountcontrollingobject                                              as EHSDataAmountControllingObject,
      // associations

      _EHSAmountStatus, 
      _UnitText,

      //      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]

      _EHSAmountHistory,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _EHSAmountLimitFail

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT",
"EHFNDD_KV_TEMP",
"EHFNDV_AMNS_ROOT"
],
"ASSOCIATED":
[
"E_EHSDATAAMOUNT",
"I_EHSAMOUNTHISTORY",
"I_EHSAMOUNTLIMITFAIL",
"I_EHSAMOUNTSOURCETYPE",
"I_EHSAMOUNTSTATUS",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/