I_DUNNINGENTRY
Dunning Entry
I_DUNNINGENTRY is a CDS View in S/4HANA. Dunning Entry. It contains 31 fields. 5 CDS views read from this table.
CDS Views using this table (5)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_DunningEntry | view | from | CONSUMPTION | Dunning Entry |
| C_EmailDunningEntryData | view_entity | from | CONSUMPTION | Email Data For Dunning Entry |
| C_MyDunnProposals | view_entity | from | CONSUMPTION | My Dunning Proposals |
| I_DunningEntryForOutpDetn | view_entity | from | COMPOSITE | Determine Output Parameter for Dunning |
| P_DunningNoticeOMPrmDet | view | from | CONSUMPTION | Dunning Notice OM Param Determination |
Fields (31)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CompanyCode | CompanyCode | 2 |
| KEY | Customer | Customer | 1 |
| KEY | CustomerHeadOffice | CustomerHeadOffice | 2 |
| KEY | DunningClerk | DunningClerk | 2 |
| KEY | DunningRun | DunningRun | 2 |
| KEY | DunningRunDate | DunningRunDate | 2 |
| KEY | FinancialAccountType | FinancialAccountType | 2 |
| KEY | GroupingDunningArea | GroupingDunningArea | 2 |
| KEY | GroupingDunningLevel | GroupingDunningLevel | 1 |
| KEY | OneTimeAcctBankAccount | OneTimeAcctBankAccount | 2 |
| KEY | Supplier | Supplier | 2 |
| _AccountingClerk | _AccountingClerk | 1 | |
| _CompanyCode | _CompanyCode | 1 | |
| _Customer | _Customer | 2 | |
| _DunningBlockingReason | _DunningBlockingReason | 1 | |
| CityName | CityName | 1 | |
| Country | Country | 1 | |
| DocIncldUpToPostgDate | DocIncldUpToPostgDate | 1 | |
| DunAreaAcctBalanceDunCrcy | DunAreaAcctBalanceDunCrcy | 1 | |
| DunningBlockingReason | DunningBlockingReason | 1 | |
| DunningCurrency | DunningCurrency | 2 | |
| DunningDate | DunningDate | 1 | |
| DunningLevel | DunningLevel | 2 | |
| DunningNoticeIsToBeSent | DunningNoticeIsToBeSent,PrintIsReal | 2 | |
| DunningPrintDate | DunningPrintDate | 1 | |
| DunningRecipient | DunningRecipient | 1 | |
| LastDunningPrntDate | LastDunningPrntDate | 1 | |
| LegDunningProcedureOn | LegDunningProcedureOn | 1 | |
| POBox | POBox | 1 | |
| PostalCode | PostalCode | 1 | |
| StreetName | StreetName | 1 |
@AbapCatalog.sqlViewName: 'IDUNNINGENTRY'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Dunning Entry'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel: { supportedCapabilities: [#EXTRACTION_DATA_SOURCE,#SQL_DATA_SOURCE ] }
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations:true
@Analytics.dataExtraction: {
enabled: true,
delta.changeDataCapture:
{
mapping: [
{
viewElement: [ 'DunningRunDate' , 'DunningRun', 'FinancialAccountType' ,'CompanyCode',
'Customer', 'Supplier', 'OneTimeAcctBankAccount', 'CustomerHeadOffice',
'GroupingDunningArea', 'GroupingDunningLevel','DunningClerk' ],
role: #MAIN,
table: 'MHNK',
tableElement: ['laufd', 'laufi', 'koart', 'bukrs', 'kunnr', 'lifnr', 'cpdky',
'sknrze', 'smaber', 'smahsk', 'busab']
},
{
viewElement: [ 'CompanyCode' ],
role: #LEFT_OUTER_TO_ONE_JOIN,
table: 'T001',
tableElement: [ 'bukrs' ]
}
]
}
}
define view I_DunningEntry
as select from mhnk
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..1] to I_FinancialAccountType as _FinancialAccountType on $projection.FinancialAccountType = _FinancialAccountType.FinancialAccountType
association [1..1] to I_Customer as _Customer on $projection.Customer = _Customer.Customer
association [1..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [1..1] to I_DunningArea as _DunningArea on $projection.CompanyCode = _DunningArea.CompanyCode
and $projection.GroupingDunningArea = _DunningArea.DunningArea
association [1..1] to I_Currency as _DunningCurrency on $projection.DunningCurrency = _DunningCurrency.Currency
association [0..1] to I_DunningBlockingReasonCode as _DunningBlockingReason on $projection.DunningBlockingReason = _DunningBlockingReason.DunningBlockingReason
association [0..1] to I_AccountingClerk as _AccountingClerk on $projection.CompanyCode = _AccountingClerk.CompanyCode
and $projection.DunningClerk = _AccountingClerk.AccountingClerk
association [1..1] to I_Country as _Country on $projection.Country = _Country.Country
association [0..*] to I_DunningEntryItem as _DunningEntryItem on $projection.DunningRunDate = _DunningEntryItem.DunningRunDate
and $projection.DunningRun = _DunningEntryItem.DunningRun
and $projection.FinancialAccountType = _DunningEntryItem.FinancialAccountType
and $projection.CompanyCode = _DunningEntryItem.CompanyCode
and $projection.Customer = _DunningEntryItem.Customer
and $projection.Supplier = _DunningEntryItem.Supplier
and $projection.OneTimeAcctBankAccount = _DunningEntryItem.OneTimeAcctBankAccount
and $projection.CustomerHeadOffice = _DunningEntryItem.CustomerHeadOffice
and $projection.GroupingDunningArea = _DunningEntryItem.GroupingDunningArea
and $projection.DunningLevel = _DunningEntryItem.DunningLevel
association [0..1] to I_DunningProcedure as _DunningProcedure on $projection.DunningProcedure = _DunningProcedure.DunningProcedure
{
key cast(mhnk.laufd as farp_laufd_mhn preserving type) as DunningRunDate,
key cast(mhnk.laufi as farp_laufi_mhn preserving type) as DunningRun,
@ObjectModel.foreignKey.association: '_FinancialAccountType'
key cast(mhnk.koart as farp_koart preserving type) as FinancialAccountType,
@ObjectModel.foreignKey.association: '_CompanyCode'
key cast(mhnk.bukrs as fis_bukrs preserving type) as CompanyCode,
@ObjectModel.foreignKey.association: '_Customer'
key mhnk.kunnr as Customer,
@ObjectModel.foreignKey.association: '_Supplier'
key cast(mhnk.lifnr as md_supplier preserving type) as Supplier,
key cast(mhnk.cpdky as bankn) as OneTimeAcctBankAccount,
key mhnk.sknrze as CustomerHeadOffice,
@ObjectModel.foreignKey.association: '_DunningArea'
key mhnk.smaber as GroupingDunningArea,
key cast( mhnk.smahsk as farp_group_dunn_level preserving type ) as GroupingDunningLevel,
@ObjectModel.foreignKey.association: '_AccountingClerk'
key mhnk.busab as DunningClerk,
mhnk.ausdt as DunningDate,
mhnk.grdat as DocIncldUpToPostgDate,
mhnk.knrma as DunningRecipient,
mhnk.gmvdt as LegDunningProcedureOn,
mhnk.mahna as DunningProcedure,
cast(mhnk.mahns as farp_mahns_d preserving type) as DunningLevel,
cast(mhnk.vzskz as farp_vzskz preserving type) as InterestCalculationCode,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_DunningCurrency'
cast(mhnk.waers as farp_waers_mhn preserving type) as DunningCurrency,
@Semantics.amount.currencyCode: 'DunningCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.saldo as farp_salfw_mhnk preserving type) as DunAreaAcctBalanceDunCrcy,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.salhw as farp_salhw_mhnk preserving type) as DunAreaAcctBalanceCCCrcy,
@Semantics.amount.currencyCode: 'DunningCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.gsfbt as farp_gsfbt_mhnk preserving type) as DueItemsBlockedInDunCrcy,
@Semantics.amount.currencyCode: 'DunningCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.gsnbt as farp_gsnbt_mhnk preserving type) as NotDueItemsBlockedInDunCrcy,
@Semantics.amount.currencyCode: 'DunningCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.faebt as farp_faebt_mhnk preserving type) as DueLineItemsTotalInDunCrcy,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.faehw as farp_faehw_mhnk preserving type) as DueLineItemsTotalInCCCrcy,
// mhnk.xmflg as DunningNoticeIsSent,
mhnk.xmflg as DunningNoticeIsToBeSent,
@ObjectModel.foreignKey.association: '_DunningBlockingReason'
cast(mhnk.mansp as farp_mansp preserving type) as DunningBlockingReason,
cast(mhnk.mahsk as maxst preserving type) as MaximumDunningLevel,
@Semantics.amount.currencyCode: 'DunningCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.zinbt as farp_dzinbt_mhn preserving type) as InterestAmountInDunCrcy,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.zinhw as farp_dzinhw_mhn preserving type) as InterestAmountInCCCrcy,
mhnk.xzins as InterestIsNotDisplayed,
mhnk.mgrup as DunningNoticeGroup,
mhnk.vertn as TreasuryContract,
mhnk.vertt as TreasuryContractType,
cast(mhnk.imkey as farp_imkey preserving type) as RealEstateObject,
@Semantics.amount.currencyCode: 'DunningCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.famsm as farp_famsm_mhnk preserving type) as DueItemDunLevelTotalInDunCrcy,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
// @DefaultAggregation: #NONE
mhnk.famsh as DueItemDunLevelTotalInCCCrcy,
cast(mhnk.pstlz as ad_pstcd1 preserving type) as PostalCode,
cast(mhnk.ort01 as ad_city1) as CityName,
mhnk.stras as StreetName,
cast(mhnk.pfach as ad_pobx preserving type) as POBox,
@ObjectModel.foreignKey.association: '_Country'
cast(mhnk.land1 as land1_gp preserving type) as Country,
mhnk.avsid as PaymentAdvice,
mhnk.applk as BusTransEventApplication,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.mhngh as farp_mhngh_f150 preserving type) as DunningChargeInCCCrcy,
@Semantics.amount.currencyCode: 'DunningCurrency'
// @DefaultAggregation: #NONE
cast(mhnk.mhngf as farp_mhngf_f150 preserving type) as DunningChargeInDunCrcy,
cast(mhnk.prndt as farp_prndt preserving type) as DunningPrintDate,
mhnk.prndt_before as LastDunningPrntDate,
@Semantics.currencyCode: true
_CompanyCode.Currency as CompanyCodeCurrency,
_CompanyCode,
_Customer,
_Supplier,
_FinancialAccountType,
_DunningArea,
_DunningCurrency,
_DunningBlockingReason,
_AccountingClerk,
_Country,
_DunningEntryItem,
_DunningProcedure
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"MHNK"
],
"ASSOCIATED":
[
"I_ACCOUNTINGCLERK",
"I_COMPANYCODE",
"I_COUNTRY",
"I_CURRENCY",
"I_CUSTOMER",
"I_DUNNINGAREA",
"I_DUNNINGBLOCKINGREASONCODE",
"I_DUNNINGENTRYITEM",
"I_DUNNINGPROCEDURE",
"I_FINANCIALACCOUNTTYPE",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/