I_DISTRIBUTIONCHANNEL

CDS View

Distribution Channel

I_DISTRIBUTIONCHANNEL is a CDS View in S/4HANA. Distribution Channel. 6 CDS views read from this table.

Used by 6 CDS view(s)

CDS Views using this table (6)

ViewTypeJoinVDMDescription
A_DistributionChannel view from BASIC Distribution Channel
C_WrntyDistributionChannelVH view from CONSUMPTION value help for distrib channel WRNTY
FAC_DistributionChannelVH view from Data Source for Distribution Channel
I_CnsldtnMasterData view union_all COMPOSITE Consolidation - Combined Master Data
I_LastMileDistrChannelVH view from BASIC LMD - Distribution Channel Value Help
P_CnsldtnDistributionChannel view from COMPOSITE 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'DistributionChannel'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Distribution Channel'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:  #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISDDISTRCHANNEL'
@Search.searchable: true
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@Metadata.ignorePropagatedAnnotations: true
@Analytics.dataExtraction.enabled: true

@ObjectModel.modelingPattern:           #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities:  [  #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #ANALYTICAL_DIMENSION,
                                        #SEARCHABLE_ENTITY,
                                        #EXTRACTION_DATA_SOURCE  ]

@ObjectModel.alternativeKey: [{ id: 'OID', uniqueness: #UNIQUE, element: ['DistributionChannelOID'] }]
@ObjectModel.sapObjectNodeType.name:'DistributionChannel'
@ObjectModel.objectIdentifier.oidElement:'DistributionChannelOID'

define view I_DistributionChannel
  as select from tvtw
    left outer to one join mdi_oid_config
    on mdi_oid_config.object_type_code = 'DRF_0049'
  association [0..*] to I_DistributionChannelText as _Text on $projection.DistributionChannel = _Text.DistributionChannel
  
{
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @ObjectModel.text.association: '_Text'
  key vtweg as DistributionChannel,
  
  @ObjectModel.filter.enabled: false
  @ObjectModel.sort.enabled: false
  case
    when mdi_oid_config.context is initial or mdi_oid_config.compose_oid is initial
      then cast( vtweg as distributionchannel_oid )
    when mdi_oid_config.context is not initial and mdi_oid_config.compose_oid is not initial
      then cast( concat( concat( mdi_oid_config.context, ':' ), vtweg ) as distributionchannel_oid )
  end as DistributionChannelOID,
           
  _Text
};          
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MDI_OID_CONFIG",
"TVTW"
],
"ASSOCIATED":
[
"I_DISTRIBUTIONCHANNELTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More