I_DEFECTCODEGROUP

CDS View

Defect Code Group

I_DEFECTCODEGROUP is a CDS View in S/4HANA. Defect Code Group. It contains 2 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 2 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_DefectCodeGroup view from BASIC Defect Code Groups
I_DefectCodeGroupStdVH view from COMPOSITE Defect Code Group

Fields (2)

KeyField CDS FieldsUsed in Views
KEY DefectCodeGroup DefectCodeGroup 1
CodeGroupStatus CodeGroupStatus 1 
@AbapCatalog.sqlViewName: 'IDEFECTCODEGRP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Defect Code Group'
@AccessControl.authorizationCheck: #CHECK
@VDM: {
    viewType:#BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel: {
    representativeKey: 'DefectCodeGroup',
    usageType: { serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING }
}
@Metadata.ignorePropagatedAnnotations: true
define view I_DefectCodeGroup as select from qpgr 

  association [0..*] to I_DefectCodeGroupText as _Text
    on $projection.DefectCodeGroup     = _Text.DefectCodeGroup
    
  association [0..*] to I_DefectCode as _DefectCode
    on $projection.DefectCodeGroup = _DefectCode.DefectCodeGroup
    
{
  @ObjectModel.text.association: '_Text'
  key cast( qpgr.codegruppe as vdm_qfegrp preserving type )   as DefectCodeGroup,
  
  // DB field has three values, but field shall be indicator

  @Semantics.booleanIndicator: true
  case qpgr.inaktiv
    when ' ' then cast( ' ' as vdm_qm_codegroupisinactive preserving type )
    else cast( 'X' as vdm_qm_codegroupisinactive preserving type )
  end                                                        as CodeGroupIsInactive,
  
  qpgr.status                                                as CodeGroupStatus,

  //Associations

  _Text,
  _DefectCode
  
} where qpgr.katalogart = '9' // Defects

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QPGR"
],
"ASSOCIATED":
[
"I_DEFECTCODE",
"I_DEFECTCODEGROUPTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More