I_DATACOLLECTIONROOT

CDS View

Data Collection Root

I_DATACOLLECTIONROOT is a CDS View in S/4HANA. Data Collection Root. It contains 2 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 2 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_EnvrmtAmountsForActivity view inner COMPOSITE Amounts for Activities

Fields (2)

KeyField CDS FieldsUsed in Views
DataUsagePeriodicity DataUsagePeriodicity 1
EHSLocationUUID EHSLocationUUID 1 
@AbapCatalog.sqlViewName: 'IMDEFROOT'
@EndUserText.label: 'Data Collection Root'
@VDM.viewType: #COMPOSITE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { dataClass: #MASTER,
                          serviceQuality: #D,
                          sizeCategory: #M }

define view I_DataCollectionRoot
  as select from I_DataCollectionRootBasic
  association [0..1] to I_UnitOfMeasure       as _UnitText      on $projection.UnitOfMeasure = _UnitText.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure       as _UnitTextAlt   on $projection.EHSAltvUnitOfMeasurement = _UnitTextAlt.UnitOfMeasure
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [1..1] to I_EHSLocationRevision as _EHSLocation   on $projection.EHSLocationUUID     = _EHSLocation.EHSLocationUUID
                                                                and(
                                                                  _EHSLocation.RevisionStartDate   <= $session.system_date
                                                                  and _EHSLocation.RevisionEndDate >= $session.system_date
                                                                )
  association [0..1] to I_EHSDataPeriod       as _EHSDataPeriod on $projection.DataUsagePeriodicity = _EHSDataPeriod.EHSDataPeriod
{

  key DataCollectionUUID,

      CreationDateTime,
      LastChangeDateTime,

      CreatedByUser,

      LastChangedByUser,

      DataCollectionID,
      DataCollectionName,

      DataCollectionInputMethod,
      EHSAmountExternalSource,
      DataUsagePeriodicity,

      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_UnitText'
      UnitOfMeasure,
      _UnitText._Text[1: Language =  $session.system_language ].UnitOfMeasureName    as UnitOfMeasureName,
      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_UnitTextAlt'
      EHSAltvUnitOfMeasurement                                                       as EHSAltvUnitOfMeasurement,
      _UnitTextAlt._Text[1: Language =  $session.system_language ].UnitOfMeasureName as EHSAltvUnitOfMeasurementName,
      _UnitText,
      _UnitTextAlt,


      EHSSubjectType,
      EHSSubjectUUID,
      DataCollectionTitle,

      @ObjectModel.foreignKey.association: '_EHSLocation'
      EHSLocationUUID,

      _EHSLocation._EHSLocRespTechnician.EHSLocRespTechnicianID                      as EHSLocRespTechnicianID,

      _EHSLocation,

      _EHSDataPeriod

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DATACOLLECTIONROOTBASIC",
"I_EHSLOCATIONREVISION",
"I_EHSLOCRESPTECHNICIANCOMBINED",
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT"
],
"ASSOCIATED":
[
"I_EHSDATAPERIOD",
"I_EHSLOCATIONREVISION",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More