I_DOMAINFIXEDVALUETEXT

@EndUserText:   {label:              'Domain Fixed Value Text'}
@ObjectModel:   {representativeKey:  'DomainValue',
                 dataCategory:       #TEXT,
                 usageType:          {serviceQuality: #B,
                                      sizeCategory:   #XL,
                                      dataClass:      #CUSTOMIZING}}
@VDM:           {viewType:           #BASIC}
@AbapCatalog:   {sqlViewName:        'IDOMFIXVALTEXT',
                 compiler:           {compareFilter:  true}}
@AccessControl: {authorizationCheck: #NOT_REQUIRED}
@ClientHandling.algorithm:           #SESSION_VARIABLE

// views deprecated for Cloud 1808/ OP 1809

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'NONE'


define view I_DomainFixedValueText
  as select from dd07t
  association [1..1] to I_Domain           as _Domain           on  $projection.SAPDataDictionaryDomain = _Domain.SAPDataDictionaryDomain
                                                                and $projection.DomainActivationState   = _Domain.DomainActivationState
                                                                and $projection.DomainVersion           = _Domain.DomainVersion
  association [1..1] to I_DomainFixedValue as _DomainFixedValue on  $projection.SAPDataDictionaryDomain = _DomainFixedValue.SAPDataDictionaryDomain
                                                                and $projection.DomainValue             = _DomainFixedValue.DomainValue
                                                                and $projection.DomainActivationState   = _DomainFixedValue.DomainActivationState
                                                                and $projection.DomainValuePosition     = _DomainFixedValue.DomainValuePosition
                                                                and $projection.DomainVersion           = _DomainFixedValue.DomainVersion
  association [0..1] to I_Language         as _Language         on  $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Domain'
  key domname     as  SAPDataDictionaryDomain,
  key domvalue_l  as  DomainValue,
      @Semantics.language: true
  key ddlanguage  as  Language,
  key as4local    as  DomainActivationState,
  key valpos      as  DomainValuePosition,
  key as4vers     as  DomainVersion,

      @Semantics.text: true
      ddtext      as  DomainText,

      /* Associations */
      _Domain,
      _DomainFixedValue,
      _Language
}
where
  as4local = 'A';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_DOMAIN",
"I_DOMAINFIXEDVALUE",
"I_LANGUAGE"
],
"BASE":
[],
"VERSION":0
}
}*/