I_CUSTOMERRETURNSERIALNUMBER

CDS View

Returns Order Serial Number

I_CUSTOMERRETURNSERIALNUMBER is a CDS View in S/4HANA. Returns Order Serial Number. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_CustomerReturnSerialNumber view from COMPOSITE Serial Number 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.usageType: {
            dataClass: #TRANSACTIONAL,
            serviceQuality: #C,
            sizeCategory: #XL }
@EndUserText.label: 'Returns Order Serial Number'
@VDM.viewType: #COMPOSITE
@AccessControl: { authorizationCheck: #CHECK,
                  personalData.blocking: #NOT_REQUIRED }
@AbapCatalog.sqlViewName: 'ISDCUSTRETSERNO'
@Metadata.ignorePropagatedAnnotations: true

define view I_CustomerReturnSerialNumber
  as select from I_MaintItmObjListSalesOrder as _MaintItmObjListSalesOrder

    inner join   I_MaintenanceItemObject     as _MaintenanceItemObject on _MaintItmObjListSalesOrder.MaintenanceItemObjectList = _MaintenanceItemObject.MaintenanceItemObjectList

  association [1..1] to I_CustomerReturn     as _CustomerReturn     on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn
  association [1..1] to I_CustomerReturnItem as _CustomerReturnItem on  $projection.CustomerReturn     = _CustomerReturnItem.CustomerReturn
                                                                    and $projection.CustomerReturnItem = _CustomerReturnItem.CustomerReturnItem
{
  key SerialNumber,
      @ObjectModel.foreignKey.association: '_CustomerReturn'
  key SalesOrder     as CustomerReturn,
      @ObjectModel.foreignKey.association: '_CustomerReturnItem'
  key SalesOrderItem as CustomerReturnItem,

      // For Access control

      @Consumption.hidden: true
      _CustomerReturn.CustomerReturnType,
      @Consumption.hidden: true
      _CustomerReturn.OrganizationDivision,
      @Consumption.hidden: true
      _CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      _CustomerReturn.DistributionChannel,

      _CustomerReturn,
      _CustomerReturnItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERRETURN",
"I_MAINTENANCEITEMOBJECT",
"I_MAINTITMOBJLISTSALESORDER"
],
"ASSOCIATED":
[
"I_CUSTOMERRETURN",
"I_CUSTOMERRETURNITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More