I_CUSTSALESPARTNERFUNC_2

CDS View

Customer Sales Area Partner Function

I_CUSTSALESPARTNERFUNC_2 is a CDS View in S/4HANA. Customer Sales Area Partner Function. It contains 10 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 10 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_Customer360InternalContact view_entity from CONSUMPTION Customer 360 Internal Contact
C_ShipToPartyByCustSalesAreaVH view_entity from CONSUMPTION Ship To Party By Sales Area
P_SuplrReturnToPartnerFunction view from COMPOSITE

Fields (10)

KeyField CDS FieldsUsed in Views
KEY Customer Customer 3
KEY DistributionChannel DistributionChannel 3
KEY Division Division 3
KEY PartnerCounter PartnerCounter 2
KEY PartnerFunction PartnerFunction 1
KEY PersonnelNumber Personnel 1
KEY SalesOrganization SalesOrganization 3
_Customer _Customer 1
_CustomerSalesArea _CustomerSalesArea 2
BPCustomerNumber BPCustomerNumber 1 
@AbapCatalog.sqlViewName: 'ICUSTPARTFUNC2'
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey:'PartnerFunction'
@Analytics.internalName:#LOCAL 
@AbapCatalog.preserveKey:true 
@AccessControl.privilegedAssociations:  [ '_CustSalesPartnerCounter']
@AccessControl.personalData.blockingIndicator: ['_CustomerSalesArea.IsBusinessPurposeCompleted'] 
@Metadata.allowExtensions:true
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET]                                     
@ObjectModel.modelingPattern: #NONE                                     
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@EndUserText.label: 'Customer Sales Area Partner Function'
@Metadata.ignorePropagatedAnnotations: true

define view I_CustSalesPartnerFunc_2 as select from knvp

association[1..1] to I_CustomerSalesArea as _CustomerSalesArea on $projection.Customer =  _CustomerSalesArea.Customer 
                                                               and $projection.SalesOrganization =  _CustomerSalesArea.SalesOrganization 
                                                               and $projection.DistributionChannel =  _CustomerSalesArea.DistributionChannel
                                                               and $projection.Division =  _CustomerSalesArea.Division 

association[1..1] to I_Customer as _Customer on $projection.Customer =  _Customer.Customer
association [0..1] to I_SalesOrganization    as _SalesOrganization   on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization  
association [0..1] to I_DistributionChannel  as _DistributionChannel on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
association [0..1] to I_Division             as _Division            on  $projection.Division = _Division.Division
association [0..1] to I_CustSalesPartnerCounter      as _CustSalesPartnerCounter     on $projection.PartnerCounter = _CustSalesPartnerCounter.PartnerCounter  
{
 @ObjectModel.foreignKey.association: '_Customer'
  key knvp.kunnr                                                      as Customer,
  @ObjectModel.foreignKey.association: '_SalesOrganization'
  key knvp.vkorg                                                      as SalesOrganization,
  @ObjectModel.foreignKey.association: '_DistributionChannel'
  key knvp.vtweg                                                      as DistributionChannel,
  @ObjectModel.foreignKey.association: '_Division'
  key knvp.spart                                                      as Division,
  @ObjectModel.foreignKey.association: '_CustSalesPartnerCounter'
  key knvp.parza                                                      as PartnerCounter,
  key cast(knvp.parvw as parvw_unv)                                   as PartnerFunction, //partner role

      knvp.kunn2                                                      as BPCustomerNumber,
      knvp.knref                                                      as CustomerPartnerDescription,
      knvp.defpa                                                      as DefaultPartner,
      knvp.lifnr                                                      as Supplier,
      knvp.pernr                                                      as PersonnelNumber,
      knvp.parnr                                                      as ContactPerson,
      knvp.adrnr                                                      as AddressID,
      //_CustomerSalesArea._Customer.AuthorizationGroup, *Field removed to reduce complexity, use from association instead*

      _CustomerSalesArea,
      _Customer,
      _SalesOrganization,
      _DistributionChannel,
      _Division,    
      _CustSalesPartnerCounter
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"KNVP"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_CUSTOMERSALESAREA",
"I_CUSTSALESPARTNERCOUNTER",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESORGANIZATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More