I_COSTELEMENTONCHARTOFACCOUNTS

CDS View

Cost Element depend on Chart of Accounts

I_COSTELEMENTONCHARTOFACCOUNTS is a CDS View in S/4HANA. Cost Element depend on Chart of Accounts. It contains 4 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 4 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_CostElement view inner COMPOSITE Cost Element
P_DMVCECCostElement view_entity inner BASIC

Fields (4)

KeyField CDS FieldsUsed in Views
ChartOfAccounts ChartOfAccounts 2
CreatedByUser CreatedByUser 1
CreationDate CreationDate 1
FunctionalArea FunctionalArea 1 
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'ICECHTACCTS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Cost Element depend on Chart of Accounts'
@ObjectModel.representativeKey: 'CostElement'
@ObjectModel.usageType: {
  serviceQuality: #A,
  sizeCategory: #S,
  dataClass: #MASTER
}
define view I_CostElementOnChartOfAccounts
  as select from cska

  association [0..1] to I_ChartOfAccounts              as _ChartOfAccounts              on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts

  association [0..1] to I_FunctionalArea               as _FunctionalArea               on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea

  association [0..*] to I_CostElementText              as _Text                         on  $projection.ChartOfAccounts = _Text.ChartOfAccounts
                                                                                        and $projection.CostElement     = _Text.CostElement

  association [0..*] to I_CostElementOnControllingArea as _CostElementOnControllingArea on  $projection.ChartOfAccounts = _CostElementOnControllingArea.ChartOfAccounts
                                                                                        and $projection.CostElement     = _CostElementOnControllingArea.CostElement

  association [0..1] to I_GLAccountInChartOfAccounts   as _GLAccountInChartOfAccounts   on  $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts
                                                                                        and $projection.CostElement     = _GLAccountInChartOfAccounts.GLAccount

{
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
  key ktopl     as ChartOfAccounts,
      @ObjectModel.text.association: '_Text'
  key kstar     as CostElement,

      @Semantics.systemDate.createdAt: true
      ersda     as CreationDate,
      @Semantics.user.createdBy: true
      usnam     as CreatedByUser,

      @ObjectModel.foreignKey.association: '_FunctionalArea'
      func_area as FunctionalArea,

      _ChartOfAccounts,
      _FunctionalArea,
      _CostElementOnControllingArea,
      _GLAccountInChartOfAccounts,
      _Text
}             
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"CSKA"
],
"ASSOCIATED":
[
"I_CHARTOFACCOUNTS",
"I_COSTELEMENTONCONTROLLINGAREA",
"I_COSTELEMENTTEXT",
"I_FUNCTIONALAREA",
"I_GLACCOUNTINCHARTOFACCOUNTS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More