I_CONTRACTACCOUNTPARTNER
Contract Account Partner
I_CONTRACTACCOUNTPARTNER is a CDS View in S/4HANA. Contract Account Partner. It contains 29 fields. 40 CDS views read from this table.
CDS Views using this table (40)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_ContractAccountPartner | view_entity | from | BASIC | Vertragskonto Partner |
| C_CAInvcgOvwDisp | view | from | CONSUMPTION | Fakturierungsübersicht für Vertr.konten |
| C_ContractacCBPCFO | view | from | CONSUMPTION | Vertragskonto |
| C_ContractAccountPartner | view | from | CONSUMPTION | Contract Account Partner |
| C_ContractAccountValueHelp | view | from | CONSUMPTION | Vertragskonto |
| C_OutsrtdUtilsBillgMaLeApply | view | left_outer | CONSUMPTION | Machine Learning Apply Data for Outsorted Billing |
| C_OutsrtdUtilsBillgMaLeTrng | view | left_outer | CONSUMPTION | Machine Learning Training Data for Outsorted Billing |
| C_OutsrtdUtilsInvcgDocOvw | view | inner | CONSUMPTION | Outsorted Invoicing Document |
| C_OutsrtdUtilsInvcgDocument | view_entity | inner | CONSUMPTION | Outsorted Invoicing Document |
| C_SbsMssProcgContractAccountVH | view_entity | from | CONSUMPTION | Contract Account |
| CRMS4_IU_I_CAP | view | from | Contract Account Partner | |
| CRMS4_IU_P_CNTBPC | view | left_outer | Business partner ISU-Contracts count | |
| CRMS4_IU_P_CNTBPCA | view | left_outer | Business partner contracts accounts count | |
| CRMS4_IU_P_CONBP | view | from | ||
| CRMS4_IU_P_PODBP | view | from | Point of Delivery by Business Partner | |
| CRMS4_IU_P_PODBP | view | union | Point of Delivery by Business Partner | |
| ESH_N_CONTRACTACCOUNT | view | from | ||
| I_ContractAccountPartnerStdVH | view | from | COMPOSITE | Contract Account Partner |
| I_ContractAccountPartnerVH | view | from | COMPOSITE | Suchhilfe für Vertragskonto Partner |
| I_LockedUtilsContrToBeInvcd | view | inner | COMPOSITE | Locked Contract to Be Invoiced |
| I_OpenUtilsBillgDocAndOrd | view | inner | COMPOSITE | Open Utilities Billing Document and Order |
| I_SchedldUtilsContrNotInvcd | view | inner | COMPOSITE | Scheduled Contract Has not Been Invoiced |
| I_SpprsdUtilsBillgOrdWthDets | view | inner | COMPOSITE | Suppressed Utilities Billing Order with Details |
| I_SuppressedUtilsBillgOrd | view | inner | COMPOSITE | Suppressed Utilities Billing Order |
| I_UtilitiesContractTP | view_entity | inner | TRANSACTIONAL | Utilities Contract |
| I_UtilitiesContractVH | view | inner | COMPOSITE | Contract Value Help |
| I_UtilitiesLossAccountVH | view | from | BASIC | ISU BR Engy Loss Contract Account |
| I_UtilsBillingOrder | view | inner | COMPOSITE | Utilities Billing Order |
| I_UtilsContrToBeBlld | view | inner | COMPOSITE | Utilities Contract to Be Billed |
| I_UtilsContrToBeBlldInvcdAnlys | view | inner | COMPOSITE | Analysis of Contract to Be Billed and Invoiced |
| I_UtilsContrToBeInvcd | view | inner | COMPOSITE | Contract to Be Invoiced |
| I_UtilsInvcgDocBillingData | view | inner | COMPOSITE | Billing Data for Invoicing Document |
| P_ContrAccountEnterpriseSearch | view | from | COMPOSITE | |
| P_ContractAccountPartner | view | from | COMPOSITE | |
| P_ISU_CSML_BUSPARTNERVH_BR | view | inner | BASIC | |
| P_ISU_CSML_PRINTORIGDOCVH_BR | view | inner | BASIC | |
| P_ISU_CSML_SIMULATEDDOCVH_BR | view | inner | BASIC | |
| P_ISU_CSMLDOCIB_BR | view | inner | BASIC | |
| P_ISU_EL_HEADER_BR | view | inner | BASIC | |
| R_ContractAccountPartnerTP | view_entity | from | TRANSACTIONAL | Contract Account Partner - TP |
Fields (29)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | BusinessPartner | BusinessPartner | 14 |
| KEY | ContractAccount | ContractAccount | 11 |
| _AcctDetnCode | _AcctDetnCode | 5 | |
| _AltvContrAcc | _AltvContrAcc | 6 | |
| _AltvInvoiceRecipient | _AltvInvoiceRecipient | 2 | |
| _BusinessPartner | _BusinessPartner | 10 | |
| _ContrAcc | _ContrAcc | 6 | |
| CAAuthorizationGroup | CAAuthorizationGroup | 2 | |
| CABillgCycle | CABillgCycle | 2 | |
| CABusinessPartnerForPayment | CABusinessPartnerForPayment | 1 | |
| CACompanyCodeGroup | CACompanyCodeGroup | 1 | |
| CACorrespondenceVariant | CACorrespondenceVariant | 1 | |
| CADetnCodeForAltvInvoiceForm | CADetnCodeForAltvInvoiceForm | 1 | |
| CADunningProcedure | CADunningProcedure | 1 | |
| CAInvcgCategory | CAInvcgCategory | 2 | |
| CAInvcgSchedule | CAInvcgSchedule | 1 | |
| CALastDayOfBillingPeriod | CALastDayOfBillingPeriod | 1 | |
| CAPaymentMethodForIncgPayment | CAPaymentMethodForIncgPayment | 1 | |
| CAPaymentMethodForOutgPayment | CAPaymentMethodForOutgPayment | 1 | |
| CARelationshipOfBPToContrAcct | CARelationshipOfBPToContrAcct | 1 | |
| CAStandardCompanyCode | CAStandardCompanyCode | 4 | |
| CAStartDateForBillingPeriod | CAStartDateForBillingPeriod | 1 | |
| CATargetCurrencyForInvoicing | CATargetCurrencyForInvoicing | 1 | |
| ContractAccountName | ContractAccountName | 1 | |
| Country | Country | 1 | |
| CreationDate | CreationDate | 1 | |
| PaymentCondition | PaymentCondition | 1 | |
| UtilitiesAccountClass | UtilitiesAccountClass | 1 | |
| UtilsActvBudgetBillgProcedure | UtilsActvBudgetBillgProcedure | 1 |
@AbapCatalog.sqlViewName: 'ICTRACCPARTNER'
@AccessControl: { authorizationCheck: #MANDATORY,
personalData: { blocking: #REQUIRED,
blockingIndicator: ['_BusinessPartner.IsBusinessPurposeCompleted'] } }
@Analytics: { dataCategory: #DIMENSION,
internalName: #LOCAL,
dataExtraction: { enabled: true,
delta.changeDataCapture: { mapping: [ { table : 'FKKVKP',
role : #MAIN,
viewElement : ['ContractAccount', 'BusinessPartner'],
tableElement : ['VKONT', 'GPART' ] },
{ table : 'T001',
role : #LEFT_OUTER_TO_ONE_JOIN,
viewElement : ['CAStandardCompanyCode'],
tableElement : ['BUKRS'] },
{ table : 'TFK001G',
role : #LEFT_OUTER_TO_ONE_JOIN,
viewElement : ['CACompanyCodeGroup'],
tableElement : ['OPBUK'] } ] } } }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Contract Account Partner'
@Metadata: { allowExtensions:true,
ignorePropagatedAnnotations: true }
@ObjectModel: { modelingPattern: #NONE,
representativeKey: 'BusinessPartner',
sapObjectNodeType.name: 'ContractAccount',
supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
#CDS_MODELING_DATA_SOURCE,
#SQL_DATA_SOURCE,
#EXTRACTION_DATA_SOURCE,
#ANALYTICAL_DIMENSION ],
usageType: { dataClass: #MASTER,
serviceQuality: #B,
sizeCategory: #XL } }
@VDM.viewType: #BASIC
define view I_ContractAccountPartner
as select from fkkvkp
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [1..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [0..1] to I_BusinessPartner as _AlternativePayer on $projection.CAAlternativePayer = _AlternativePayer.BusinessPartner
association [0..1] to I_BusinessPartner as _AlternativePayee on $projection.CAAlternativePayee = _AlternativePayee.BusinessPartner
association [0..1] to I_BusinessPartner as _AltvDunningRecipient on $projection.CAAlternativeDunningRecipient = _AltvDunningRecipient.BusinessPartner
association [0..1] to I_BusinessPartner as _AltvInvoiceRecipient on $projection.CAAlternativeInvoiceRecipient = _AltvInvoiceRecipient.BusinessPartner
association [0..1] to I_BusinessPartner as _AltvCorrespncRcpnt on $projection.CAAlternativeCorrespncRcpnt = _AltvCorrespncRcpnt.BusinessPartner
association [0..1] to I_BusinessPartner as _BPForPayment on $projection.CABusinessPartnerForPayment = _BPForPayment.BusinessPartner
association [0..1] to I_BusinessPartner as _CollContactPerson on $projection.CACollectionsContactPerson = _CollContactPerson.BusinessPartner
association [0..1] to I_BusinessPartner as _BPForPosting on $projection.CABusinessPartnerForPosting = _BPForPosting.BusinessPartner
association [0..1] to I_BusinessPartner as _BPForInvcgList on $projection.CABusinessPartnerForInvcgList = _BPForInvcgList.BusinessPartner
association [0..1] to I_CAAccountDetnCode as _AcctDetnCode on $projection.CAAccountDeterminationCode = _AcctDetnCode.CAAccountDeterminationCode
association [0..1] to I_CAAuthorizationGroup as _CAAuthorizationGroup on $projection.CAAuthorizationGroup = _CAAuthorizationGroup.CAAuthorizationGroup
and _CAAuthorizationGroup.CAAuthorizationGroupObject = 'CA_CONTACC'
association [1..1] to I_CABillgCycle as _BillgCycle on $projection.CABillgCycle = _BillgCycle.CABillgCycle
association [0..1] to I_CABusPrtnAddlLockExstcCode as _CABusPrtnAddlLockExstcCode on $projection.CABusPartnerAddlLockExstcCode = _CABusPrtnAddlLockExstcCode.CABusPartnerAddlLockExstcCode
association [0..1] to I_CABusPrtnPostgLockExstcCode as _CABusPrtnPostgLockExstcCode on $projection.CABusPartnerPostgLockExstcCode = _CABusPrtnPostgLockExstcCode.CABusPartnerPostgLockExstcCode
association [0..1] to I_CAClearingCategory as _ClearingCategory on $projection.CAClearingCategory = _ClearingCategory.CAClearingCategory
association [0..1] to I_CACollectionStrategy as _CollectionStrategy on $projection.CACollectionStrategy = _CollectionStrategy.CACollectionStrategy
association [0..1] to I_CACollMasterDataGroup as _CollMasterDataGroup on $projection.CACollectionsMasterDataGroup = _CollMasterDataGroup.CACollectionsMasterDataGroup
association [1..1] to I_CACompanyCodeGroup as _CompCodeGroup on $projection.CACompanyCodeGroup = _CompCodeGroup.CACompanyCodeGroup
association [0..1] to I_CACorrespncActivityCode as _CACorrespncActivityCode on $projection.CACorrespondenceActivityCode = _CACorrespncActivityCode.CACorrespondenceActivityCode
association [1..1] to I_CACorrespondenceVariant as _CorrVariant on $projection.CACorrespondenceVariant = _CorrVariant.CACorrespondenceVariant
association [1..1] to I_CACorrespondenceVariant as _CorrespncVar on $projection.CACorrespondenceVariant = _CorrespncVar.CACorrespondenceVariant
association [1..1] to I_CADfltClearingRstrcnCode as _CADfltClearingRstrcnCode on $projection.CADefaultClearingRstrcnCode = _CADfltClearingRstrcnCode.CADefaultClearingRstrcnCode
association [0..1] to I_CADirectDebitLimitCalcMode as _CADirectDebitLimitCalcMod on $projection.CADirectDebitLimitCalcMode = _CADirectDebitLimitCalcMod.CADirectDebitLimitCalcMode
association [0..1] to I_CADunningProcedure as _DunningProcedure on $projection.CADunningProcedure = _DunningProcedure.CADunningProcedure
association [0..1] to I_CADunningNoticeGroup as _DunNoticeGroup on $projection.CADunningNoticeGroup = _DunNoticeGroup.CADunningNoticeGroup
association [0..1] to I_CAHouseBankReference as _HouseBankRef on $projection.capaymentcompanycode = _HouseBankRef.CAPaymentCompanyCode
and $projection.CAHouseBankReference = _HouseBankRef.CAHouseBankReference
association [0..1] to I_CAInterestCode as _InterestCode on $projection.CAInterestCode = _InterestCode.CAInterestCode
association [0..1] to I_CAInvcgCategory as _InvcgCategory on $projection.CAInvcgCategory = _InvcgCategory.CAInvcgCategory
association [1..1] to I_CAInvcgSchedule as _InvcgSchedule on $projection.CAInvcgSchedule = _InvcgSchedule.CAInvcgSchedule
association [1..1] to I_CAMasterAgreement as _MasterAgreement on $projection.CAMasterAgreement = _MasterAgreement.CAMasterAgreement
association [0..1] to I_CAPaymentMethod as _PaytMethodIncg on $projection.country = _PaytMethodIncg.Country
and $projection.CAPaymentMethodForIncgPayment = _PaytMethodIncg.CAPaymentMethod
association [0..1] to I_CAPaymentMethod as _PaytMethodOutg on $projection.country = _PaytMethodOutg.Country
and $projection.CAPaymentMethodForOutgPayment = _PaytMethodOutg.CAPaymentMethod
association [0..1] to I_CAToleranceGroup as _ToleranceGroup on $projection.CAToleranceGroup = _ToleranceGroup.CAToleranceGroup
association [1..1] to I_CompanyCode as _CompCode on $projection.CAStandardCompanyCode = _CompCode.CompanyCode
association [1..1] to I_CompanyCode as _PaymentCompCode on $projection.capaymentcompanycode = _PaymentCompCode.CompanyCode
association [0..1] to I_ContrAcctPrtnRelshpType as _RelshpOfBP on $projection.CARelationshipOfBPToContrAcct = _RelshpOfBP.CARelationshipOfBPToContrAcct
association [1..1] to I_ContractAccountHeader as _ContrAcc on $projection.ContractAccount = _ContrAcc.ContractAccount
association [0..1] to I_ContractAccountHeader as _AltvContrAcc on $projection.AltvContractAcctForCollvBills = _AltvContrAcc.ContractAccount
association [0..1] to I_ContractAccountHeader as _ContrAcctForPayt on $projection.ContractAccountForPayment = _ContrAcctForPayt.ContractAccount
association [0..1] to I_ContractAccountHeader as _ContrAcctForPosting on $projection.ContractAccountForPosting = _ContrAcctForPosting.ContractAccount
association [0..1] to I_ContractAccountHeader as _ContrAcctForInvcgList on $projection.ContractAccountForInvcgList = _ContrAcctForInvcgList.ContractAccount
association [0..1] to I_Country as _Country on $projection.country = _Country.Country
association [0..1] to I_Country as _SupplyingCountry on $projection.SupplyingCountry = _SupplyingCountry.Country
association [0..1] to I_Currency as _CurrencyForDDL on $projection.CACurrencyForDirectDebitLimit = _CurrencyForDDL.Currency
association [0..1] to I_Currency as _CurrencyForInvoicing on $projection.CATargetCurrencyForInvoicing = _CurrencyForInvoicing.Currency
association [0..1] to I_PaymentCondition as _PaymentCondition on $projection.PaymentCondition = _PaymentCondition.PaymentCondition
association [1..1] to E_ContractAccountPartner as _Extension on $projection.ContractAccount = _Extension.ContractAccount
and $projection.BusinessPartner = _Extension.BusinessPartner
{
@ObjectModel.foreignKey.association: '_ContrAcc'
key vkont as ContractAccount,
key gpart as BusinessPartner,
vkbez as ContractAccountName,
/* administration data */
@Semantics.systemDate.createdAt: true
erdat as CreationDate,
@Semantics.systemTime.createdAt: true
ertim as CreationTime,
@Semantics.user.createdBy: true
ernam as CreatedByUser,
cast( loevm as loevm preserving type ) as IsMarkedForDeletion,
@Semantics.systemDate.lastChangedAt: true
aedatp as LastChangeDate,
@Semantics.systemTime.lastChangedAt: true
aetimp as LastChangeTime,
@Semantics.user.lastChangedBy: true
aenamp as LastChangedByUser,
/* payment data */
ebvty as CABankIDForIncomingPayments,
abvty as CABankIDForOutgoingPayments,
@ObjectModel.foreignKey.association: '_PaytMethodIncg'
ezawe as CAPaymentMethodForIncgPayment,
@ObjectModel.foreignKey.association: '_PaytMethodOutg'
azawe as CAPaymentMethodForOutgPayment,
@ObjectModel.foreignKey.association: '_HouseBankRef'
eigbv as CAHouseBankReference,
ccard_id as CAPaymentCardIDForIncomingPayt,
ccard_out as CAPaymentCardIDForOutgoingPayt,
mndid as SEPAMandate,
/* dunning and collections */
@ObjectModel.foreignKey.association: '_DunningProcedure'
mahnv as CADunningProcedure,
@ObjectModel.foreignKey.association: '_DunNoticeGroup'
mgrup as CADunningNoticeGroup,
corr_mahnv as CACorrespondenceDunningProced,
persr as CACollectionsClerk,
@ObjectModel.foreignKey.association: '_CollMasterDataGroup'
cmgrp as CACollectionsMasterDataGroup,
@ObjectModel.foreignKey.association: '_CollectionStrategy'
strat as CACollectionStrategy,
@ObjectModel.foreignKey.association: '_CollContactPerson'
cpers as CACollectionsContactPerson,
/* alternative business partners */
@ObjectModel.foreignKey.association: '_ContrAcctForPayt'
vkonv as ContractAccountForPayment,
@ObjectModel.foreignKey.association: '_BPForPayment'
gparv as CABusinessPartnerForPayment,
@ObjectModel.foreignKey.association: '_AlternativePayer'
abwre as CAAlternativePayer,
@ObjectModel.foreignKey.association: '_AlternativePayee'
abwra as CAAlternativePayee,
@ObjectModel.foreignKey.association: '_AltvDunningRecipient'
abwma as CAAlternativeDunningRecipient,
@ObjectModel.foreignKey.association: '_AltvInvoiceRecipient'
abwrh as CAAlternativeInvoiceRecipient,
@ObjectModel.foreignKey.association: '_AltvCorrespncRcpnt'
def_rec as CAAlternativeCorrespncRcpnt,
//@ObjectModel.foreignKey.association: '_AddressOfAltvPayer'
adrre as CAAddressIDOfAlternativePayer,
//@ObjectModel.foreignKey.association: '_AddressOfAltvPayee'
adrra as CAAddressIDOfAlternativePayee,
//@ObjectModel.foreignKey.association: '_AddressOfDunRcpnt'
adrma as CAAddressIDOfAltvDunRecipient,
//@ObjectModel.foreignKey.association: '_AddressOFInvcRcpnt'
adrrh as CAAddressIDOfAltvInvoiceRcpnt,
/* direct debit limit */
@ObjectModel.foreignKey.association: '_CurrencyForDDL'
ddlcu as CACurrencyForDirectDebitLimit,
@Semantics.amount.currencyCode: 'CACurrencyForDirectDebitLimit'
ddlam as CADirectDebitLimit,
ddlnm as CANmbrMnthsForDirectDebitLimit,
@ObjectModel.foreignKey.association: '_CADirectDebitLimitCalcMod'
ddlxg as CADirectDebitLimitCalcMode,
/* billing and invoicing */
inv_cycle_start as CAStartDateForBillingPeriod,
@ObjectModel.foreignKey.association: '_CurrencyForInvoicing'
inv_curr as CATargetCurrencyForInvoicing,
@ObjectModel.foreignKey.association: '_InvcgCategory'
inv_category as CAInvcgCategory,
@ObjectModel.foreignKey.association: '_InvcgSchedule'
inv_schedule as CAInvcgSchedule,
@ObjectModel.foreignKey.association: '_BillgCycle'
inv_cycle as CABillgCycle,
inv_cycle_day as CALastDayOfBillingPeriod,
inv_form_det_key as CADetnCodeForAltvInvoiceForm,
@ObjectModel.foreignKey.association: '_BPForPosting'
gpart_inv as CABusinessPartnerForPosting,
@ObjectModel.foreignKey.association: '_ContrAcctForPosting'
vkont_inv as ContractAccountForPosting,
@ObjectModel.foreignKey.association: '_BPForInvcgList'
gpart_invlist as CABusinessPartnerForInvcgList,
@ObjectModel.foreignKey.association: '_ContrAcctForInvcgList'
vkont_invlist as ContractAccountForInvcgList,
//@ObjectModel.foreignKey.association: '_MasterAgreement'
makey as CAMasterAgreement,
//@ObjectModel.foreignKey.association: '_PartSettlmtRule'
ptsrl as CAPartnerSettlementRule,
/* tax data */
qszdt as ValdtyDateForWhldgTaxExmpCert,
//@ObjectModel.foreignKey.association: '_TaxJurisdiction'
cast( txjcd as fis_txjcd preserving type ) as TaxJurisdiction,
qsskz_a as CAWhldgTaxCodeOutgoingPayt,
qsskz_e as CAWhldgTaxCodeIncomingPayt,
cast( qsznr as fis_wtcert preserving type ) as WithholdingTaxCertificate,
/* other data */
fdztg as CAAdditionalDaysForCashMgmt,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'CABusPartnerPostgLockExstcCode'
bpl_xpocl as CABusinessPartnerLock,
@ObjectModel.foreignKey.association: '_CABusPrtnPostgLockExstcCode'
bpl_xpocl as CABusPartnerPostgLockExstcCode,
@ObjectModel.foreignKey.association: '_CABusPrtnAddlLockExstcCode'
bpl_xaddl as CABusPartnerAddlLockExstcCode,
bpl_fdate as CABusinessPartnerLockStartDate,
bpl_tdate as CABusinessPartnerLockEndDate,
exvko as CABPReferenceNumber,
@ObjectModel.foreignKey.association: '_CompCodeGroup'
opbuk as CACompanyCodeGroup,
@ObjectModel.foreignKey.association: '_CompCode'
stdbk as CAStandardCompanyCode,
@ObjectModel.foreignKey.association: '_AltvContrAcc'
abwvk as AltvContractAcctForCollvBills,
@ObjectModel.foreignKey.association: '_InterestCode'
ikey as CAInterestCode,
fdgrp as CashPlanningGroup,
@ObjectModel.foreignKey.association: '_RelshpOfBP'
vkpbz as CARelationshipOfBPToContrAcct,
//@ObjectModel.foreignKey.association: '_Address'
adrnb as AddressID,
//@ObjectModel.foreignKey.association: '_AddressOfJurisdiction'
adrjdc as CAAddressIDOfJurisdictionCode,
@ObjectModel.foreignKey.association: '_CAAuthorizationGroup'
begru as CAAuthorizationGroup,
@ObjectModel.foreignKey.association: '_ToleranceGroup'
togru as CAToleranceGroup,
coprc as CACorrespondenceVariant,
cast( vbund as fis_rassc preserving type ) as PartnerCompany,
@ObjectModel.foreignKey.association: '_CACorrespncActivityCode'
def_rec_ind as CACorrespondenceActivityCode,
@ObjectModel.foreignKey.association: '_ClearingCategory'
vertyp as CAClearingCategory,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'CADefaultClearingRstrcnCode'
augrs_def as CAClearingRestriction,
@ObjectModel.foreignKey.association: '_CADfltClearingRstrcnCode'
augrs_def as CADefaultClearingRstrcnCode,
@ObjectModel.foreignKey.association: '_SupplyingCountry'
cast( landl as fac_landl preserving type ) as SupplyingCountry,
cast( bupla as farp_bupla preserving type ) as BusinessPlace,
/* include SI_FKKVKPSICA */
@ObjectModel.foreignKey.association: '_PaymentCondition'
zahlkond as PaymentCondition,
@ObjectModel.foreignKey.association: '_AcctDetnCode'
cast( kofiz_sd as kofiz_kk preserving type ) as CAAccountDeterminationCode,
@ObjectModel.foreignKey.association: '_BusinessArea'
cast( gsber as fis_rbusa preserving type ) as BusinessArea,
// needed for house bank data
@ObjectModel.foreignKey.association: '_PaymentCompCode'
_CompCodeGroup.CAPaymentCompanyCode,
// needed for payment method data
@ObjectModel.foreignKey.association: '_Country'
_CompCodeGroup._CompanyCode.Country,
// propagation of associations
_AcctDetnCode,
_AlternativePayer,
_AlternativePayee,
_AltvDunningRecipient,
_AltvInvoiceRecipient,
_AltvCorrespncRcpnt,
_AltvContrAcc,
_BillgCycle,
_BPForInvcgList,
_BPForPayment,
_BPForPosting,
_BusinessArea,
_BusinessPartner,
_CAAuthorizationGroup,
_CABusPrtnAddlLockExstcCode,
_CABusPrtnPostgLockExstcCode,
_CACorrespncActivityCode,
_CADfltClearingRstrcnCode,
_CADirectDebitLimitCalcMod,
_ClearingCategory,
_CollContactPerson,
_CollectionStrategy,
_CollMasterDataGroup,
_CompCode,
_CompCodeGroup,
_ContrAcc,
_ContrAcctForPayt,
_ContrAcctForInvcgList,
_ContrAcctForPosting,
@API.element.releaseState: #DEPRECATED
@API.element.successor: '_CorrespncVar'
_CorrVariant,
_CorrespncVar,
_Country,
_CurrencyForDDL,
_CurrencyForInvoicing,
_DunningProcedure,
_DunNoticeGroup,
_HouseBankRef,
_InvcgCategory,
_InvcgSchedule,
_InterestCode,
_MasterAgreement,
_PaymentCompCode,
_PaymentCondition,
_PaytMethodIncg,
_PaytMethodOutg,
_RelshpOfBP,
_SupplyingCountry,
_ToleranceGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CACOMPANYCODEGROUP",
"I_COMPANYCODE",
"FKKVKP"
],
"ASSOCIATED":
[
"E_CONTRACTACCOUNTPARTNER",
"I_BUSINESSAREA",
"I_BUSINESSPARTNER",
"I_CAACCOUNTDETNCODE",
"I_CAAUTHORIZATIONGROUP",
"I_CABILLGCYCLE",
"I_CABUSPRTNADDLLOCKEXSTCCODE",
"I_CABUSPRTNPOSTGLOCKEXSTCCODE",
"I_CACLEARINGCATEGORY",
"I_CACOLLECTIONSTRATEGY",
"I_CACOLLMASTERDATAGROUP",
"I_CACOMPANYCODEGROUP",
"I_CACORRESPNCACTIVITYCODE",
"I_CACORRESPONDENCEVARIANT",
"I_CADFLTCLEARINGRSTRCNCODE",
"I_CADIRECTDEBITLIMITCALCMODE",
"I_CADUNNINGNOTICEGROUP",
"I_CADUNNINGPROCEDURE",
"I_CAHOUSEBANKREFERENCE",
"I_CAINTERESTCODE",
"I_CAINVCGCATEGORY",
"I_CAINVCGSCHEDULE",
"I_CAMASTERAGREEMENT",
"I_CAPAYMENTMETHOD",
"I_CATOLERANCEGROUP",
"I_COMPANYCODE",
"I_CONTRACCTPRTNRELSHPTYPE",
"I_CONTRACTACCOUNTHEADER",
"I_COUNTRY",
"I_CURRENCY",
"I_PAYMENTCONDITION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/