I_CONACCTPRTNINVCGCHRGANDDISC

CDS View

Contr Acct Partner Invcg Charge and Disc

I_CONACCTPRTNINVCGCHRGANDDISC is a CDS View in S/4HANA. Contr Acct Partner Invcg Charge and Disc. It contains 5 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 5 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_CAInvcgChargeAndDiscount view from CONSUMPTION Zu- und Abschläge
P_CAChrgAndDiscByContrAcct view_entity from COMPOSITE
R_ConAcctPrtnInvcgChrgDscTP view_entity from TRANSACTIONAL Contr Acct Prtn Invcg Chrg and Disc - TP

Fields (5)

KeyField CDS FieldsUsed in Views
KEY BusinessPartner BusinessPartner 1
KEY CAInvcgChargeAndDiscountKey CAInvcgChargeAndDiscountKey 1
KEY CAInvcgChrgAndDiscKeyStartDate CAInvcgChrgAndDiscKeyStartDate 1
KEY ContractAccount ContractAccount 1
CAInvcgChrgAndDiscKeyEndDate CAInvcgChrgAndDiscKeyEndDate 1 
@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData: { blocking: #REQUIRED,
                                  blockingIndicator: ['_BusinessPartner.IsBusinessPurposeCompleted'] } }

@Analytics.technicalName: 'ICONACCTPARTICD'

@EndUserText.label: 'Contr Acct Partner Invcg Charge and Disc'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { modelingPattern: #NONE,
                representativeKey: 'CAInvcgChargeAndDiscountKey',
                sapObjectNodeType.name: 'ContrAcctPrtnInvcgChrgAndDisc',
                supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #CDS_MODELING_DATA_SOURCE,
                                         #SQL_DATA_SOURCE ],
                usageType: { dataClass: #MASTER,
                             serviceQuality: #A,
                             sizeCategory: #XL } }

@VDM.viewType: #BASIC

define view entity I_ConAcctPrtnInvcgChrgAndDisc
  as select from fkkvkp_chgdisc

  association [1..1] to I_BusinessPartner        as _BusinessPartner        on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to I_CAApplicationArea      as _CAApplicationArea      on  $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
  association [1..1] to I_CAInvcgChrgAndDiscKey  as _CAInvcgChrgAndDiscKey  on  $projection.CAInvcgChargeAndDiscountKey = _CAInvcgChrgAndDiscKey.CAInvcgChargeAndDiscountKey
                                                                            and $projection.CAApplicationArea           = _CAInvcgChrgAndDiscKey.CAApplicationArea
  association [1..1] to I_ContractAccountHeader  as _ContractAccount        on  $projection.ContractAccount = _ContractAccount.ContractAccount
  association [1..1] to I_ContractAccountPartner as _ContractAccountPartner on  $projection.BusinessPartner = _ContractAccountPartner.BusinessPartner
                                                                            and $projection.ContractAccount = _ContractAccountPartner.ContractAccount

{
      @ObjectModel.foreignKey.association: '_ContractAccount'
  key vkont                              as ContractAccount,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
  key gpart                              as BusinessPartner,
      @ObjectModel.foreignKey.association: '_CAInvcgChrgAndDiscKey'
  key chgkey                             as CAInvcgChargeAndDiscountKey,
      @Semantics.businessDate.from: true
  key date_from                          as CAInvcgChrgAndDiscKeyStartDate,

      @Semantics.businessDate.to: true
      date_to                            as CAInvcgChrgAndDiscKeyEndDate,

      //for association of CAInvcgChargeAndDiscountKey (association is needed for representativeKey)

      @ObjectModel.foreignKey.association: '_CAApplicationArea'
      _ContractAccount.CAApplicationArea as CAApplicationArea,

      _BusinessPartner,
      _CAApplicationArea,
      _CAInvcgChrgAndDiscKey,
      _ContractAccount,
      _ContractAccountPartner
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CONTRACTACCOUNTHEADER",
"FKKVKP_CHGDISC"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAPPLICATIONAREA",
"I_CAINVCGCHRGANDDISCKEY",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More