I_COMMITMENTITEMTEXT

CDS View

Commitment Item - Text

I_COMMITMENTITEMTEXT is a CDS View in S/4HANA. Commitment Item - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_CommitmentItemText view_entity from CONSUMPTION Commitment Item Text 
@EndUserText.label: 'Commitment Item - Text'

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'CommitmentItem'
@ObjectModel.usageType: { 
  sizeCategory: #M,
  serviceQuality: #A,
  dataClass: #MASTER
}
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT]
@ObjectModel.dataCategory: #TEXT
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'ICOMMITEMT'
define view I_CommitmentItemText
  as select from fmcit
  association [0..1] to I_Language                 as _Language          on  $projection.Language = _Language.Language
  association [1..1] to I_FinancialManagementArea  as _FinMgmtArea       on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea
  association [1..1] to I_FiscalYearForFinMgmtArea as _FinMgmtFiscalYear on  $projection.FinancialManagementArea = _FinMgmtFiscalYear.FinancialManagementArea
                                                                         and $projection.FinMgmtAreaFiscalYear   = _FinMgmtFiscalYear.FinMgmtAreaFiscalYear
  association [0..1] to I_CommitmentItem           as _CommitmentItem    on  $projection.FinancialManagementArea = _CommitmentItem.FinancialManagementArea   //for authorization check

                                                                         and $projection.FinMgmtAreaFiscalYear   = _CommitmentItem.FinMgmtAreaFiscalYear
                                                                         and $projection.CommitmentItem          = _CommitmentItem.CommitmentItem

{

      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key spras                                                                                                            as Language,
      //--[ GENERATED:011:GFBfhyK17jY4g{lgBXRgP0

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_FinMgmtAreaStdVH',
                     element: 'FinancialManagementArea' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_FinMgmtArea'
  key fikrs                                                                                                            as FinancialManagementArea,
      //--[ GENERATED:011:GFBfhyK17jY4g{lgBXRgP0

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_FsclYrForFinMgmtAreaStdVH',
                     element: 'FinMgmtAreaFiscalYear' },
          additionalBinding: [{ localElement: 'FinancialManagementArea',
                                element: 'FinancialManagementArea' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_FinMgmtFiscalYear'
  key cast( gjahr as fmis_fma_fiscal_year preserving type )                                                            as FinMgmtAreaFiscalYear,
      //--[ GENERATED:011:GFBfhyK17jY4g{lgBXRgP0

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CommitmentItemStdVH',
                     element: 'CommitmentItem' },
          additionalBinding: [{ localElement: 'FinancialManagementArea',
                                element: 'FinancialManagementArea' },
                              { localElement: 'FinMgmtAreaFiscalYear',
                                element: 'FinMgmtAreaFiscalYear' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_CommitmentItem'
  key fipex                                                                                                            as CommitmentItem,
      @Semantics.text: true
      cast( bezei as fmis_commitment_item_name preserving type )                                                       as CommitmentItemName,
      cast( text1 as fmis_ci_description preserving type )                                                             as CommitmentItemDescription,
      cast( text2 as fmis_ci_description2 preserving type )                                                            as CommitmentItemDescription2,
      cast( text3 as fmis_ci_description3 preserving type )                                                            as CommitmentItemDescription3,

      _Language,
      _FinMgmtArea,
      _FinMgmtFiscalYear,
      _CommitmentItem

};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FMCIT"
],
"ASSOCIATED":
[
"I_COMMITMENTITEM",
"I_FINANCIALMANAGEMENTAREA",
"I_FISCALYEARFORFINMGMTAREA",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More