I_CNTRBTSCENENVRMTOPLCNDN

@AbapCatalog.sqlViewName: 'ICRRENOPCN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

--Access Control: Authorizations Checks
@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

@EndUserText.label: 'Operational Conditions'

@VDM.viewType: #BASIC

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel:
{

    usageType:
    {
      dataClass: #TRANSACTIONAL,
      sizeCategory: #L,
      serviceQuality: #B
    },
    representativeKey: 'PCESOperationalConditionUUID'
}

define view I_CntrbtScenEnvrmtOplCndn
  as select from ehsdsv_cs_envoc

  association [1..1] to I_CmplRqRslt as _CmplRqRslt        on $projection.CmplRqRsltUUID = _CmplRqRslt.CmplRqRsltUUID

  --Link to user data
  association [0..1] to I_User       as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User       as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID

{

  key  pcesoperationalconditionuuid                                         as PCESOperationalConditionUUID,

       --Compliance Assessment UUID
       cmplrqrsltuuid                                                       as CmplRqRsltUUID,

       --Condition Type
       pcesstptypephrsuuid                                                  as PCESSTPTypePhrsUUID,

       --Effectiveness Lower Value
       pceseffctvnlowrvalue                                                 as PCESEffctvnLowrValue,

       --Effectiveness Lower Value Text
       pceseffctvnlowrvaluetxt                                              as PCESEffctvnLowrValueTxt,

       --Effectiveness Lower Value Operator
       pceseffctvnlowrvalueoptr                                             as PCESEffctvnLowrValueOptr,

       --Effectiveness Upper Value
       pceseffctvnuprvalue                                                  as PCESEffctvnUprValue,

       --Effectiveness Upper Value Text
       pceseffctvnuprvaluetxt                                               as PCESEffctvnUprValueTxt,

       --Effectiveness Upper Value Operator
       pceseffctvnuprvalueoptr                                              as PCESEffctvnUprValueOptr,

       --Effectiveness Unit
       pceseffctvnuom                                                       as PCESEffctvnUoM,

       --Condition Type Additional Information
       pcesstptypeaddlinfophrs1uuid                                         as PCESSTPTypeAddlInfoPhrs1UUID,

       --Condition Type Additional Information
       pcesstptypeaddlinfophrs2uuid                                         as PCESSTPTypeAddlInfoPhrs2UUID,

       --Condition Type Additional Information
       pcesstptypeaddlinfophrs3uuid                                         as PCESSTPTypeAddlInfoPhrs3UUID,

       --Condition Sludge Treatment
       pcessludgetreatmentphrs1uuid                                         as PCESSludgeTreatmentPhrs1UUID,

       --Condition Sludge Treatment
       pcessludgetreatmentphrs2uuid                                         as PCESSludgeTreatmentPhrs2UUID,

       --Condition Sludge Treatment
       pcessludgetreatmentphrs3uuid                                         as PCESSludgeTreatmentPhrs3UUID,

       --Condition STP effluent Value
       pcesstpeffluentvalue                                                 as PCESSTPEffluentValue,

       --Condition STP effluent Value
       pcesstpeffluentvaluetxt                                              as PCESSTPEffluentValueTxt,


       --STP Effluent Unit
       pcesstpeffluentuom                                                   as PCESSTPEffluentUoM,

       --Create at date/time
       @Semantics.systemDateTime.createdAt: true
       cast(creationdatetime  as ehfnd_bo_crea_date_time preserving type )  as CreationDateTime,

       --Create by user
       @ObjectModel.readOnly: true
       @Semantics.user.createdBy: true
       cast(createdbyuser as ehfnd_bo_crea_uname preserving type )          as CreatedByUser,

       --Update at date/time
       @Semantics.systemDateTime.lastChangedAt: true
       cast(lastchangedatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeDateTime,

       --Update by user
       @ObjectModel.readOnly: true
       @Semantics.user.lastChangedBy: true
       cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )      as LastChangedByUser,


       /**** Associations ****/
       _CmplRqRslt,
       _CreatedByUser,
       _LastChangedByUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHSDSV_CS_ENVOC"
],
"ASSOCIATED":
[
"I_CMPLRQRSLT",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/