I_CMTMTCARRYFORWARDDOCUMENT
Commitment Carry Forward - Cube
I_CMTMTCARRYFORWARDDOCUMENT is a CDS View in S/4HANA. Commitment Carry Forward - Cube. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_CmtmtCarryForwardDocument | view | from | COMPOSITE | Funds Management Carry Forward Document |
@AbapCatalog.sqlViewName: 'ICMMTCCFDOC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Commitment Carry Forward - Cube'
@VDM.viewType:#COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
usageType: {
dataClass: #MIXED,
serviceQuality: #D,
sizeCategory: #XXL
},
supportedCapabilities: [#ANALYTICAL_PROVIDER],
modelingPattern: #ANALYTICAL_CUBE
}
@AccessControl.personalData.blocking:#REQUIRED
@Metadata.allowExtensions:true
@Analytics.dataCategory: #CUBE
@Analytics.internalName:#LOCAL
define view I_CmtmtCarryForwardDocument
as select from I_FundsMgmtCarryFwdDocument as ccf
association [1..1] to I_FiscalYearForFinMgmtArea as _FiscalYearForFinMgmtArea on $projection.FinancialManagementArea = _FiscalYearForFinMgmtArea.FinancialManagementArea
and $projection.SenderFinMgmtAreaFiscalYear = _FiscalYearForFinMgmtArea.FinMgmtAreaFiscalYear
association [1..1] to I_FinancialManagementArea as _FinMgmtArea on $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea
association [1..1] to I_FiscalYearForFinMgmtArea as _FinMgmtFiscalYear on $projection.FinancialManagementArea = _FinMgmtFiscalYear.FinancialManagementArea
and $projection.CommitmentItemFiscalYear = _FinMgmtFiscalYear.FinMgmtAreaFiscalYear
association [0..1] to I_Fund as _SenderFund on $projection.FinancialManagementArea = _SenderFund.FinancialManagementArea
and $projection.SenderPostedFund = _SenderFund.Fund
association [0..1] to I_CommitmentItem as _SenderCommitmentItem on $projection.FinancialManagementArea = _SenderCommitmentItem.FinancialManagementArea
and $projection.CommitmentItemFiscalYear = _SenderCommitmentItem.FinMgmtAreaFiscalYear
and $projection.SenderPostedCommitmentItem = _SenderCommitmentItem.CommitmentItem
association [0..1] to I_BudgetPeriod as _SenderBudgetPeriod on $projection.SenderPostedBudgetPeriod = _SenderBudgetPeriod.BudgetPeriod
association [0..1] to I_FundsMgmtFunctionalArea as _SenderFunctionalArea on $projection.SenderPostedFunctionalArea = _SenderFunctionalArea.FunctionalArea
association [0..1] to I_FundedProgram as _SenderFundedProgram on $projection.FinancialManagementArea = _SenderFundedProgram.FinancialManagementArea
and $projection.SenderPostedFundedProgram = _SenderFundedProgram.FundedProgram
association [0..*] to I_FundsCenter as _SenderFundsCenter on $projection.FinancialManagementArea = _SenderFundsCenter.FinancialManagementArea
and $projection.SenderPostedFundsCenter = _SenderFundsCenter.FundsCenter
association [0..1] to I_Grant as _SenderGrant on $projection.SenderPostedGrantId = _SenderGrant.GrantID
association [0..1] to I_ReferenceDocumentType as _ReferenceDocumentType on $projection.ReferenceDocumentType = _ReferenceDocumentType.ReferenceDocumentType
association [0..1] to I_Fund as _ReceiverFund on $projection.FinancialManagementArea = _ReceiverFund.FinancialManagementArea
and $projection.ReceiverPostedFund = _ReceiverFund.Fund
association [0..1] to I_CommitmentItem as _ReceiverCommitmentItem on $projection.FinancialManagementArea = _ReceiverCommitmentItem.FinancialManagementArea
and $projection.ReceiverPostedCommitmentItem = _ReceiverCommitmentItem.CommitmentItem
and $projection.CommitmentItemFiscalYear = _ReceiverCommitmentItem.FinMgmtAreaFiscalYear
association [0..1] to I_BudgetPeriod as _ReceiverBudgetPeriod on $projection.ReceiverPostedBudgetPeriod = _ReceiverBudgetPeriod.BudgetPeriod
association [0..1] to I_FundsMgmtFunctionalArea as _ReceiverFunctionalArea on $projection.ReceiverPostedFunctionalArea = _ReceiverFunctionalArea.FunctionalArea
association [0..1] to I_FundedProgram as _ReceiverFundedProgram on $projection.FinancialManagementArea = _ReceiverFundedProgram.FinancialManagementArea
and $projection.ReceiverPostedFundedProgram = _ReceiverFundedProgram.FundedProgram
association [0..*] to I_FundsCenter as _ReceiverFundsCenter on $projection.FinancialManagementArea = _ReceiverFundsCenter.FinancialManagementArea
and $projection.ReceiverPostedFundsCenter = _ReceiverFundsCenter.FundsCenter
association [0..1] to I_Grant as _ReceiverGrant on $projection.ReceiverPostedGrantId = _ReceiverGrant.GrantID
association [0..1] to I_Currency as _Currency on $projection.FinancialManagementAreaCrcy = _Currency.Currency
association [0..1] to I_Currency as _TransactionCurrency on $projection.TransactionCurrency = _TransactionCurrency.Currency
association [0..*] to I_FundsMgmtCommitmentEntryItem as _CommitmentDocument on $projection.ReferenceDocument = _CommitmentDocument.ReferenceDocument
and $projection.ReferenceDocumentContext = _CommitmentDocument.ReferenceDocumentContext
and $projection.FundsMgmtReferenceDocumentItem = _CommitmentDocument.FundsMgmtReferenceDocumentItem
and $projection.RefDocAccountAssignment = _CommitmentDocument.RefDocAccountAssignment
and $projection.FundsMgmtRefDocScheduleLine = _CommitmentDocument.FundsMgmtRefDocScheduleLine
and $projection.RefDocPricingElementContent = _CommitmentDocument.RefDocPricingElementContent
and $projection.ReferenceDocumentType = _CommitmentDocument.ReferenceDocumentType
and $projection.FundsMgmtTransactionNumber = _CommitmentDocument.FundsMgmtTransactionNumber
and $projection.FundsManagementDocument is initial
association [0..*] to I_FundsManagementDocumentItem as _ActualsDocument on $projection.ReferenceDocument = _ActualsDocument.FundsMgmtFinDocNumber
and $projection.OriginAccountingDocFiscalYear = _ActualsDocument.FundsMgmtFinDocFiscalYear
and $projection.CompanyCode = _ActualsDocument.CompanyCode
and $projection.FundsMgmtTransactionNumber = _ActualsDocument.FundsMgmtTransactionNumber
and $projection.FundsManagementDocument is not initial
association [0..1] to I_BudgetEntryDocument as _BudgetEntryDocument on $projection.CommitmentCarryForwardDocument = _BudgetEntryDocument.ReferenceDocument
and $projection.FinancialManagementArea = _BudgetEntryDocument.FinancialManagementArea
and $projection.ReceiverFinMgmtAreaFiscalYear = _BudgetEntryDocument.BudgetDocumentYear
and _BudgetEntryDocument.ReferenceDocumentType = 'FMCCF'
and $projection.FsclYrChgDocHasFollowOnDoc = 'X'
association [1..1] to E_CmtmtCarryFwdDoc as _Extension //do not expose this association in the projection list of the view
on $projection.CommitmentCarryForwardDocument = _Extension.CommitmentCarryForwardDocument
and $projection.FinancialManagementArea = _Extension.FinancialManagementArea
and $projection.ReceiverFinMgmtAreaFiscalYear = _Extension.ReceiverFinMgmtAreaFiscalYear
{
// key FiscalYearChangeDocument,
key ccf.CommitmentCarryForwardDocument,
key ccf.FinancialManagementArea,
key ccf.ReceiverFinMgmtAreaFiscalYear,
ccf.FundsMgmtRefDocumentCategory,
ccf.FundsMgmtCarryBackStatus,
ccf.FundsMgCarryBackRefDocument,
ccf.ReferenceDocument,
ccf.ReferenceDocumentContext,
ccf.FundsMgmtReferenceDocumentItem,
ccf.ReferenceDocumentLogicalSystem,
ccf.RefDocAccountAssignment,
ccf.FundsMgmtRefDocScheduleLine,
ccf.RefDocPricingElementContent,
@ObjectModel.foreignKey.association: '_ReferenceDocumentType'
ccf.ReferenceDocumentType,
ccf.CompanyCode,
ccf.OriginAccountingDocFiscalYear,
ccf.FundsManagementDocument,
ccf.FundsMgmtValueType,
ccf.FundsManagementDocumentItem,
//-----------------------Amounts------------------------------------------------------
// Amount is amount of 350 entry. Each FMCCFD line has one 300/350 pair defined by one TRANR.
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FinancialManagementAreaCrcy'} }
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0350'].PostedAmountInFMACrcy
else
_CommitmentDocument[FundsMgmtAmountType = '0350'].PostedAmountInFMACrcy
end as CmtmtCarryFwdAmtInFMACrcy,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0350'].PostedAmountInTransCrcy
else
_CommitmentDocument[FundsMgmtAmountType = '0350'].PostedAmountInTransCrcy
end as CmtmtCarryFwdAmtInTransCrcy,
@ObjectModel.foreignKey.association: '_Currency'
@Semantics.currencyCode:true
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0350'].FinancialManagementAreaCrcy
else
_CommitmentDocument[FundsMgmtAmountType = '0350'].FinancialManagementAreaCrcy
end as FinancialManagementAreaCrcy,
@Semantics.currencyCode:true
@ObjectModel.foreignKey.association: '_TransactionCurrency'
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0350'].TransactionCurrency
else
_CommitmentDocument[FundsMgmtAmountType = '0350'].TransactionCurrency
end as TransactionCurrency,
//-----------------------Sender Fields------------------------------------------------
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0300'].CashEffectivityFiscalYear
else
_CommitmentDocument[FundsMgmtAmountType = '0300'].CashEffectivityFiscalYear
end as SndrPostdCshEffctyFiscalYear,
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0300'].FundsManagementStatisticalType
else
_CommitmentDocument[FundsMgmtAmountType = '0300'].FundsManagementStatisticalType
end as FndsMgmtSenderStatisticalType,
ccf.SenderLedger,
@ObjectModel.foreignKey.association: '_SenderFund'
ccf.SenderPostedFund,
@ObjectModel.foreignKey.association: '_SenderBudgetPeriod'
ccf.SenderPostedBudgetPeriod,
@ObjectModel.foreignKey.association: '_SenderFundsCenter'
ccf.SenderPostedFundsCenter,
@ObjectModel.foreignKey.association: '_SenderCommitmentItem'
ccf.SenderPostedCommitmentItem,
@ObjectModel.foreignKey.association: '_SenderFunctionalArea'
ccf.SenderPostedFunctionalArea,
@ObjectModel.foreignKey.association: '_SenderFundedProgram'
ccf.SenderPostedFundedProgram,
@ObjectModel.foreignKey.association: '_SenderGrant'
ccf.SenderPostedGrantId,
ccf.SenderPostedFundsMgmtCustField,
ccf.SenderFinMgmtAreaFiscalYear,
@ObjectModel.foreignKey.association: '_FinMgmtFiscalYear'
_FiscalYearForFinMgmtArea.CommitmentItemFiscalYear as CommitmentItemFiscalYear,
//----------------------Receiver Fields----------------------------------------------
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0350'].CashEffectivityFiscalYear
else
_CommitmentDocument[FundsMgmtAmountType = '0350'].CashEffectivityFiscalYear
end as RcvrPostdCshEffctyFiscalYear,
case
when ccf.FundsMgmtRefDocumentCategory = '900' or ccf.FundsMgmtRefDocumentCategory = '910'
then _ActualsDocument[FundsMgmtAmountType = '0350'].FundsManagementStatisticalType
else
_CommitmentDocument[FundsMgmtAmountType = '0350'].FundsManagementStatisticalType
end as FndsMgmtRcvrStatisticalType,
ccf.ReceiverLedger,
@ObjectModel.foreignKey.association: '_ReceiverFund'
ccf.ReceiverPostedFund,
@ObjectModel.foreignKey.association: '_ReceiverBudgetPeriod'
ccf.ReceiverPostedBudgetPeriod,
@ObjectModel.foreignKey.association: '_ReceiverFundsCenter'
ccf.ReceiverPostedFundsCenter,
@ObjectModel.foreignKey.association: '_ReceiverCommitmentItem'
ccf.ReceiverPostedCommitmentItem,
@ObjectModel.foreignKey.association: '_ReceiverFunctionalArea'
ccf.ReceiverPostedFunctionalArea,
@ObjectModel.foreignKey.association: '_ReceiverFundedProgram'
ccf.ReceiverPostedFundedProgram,
@ObjectModel.foreignKey.association: '_ReceiverGrant'
ccf.ReceiverPostedGrantId,
ccf.ReceiverPostedFundsMgmtCustFld,
// @ObjectModel.foreignKey.association: '_BudgetEntryDocument'
_BudgetEntryDocument.BudgetEntryDocument as BudgetEntryDocument,
ccf.FundsMgmtTransactionNumber,
ccf.CreatedByUser,
ccf.CreationDate,
ccf.CreationTime,
ccf.FundsMgCarryForwardLevel,
ccf.FundsMgCarryForwardCounter,
ccf.FsclYrChgDocHasFollowOnDoc,
ccf.FundsMgmtCarryFwdBudgetStatus,
/* Associations */
_CompanyCode,
_FinMgmtArea,
_FinMgmtFiscalYear,
_ReferenceDocumentType,
_SenderFund,
_SenderCommitmentItem,
_SenderBudgetPeriod,
_SenderFunctionalArea,
_SenderFundedProgram,
_SenderFundsCenter,
_SenderGrant,
_ReceiverFund,
_ReceiverCommitmentItem,
_ReceiverBudgetPeriod,
_ReceiverFunctionalArea,
_ReceiverFundedProgram,
_ReceiverFundsCenter,
_ReceiverGrant,
_FiscalYearForFinMgmtArea,
_BudgetEntryDocument,
_TransactionCurrency,
_Currency
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUDGETENTRYDOCUMENT",
"I_FISCALYEARFORFINMGMTAREA",
"I_FUNDSMANAGEMENTDOCUMENTITEM",
"I_FUNDSMGMTCARRYFWDDOCUMENT",
"I_FUNDSMGMTCOMMITMENTENTRYITEM"
],
"ASSOCIATED":
[
"E_CMTMTCARRYFWDDOC",
"I_BUDGETENTRYDOCUMENT",
"I_BUDGETPERIOD",
"I_COMMITMENTITEM",
"I_COMPANYCODE",
"I_CURRENCY",
"I_FINANCIALMANAGEMENTAREA",
"I_FISCALYEARFORFINMGMTAREA",
"I_FUND",
"I_FUNDEDPROGRAM",
"I_FUNDSCENTER",
"I_FUNDSMANAGEMENTDOCUMENTITEM",
"I_FUNDSMGMTCOMMITMENTENTRYITEM",
"I_FUNDSMGMTFUNCTIONALAREA",
"I_GRANT",
"I_REFERENCEDOCUMENTTYPE"
],
"BASE":
[
"I_FUNDSMGMTCARRYFWDDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/