I_CMPLRQRSLTDYNPATTERNDETAIL

@EndUserText.label: 'Dynamic Pattern Assessment Detail'

@AbapCatalog:
{
  sqlViewName: 'ICRRDPDET',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

--Client Handling of the view
@ClientHandling:
{
  algorithm: #SESSION_VARIABLE
}

--VDM view type
@VDM.viewType: #BASIC


@ObjectModel:
{
  --Performance Annotations
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

define view I_CmplRqRsltDynPatternDetail
  as select from ehfndd_dyn_det

  --Link to root
  association [1..1] to I_CmplRqRslt    as _CmplRqRsltDynPatternAssmt on $projection.CmplRqRsltUUID = _CmplRqRsltDynPatternAssmt.CmplRqRsltUUID

  --Link to unit of measurement
  association [0..1] to I_UnitOfMeasure as _UnitOfMeasureQty1         on $projection.CmplRqRsltQty1UoM = _UnitOfMeasureQty1.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure as _UnitOfMeasureQty2         on $projection.CmplRqRsltQty2UoM = _UnitOfMeasureQty2.UnitOfMeasure

  --Link to user data
  association [0..1] to I_User          as _CreatedByUser             on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User          as _LastChangedByUser         on $projection.LastChangedByUser = _LastChangedByUser.UserID
{

       --UUID of Substance Assingment
  key  uuid                                                                 as CmplRqRsltDynPatternDetailUUID,

       --CmplRqRsltUUID
       crr_uuid                                                             as CmplRqRsltUUID,

       --Component UUID
       component_uuid                                                       as CmplRqRsltComponentUUID,

       --Value 1
       value_1_op_lower_limit                                               as CmplRqRsltLowrValue1Optr,
       value_1_lower_limit                                                  as CmplRqRsltLowrValue1,
       value_1_lower_limit_text                                             as CmplRqRsltLowrValue1Txt,
       value_1_op_upper_limit                                               as CmplRqRsltUprValue1Optr,
       value_1_upper_limit                                                  as CmplRqRsltUprValue1,
       value_1_upper_limit_text                                             as CmplRqRsltUprValue1Txt,

       --Value 2
       value_2_op_lower_limit                                               as CmplRqRsltLowrValue2Optr,
       value_2_lower_limit                                                  as CmplRqRsltLowrValue2,
       value_2_lower_limit_text                                             as CmplRqRsltLowrValue2Txt,
       value_2_op_upper_limit                                               as CmplRqRsltUprValue2Optr,
       value_2_upper_limit                                                  as CmplRqRsltUprValue2,
       value_2_upper_limit_text                                             as CmplRqRsltUprValue2Txt,

       --Value 3
       value_3_op_lower_limit                                               as CmplRqRsltLowrValue3Optr,
       value_3_lower_limit                                                  as CmplRqRsltLowrValue3,
       value_3_lower_limit_text                                             as CmplRqRsltLowrValue3Txt,
       value_3_op_upper_limit                                               as CmplRqRsltUprValue3Optr,
       value_3_upper_limit                                                  as CmplRqRsltUprValue3,
       value_3_upper_limit_text                                             as CmplRqRsltUprValue3Txt,

       --Quantity 1 with UoM
       @Semantics.quantity.unitOfMeasure: 'CmplRqRsltQty1UoM'
       qty_1_lower_limit                                                    as CmplRqRsltLowrQty1,
       qty_1_op_lower_limit                                                 as CmplRqRsltLowrQty1Optr,
       qty_1_lower_limit_text                                               as CmplRqRsltLowrQty1Txt,
       @Semantics.quantity.unitOfMeasure: 'CmplRqRsltQty1UoM'
       qty_1_upper_limit                                                    as CmplRqRsltUprQty1,
       qty_1_op_upper_limit                                                 as CmplRqRsltUprQty1Optr,
       qty_1_upper_limit_text                                               as CmplRqRsltUprQty1Txt,
       qty_1_quantity_unit                                                  as CmplRqRsltQty1UoM,

       --Quantity 2 with UoM
       @Semantics.quantity.unitOfMeasure: 'CmplRqRsltQty2UoM'
       qty_2_lower_limit                                                    as CmplRqRsltLowrQty2,
       qty_2_op_lower_limit                                                 as CmplRqRsltLowrQty2Optr,
       qty_2_lower_limit_text                                               as CmplRqRsltLowrQty2Txt,
       @Semantics.quantity.unitOfMeasure: 'CmplRqRsltQty2UoM'
       qty_2_upper_limit                                                    as CmplRqRsltUprQty2,
       qty_2_op_upper_limit                                                 as CmplRqRsltUprQty2Optr,
       qty_2_upper_limit_text                                               as CmplRqRsltUprQty2Txt,
       qty_2_quantity_unit                                                  as CmplRqRsltQty2UoM,

       -- Phrases
       phrase_1                                                             as CmplRqRsltPhrase1UUID,
       phrase_2                                                             as CmplRqRsltPhrase2UUID,
       phrase_3                                                             as CmplRqRsltPhrase3UUID,
       phrase_4                                                             as CmplRqRsltPhrase4UUID,

       -- Multi Phrases
       multi_phrase_1_1                                                     as CmplRqRsltMultiPhrase11UUID,
       multi_phrase_1_2                                                     as CmplRqRsltMultiPhrase12UUID,
       multi_phrase_1_3                                                     as CmplRqRsltMultiPhrase13UUID,
       multi_phrase_2_1                                                     as CmplRqRsltMultiPhrase21UUID,
       multi_phrase_2_2                                                     as CmplRqRsltMultiPhrase22UUID,
       multi_phrase_2_3                                                     as CmplRqRsltMultiPhrase23UUID,

       -- Text
       text1                                                                as CmplRqRsltText1,

       --Create at date/time and by user
       @Semantics.systemDateTime.createdAt: true
       cast(creationdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationDateTime,
       @Semantics.user.createdBy: true
       cast(createdbyuser as ehfnd_bo_crea_uname preserving type )          as CreatedByUser,
       --Update at date/time and by user
       @Semantics.systemDateTime.lastChangedAt: true
       cast(lastchangedatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeDateTime,
       @Semantics.user.lastChangedBy: true
       cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )      as LastChangedByUser,

       /* Associations */
       _CmplRqRsltDynPatternAssmt,
       _UnitOfMeasureQty1,
       _UnitOfMeasureQty2,
       _CreatedByUser,
       _LastChangedByUser

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHFNDD_DYN_DET"
],
"ASSOCIATED":
[
"I_CMPLRQRSLT",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/