I_CLFNCLASSFORKEYDATETP

CDS View

TP for Classification Class

I_CLFNCLASSFORKEYDATETP is a CDS View in S/4HANA. TP for Classification Class. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_ClfnClassForKeyDate view_entity from CONSUMPTION Class Header Data
A_ClfnProductClassHeader view from COMPOSITE Class Header Data 
//@ClientHandling.algorithm: #SESSION_VARIABLE

//@AbapCatalog.sqlViewName: 'INGCCLS01TP'

//@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'TP for Classification Class'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.representativeKey: 'ClassInternalID'
@ObjectModel.sapObjectNodeType.name: 'ClassificationClass'

//@AbapCatalog.preserveKey: true


//@ObjectModel.createEnabled: true

//@ObjectModel.updateEnabled: true

//@ObjectModel.deleteEnabled: true

//@ObjectModel.transactionalProcessingEnabled: true

//@ObjectModel.writeActiveImplementedBy: 'ABAP:CL_NGC_RAP_CLS'

//@ObjectModel.entityChangeStateId: 'ClassLastChangedDateTime'

define root view entity I_ClfnClassForKeyDateTP 
  with parameters
    // @Semantics.businessDate.at: true

    @Environment.systemField: #SYSTEM_DATE  
    @Consumption.hidden: true 
    P_KeyDate :sydate
  as select from I_ClfnClassForKeyDate( P_KeyDate: $parameters.P_KeyDate ) as Class
      //used only until related view are released, then they will come via I_ClfnClassForKeyDate

      association [0..*] to I_ClfnClassTypeText as _ClassTypeText
        on  $projection.ClassType  = _ClassTypeText.ClassType
      association [0..*] to I_ClfnClassStatusText as _ClassStatusText
        on  $projection.ClassStatus  = _ClassStatusText.ClassStatus
        and $projection.ClassType    = _ClassStatusText.ClassType        
      association [0..*] to I_ClfnClassGroupText as _ClassGroupText
        on  $projection.ClassGroup  = _ClassGroupText.ClassGroup
    
      composition [0..*] of I_ClfnClassKeywordForKeyDateTP as _ClassKeyword
      composition [0..*] of I_ClfnClassDescForKeyDateTP as _ClassDescription
      composition [0..*] of I_ClfnClassCharcForKeyDateTP as _ClassCharacteristic      
      composition [0..*] of I_ClfnClassTextForKeyDateTP as _ClassText
{
  key Class.ClassInternalID,
      Class.ClassType,
      _ClassTypeText[1:Language=$session.system_language].ClassTypeName,
      Class.Class,      
      Class.ClassStatus,
      //used only until related view are released

      //_ClassStatus._ClassStatusText[1:Language=$session.system_language].ClassStatusName,

      _ClassStatusText[1:Language=$session.system_language].ClassStatusName,
      Class.ClassGroup,
      //used only until related view are released

      //_ClassGroup._ClassGroupText[1:Language=$session.system_language].ClassGroupName,

      _ClassGroupText[1:Language=$session.system_language].ClassGroupName,
      Class.ClassSearchAuthGrp,
      Class.ClassClassfctnAuthGrp,
      Class.ClassMaintAuthGrp,     
      Class.DocumentInfoRecordDocNumber,
      Class.DocumentInfoRecordDocType,
      Class.DocumentInfoRecordDocPart,
      Class.DocumentInfoRecordDocVersion,        
      Class.SameClassfctnReaction,
      Class.ClassStandardOrgName,
      Class.ClassStandardNumber,
      Class.ClassStandardStartDate,
      Class.ClassStandardVersionStartDate,
      Class.ClassStandardVersion,
      Class.ClassStandardCharcTable,
      Class.CreationDate,
      Class.LastChangeDate,
      Class.ClassIsLocal, 
      Class.ValidityStartDate,
      Class.ValidityEndDate,
//      @ObjectModel.readOnly: true

      Class.ClassLastChangedDateTime,
//      @ObjectModel.readOnly: true

      $parameters.P_KeyDate as KeyDate,
      
//      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _ClassKeyword,
//      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _ClassDescription,
//      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _ClassText,
//      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _ClassCharacteristic
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CLFNCLASSFORKEYDATE",
"I_CLFNCLASSGROUPTEXT",
"I_CLFNCLASSSTATUSTEXT",
"I_CLFNCLASSTYPETEXT"
],
"ASSOCIATED":
[
"I_CLFNCLASSCHARCFORKEYDATETP",
"I_CLFNCLASSDESCFORKEYDATETP",
"I_CLFNCLASSKEYWORDFORKEYDATETP",
"I_CLFNCLASSTEXTFORKEYDATETP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More