I_CHGRECDREFTMPLROUTINGTP

CDS View

Chg Record Ref Obj Template Routing

I_CHGRECDREFTMPLROUTINGTP is a CDS View in S/4HANA. Chg Record Ref Obj Template Routing. It contains 2 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 2 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChangeRecordObjPgTmplRouting view from CONSUMPTION Change Record Ref Object Tmpl Routing

Fields (2)

KeyField CDS FieldsUsed in Views
BillOfOperationsType BillOfOperationsType 1
Plant Plant 1 
@AbapCatalog.sqlViewName: 'ICRREFTMPLRTGTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant','BillOfOperationsVersion'],
                writeDraftPersistence: 'PLMCRREFTER_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@EndUserText.label: 'Chg Record Ref Obj Template Routing'

define view I_ChgRecdRefTmplRoutingTP
  as select from           I_ChgRecdRefTmplRoutingBsc as reference_template_routing
    left outer to one join I_ProductionRoutingVersion as Routing on  reference_template_routing.ChgRecRefInternalKey1 = Routing.BillOfOperationsType
                                                                 and reference_template_routing.ChgRecRefInternalKey2 = Routing.BillOfOperationsGroup
                                                                 and reference_template_routing.ChgRecRefInternalKey3 = Routing.BillOfOperationsVariant
                                                                 and reference_template_routing.ChgRecRefInternalKey4 = Routing.BillOfOperationsVersion
  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP       on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefTmplRoutingBsc as _TmplRoutingExtension on $projection.ChangeRecordReferenceUUID = _TmplRoutingExtension.ChangeRecordReferenceUUID

{
  key   reference_template_routing.ChangeRecordReferenceUUID,
        @ObjectModel.readOnly: true
        case
           when Routing.BillOfOperationsType is null then cast(SUBSTRING( reference_template_routing.ChangeRecordReference, 1, 1) as plnty)
           else cast(Routing.BillOfOperationsType as plnty)
        end   as BillOfOperationsType,

        case
            when Routing.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_template_routing.ChangeRecordReference, 2, 9) as plnnr)
            else cast(Routing.BillOfOperationsGroup as plnnr)
        end   as BillOfOperationsGroup,

        case
          when Routing.BillOfOperationsVariant is null then cast (SUBSTRING( reference_template_routing.ChangeRecordReference, 10, 2) as plnal)
          else cast(Routing.BillOfOperationsVariant as plnal)
         end  as BillOfOperationsVariant,

        case
          when Routing.BillOfOperationsVersion is null then cast (SUBSTRING( reference_template_routing.ChangeRecordReference, 12, 4) as plnversn)
          else cast(Routing.BillOfOperationsVersion as plnversn)
          end as BillOfOperationsVersion,

        reference_template_routing.ChangeRecordUUID,
        reference_template_routing.ChangeRecordReferenceType,
        reference_template_routing.ChangeRecordReferenceSubtype,
        reference_template_routing.ChangeRecordRefObjectUUID,
        reference_template_routing.ChangeRecordReference,
        reference_template_routing.ParentChangeRecordRefUUID,
        reference_template_routing.IsMainReference,
        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        reference_template_routing.CreatedByUser,
        reference_template_routing.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        reference_template_routing.LastChangedByUser,
        reference_template_routing.LastChangeDateTime,
        reference_template_routing.ChangeRecordItemRelevance,
        reference_template_routing.ChangeRecordVirtualRefInd,
        ChangeRecordItemProcgStatus,
        reference_template_routing.ChgRecdReasonForChange,
        reference_template_routing.ExpdCompltnDte,
        reference_template_routing.ChgRecdAuthznGrpText,
        reference_template_routing.ChgRecdNmbrChgSts,
        reference_template_routing.ChangeNumber,
        ChgRecdItmTgtSts,
        ChgRecdItmDSgntr,
        ChgRecdCurrentItemProcgStatus,
        @ObjectModel.readOnly: true
        Routing.Plant,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
  (
       Routing.BillOfOperationsType                           = 'F' //F: Task list type for Template Routing

    or Routing.BillOfOperationsType                           is null
  )
  and  Routing._BillOfOperations.ShopFloorRtgTemplateCategory = '' // Category = '' is category for Reference Templates

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDREFTMPLROUTINGBSC",
"I_PRODUCTIONROUTINGVERSION"
],
"ASSOCIATED":
[
"E_CHGRECDREFTMPLROUTINGBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More